Meteran air pintar: flow sensor di pipa menghitung liter yang terpakai hari ini dan total sejak dipasang. Angkanya disimpan di memori ESP32, jadi tidak hilang saat listrik padam. Setiap tengah malam, pemakaian kemarin dilaporkan ke Klenik.

Pulsa YF-S201C dihitung dengan interrupt seperti proyek 067. Yang baru adalah Preferences, pustaka bawaan ESP32 untuk menyimpan angka di memori flash. Isi flash tetap ada walaupun listrik mati. Saat menyala, angka total, angka hari ini, dan tanggal terakhir dibaca kembali dengan getFloat(), sehingga hitungan berlanjut, bukan mulai dari nol.

Memori flash punya batas tulis (±100.000 kali per lokasi), jadi angka tidak disimpan setiap 5 detik, melainkan setiap menit. Kalau listrik padam, paling banyak satu menit pemakaian yang hilang.

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
Water Flow Sensor Ukuran G1/2 inchi Hall Water F	1	Rp35.000
Resistor 1K (isi 10)isi 10, terpakai 1	1	Rp1.800
Resistor 2K (isi 10)isi 10, terpakai 1	1	Rp1.800
Breadboard mini 170 titik	1	Rp4.875
Kabel jumper male-female 10 cm (isi 10)isi 10, terpakai 3	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp121.975

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
YF-S201C (kuning OUT, hitam −, merah +) + pembagi 1K/2K di OUT OUT	→	D27 GPIO27	kuning
YF-S201C (kuning OUT, hitam −, merah +) + pembagi 1K/2K di OUT −	→	GND	hitam
YF-S201C (kuning OUT, hitam −, merah +) + pembagi 1K/2K di OUT +	→	VIN	merah

Langkah 2: Siapkan dashboard Klenik

Hari Iniichibot/budi1234/p135/hari

0 detik lalu

Debit Sekarangichibot/budi1234/p135/debit

0 detik lalu

Total Sejak Dipasangichibot/budi1234/p135/total

0 detik lalu

Laporan Harianichibot/budi1234/p135/log

Pemakaian kemarin: 214 liter

0 detik lalu

Cara cepat: unduh p135.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Gauge Hari Ini	`ichibot/KODE/p135/hari`	0–500 L
Gauge Debit Sekarang	`ichibot/KODE/p135/debit`	0–30 L/mnt
Gauge Total Sejak Dipasang	`ichibot/KODE/p135/total`	0–10000 L
Text Log Laporan Harian	`ichibot/KODE/p135/log`	menampilkan teks masuk

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p135.inoUnduh .ino

// Proyek 135 - Total Air Terpakai (Liter) Flow Sensor
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <Preferences.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LOG   = "ichibot/budi1234/p135/log";
const char* TOPIK_DEBIT = "ichibot/budi1234/p135/debit";
const char* TOPIK_HARI  = "ichibot/budi1234/p135/hari";
const char* TOPIK_TOTAL = "ichibot/budi1234/p135/total";
const float PULSA_PER_LITER = 450;    // sesuaikan dengan hasil kalibrasi proyek 067

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
Preferences memori;                   // flash ESP32: tidak hilang saat listrik padam
const int SENSOR = 27;
volatile unsigned long pulsa = 0;
float literHariIni = 0, literTotal = 0;
int hariTadi = -1;
unsigned long kirimTerakhir = 0, simpanTerakhir = 0;

void IRAM_ATTR hitung() { pulsa++; }

void langganan() {}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  memori.begin("air", false);
  literTotal = memori.getFloat("total", 0);       // lanjutkan dari angka terakhir
  literHariIni = memori.getFloat("hari", 0);
  hariTadi = memori.getInt("tgl", -1);
  pinMode(SENSOR, INPUT);
  attachInterrupt(digitalPinToInterrupt(SENSOR), hitung, FALLING);
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org");
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (millis() - kirimTerakhir < 5000) return;
  kirimTerakhir = millis();
  noInterrupts();
  unsigned long n = pulsa;
  pulsa = 0;
  interrupts();
  float liter = n / PULSA_PER_LITER;
  literHariIni += liter;
  literTotal += liter;

  time_t t = time(nullptr);
  struct tm* w = localtime(&t);
  if (t > 1700000000 && w->tm_mday != hariTadi) {
    if (hariTadi != -1) mqtt.publish(TOPIK_LOG, ("Pemakaian kemarin: " + String(literHariIni, 0) + " liter").c_str());
    hariTadi = w->tm_mday;
    literHariIni = 0;
  }

  mqtt.publish(TOPIK_DEBIT, String(liter / 5 * 60, 1).c_str());   // L/menit dari 5 detik
  mqtt.publish(TOPIK_HARI, String(literHariIni, 1).c_str());
  mqtt.publish(TOPIK_TOTAL, String(literTotal, 0).c_str());

  if (millis() - simpanTerakhir > 60000) {        // simpan ke flash tiap menit, bukan tiap 5 detik
    simpanTerakhir = millis();
    memori.putFloat("total", literTotal);
    memori.putFloat("hari", literHariIni);
    memori.putInt("tgl", hariTadi);
  }
}

// Proyek 135 - Total Air Terpakai (Liter) Flow Sensor
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <Preferences.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LOG   = "ichibot/budi1234/p135/log";
const char* TOPIK_DEBIT = "ichibot/budi1234/p135/debit";
const char* TOPIK_HARI  = "ichibot/budi1234/p135/hari";
const char* TOPIK_TOTAL = "ichibot/budi1234/p135/total";
const float PULSA_PER_LITER = 450;    // sesuaikan dengan hasil kalibrasi proyek 067

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
Preferences memori;                   // flash ESP32: tidak hilang saat listrik padam
const int SENSOR = 27;
volatile unsigned long pulsa = 0;
float literHariIni = 0, literTotal = 0;
int hariTadi = -1;
unsigned long kirimTerakhir = 0, simpanTerakhir = 0;

void IRAM_ATTR hitung() { pulsa++; }

void langganan() {}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  memori.begin("air", false);
  literTotal = memori.getFloat("total", 0);       // lanjutkan dari angka terakhir
  literHariIni = memori.getFloat("hari", 0);
  hariTadi = memori.getInt("tgl", -1);
  pinMode(SENSOR, INPUT);
  attachInterrupt(digitalPinToInterrupt(SENSOR), hitung, FALLING);
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org");
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

if (millis() - kirimTerakhir < 5000) return;
  kirimTerakhir = millis();
  noInterrupts();
  unsigned long n = pulsa;
  pulsa = 0;
  interrupts();
  float liter = n / PULSA_PER_LITER;
  literHariIni += liter;
  literTotal += liter;

time_t t = time(nullptr);
  struct tm* w = localtime(&t);
  if (t > 1700000000 && w->tm_mday != hariTadi) {
    if (hariTadi != -1) mqtt.publish(TOPIK_LOG, ("Pemakaian kemarin: " + String(literHariIni, 0) + " liter").c_str());
    hariTadi = w->tm_mday;
    literHariIni = 0;
  }

mqtt.publish(TOPIK_DEBIT, String(liter / 5 * 60, 1).c_str());   // L/menit dari 5 detik
  mqtt.publish(TOPIK_HARI, String(literHariIni, 1).c_str());
  mqtt.publish(TOPIK_TOTAL, String(literTotal, 0).c_str());

if (millis() - simpanTerakhir > 60000) {        // simpan ke flash tiap menit, bukan tiap 5 detik
    simpanTerakhir = millis();
    memori.putFloat("total", literTotal);
    memori.putFloat("hari", literHariIni);
    memori.putInt("tgl", hariTadi);
  }
}

Langkah 4: Pahami kodenya

Membaca angka yang tersimpan. Angka kedua (0) dipakai kalau belum pernah ada yang disimpan.
Menulis flash terlalu sering memperpendek umurnya. Sekali per menit aman untuk bertahun-tahun.
"air" adalah nama laci penyimpanan. false berarti boleh baca dan tulis.