Papan sensor hujan diletakkan telentang di lantai, dekat mesin cuci, dispenser, atau tandon dalam rumah. Begitu ada air merembes, buzzer berbunyi dan Klenik memberi tahu, sebelum air menggenang ke mana-mana.

Papan sensor hujan dari proyek 063 juga bisa mendeteksi genangan. Papan diletakkan menghadap ke atas, rata dengan lantai, di titik paling rendah. Air yang merembes menjembatani jalur tembaga sehingga angka A0 turun. Di bawah 700, lantai dianggap basah.

Status hanya dikirim saat berubah, dan dikirim dengan flag retained supaya terlihat walaupun kamu baru membuka dashboard. Buzzer berbunyi selama lantai basah. Setelah papan dilap kering, buzzer berhenti sendiri.

Komponen

Komponen	Qty	Harga
NodeMCU ESP8266 V3 (Lolin)	1	Rp42.000
Rain Drop Sensor Pendeteksi Hujan Tetesan Air Ar	1	Rp11.640
Modul buzzer aktif KY-012	1	Rp7.500
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 6	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp64.640

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Modul sensor hujan (papan hujan ke 2 pin ujung) AO	→	A0	hijau
Modul sensor hujan (papan hujan ke 2 pin ujung) VCC	→	3V	merah
Modul sensor hujan (papan hujan ke 2 pin ujung) GND	→	G	hitam
Modul buzzer aktif KY-012 S	→	D2 GPIO4	kuning
Modul buzzer aktif KY-012 +	→	3V	merah
Modul buzzer aktif KY-012 −	→	G	hitam

Langkah 2: Siapkan dashboard Klenik

Lantaiichibot/budi1234/p136/basah

ADA AIR!

0 detik lalu

Nilai Sensorichibot/budi1234/p136/nilai

0 detik lalu

Catatanichibot/budi1234/p136/log

AIR DI LANTAI! Cek mesin cuci/tandon/pipa

Lantai sudah kering

0 detik lalu

Cara cepat: unduh p136.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Indikator Boolean Lantai	`ichibot/KODE/p136/basah`	ON = `1` “ADA AIR!”, OFF = `0`
Gauge Nilai Sensor	`ichibot/KODE/p136/nilai`	0–1024
Text Log Catatan	`ichibot/KODE/p136/log`	menampilkan teks masuk

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: NodeMCU 1.0 (ESP-12E Module). Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p136.inoUnduh .ino

// Proyek 136 - Alarm Air Tumpah di Lantai
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_BASAH = "ichibot/budi1234/p136/basah";
const char* TOPIK_LOG   = "ichibot/budi1234/p136/log";
const char* TOPIK_NILAI = "ichibot/budi1234/p136/nilai";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int BUZZER = D2;
const int BATAS_BASAH = 700;          // A0 di bawah angka ini = papan terkena air
bool basah = false;
unsigned long terakhir = 0;

void langganan() {}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(BUZZER, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
  digitalWrite(BUZZER, basah && (millis() / 300) % 2);

  if (millis() - terakhir < 1000) return;
  terakhir = millis();
  int nilai = analogRead(A0);         // kering ±1024, basah turun
  bool sekarang = nilai < BATAS_BASAH;
  if (sekarang != basah) {
    basah = sekarang;
    mqtt.publish(TOPIK_BASAH, basah ? "1" : "0", true);
    mqtt.publish(TOPIK_LOG, basah ? "AIR DI LANTAI! Cek mesin cuci/tandon/pipa" : "Lantai sudah kering");
  }
  mqtt.publish(TOPIK_NILAI, String(nilai).c_str());
}

// Proyek 136 - Alarm Air Tumpah di Lantai
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_BASAH = "ichibot/budi1234/p136/basah";
const char* TOPIK_LOG   = "ichibot/budi1234/p136/log";
const char* TOPIK_NILAI = "ichibot/budi1234/p136/nilai";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int BUZZER = D2;
const int BATAS_BASAH = 700;          // A0 di bawah angka ini = papan terkena air
bool basah = false;
unsigned long terakhir = 0;

void langganan() {}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(BUZZER, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
  digitalWrite(BUZZER, basah && (millis() / 300) % 2);

if (millis() - terakhir < 1000) return;
  terakhir = millis();
  int nilai = analogRead(A0);         // kering ±1024, basah turun
  bool sekarang = nilai < BATAS_BASAH;
  if (sekarang != basah) {
    basah = sekarang;
    mqtt.publish(TOPIK_BASAH, basah ? "1" : "0", true);
    mqtt.publish(TOPIK_LOG, basah ? "AIR DI LANTAI! Cek mesin cuci/tandon/pipa" : "Lantai sudah kering");
  }
  mqtt.publish(TOPIK_NILAI, String(nilai).c_str());
}

Langkah 4: Pahami kodenya

Batas basah. Lihat gauge Nilai Sensor saat kering dan saat papan diteteskan air, lalu pilih angka di antaranya.
Buzzer berbunyi putus-putus selama basah, ditulis di awal loop() supaya bunyinya tidak tertahan jeda 1 detik.