Wadah beras di atas load cell memberi tahu sisa beras dalam kilogram dan persen, memperkirakan cukup untuk berapa hari lagi berdasarkan pemakaian kemarin, dan mengingatkan saat beras tinggal 1 kg. Cocok juga untuk pakan ternak atau stok warung.

Timbangan bekerja seperti proyek 131. Saat pertama dinyalakan, wadah harus dalam keadaan kosong supaya tara menghasilkan berat wadah = 0, dan setelah itu yang terbaca hanya berat beras.

Setiap pergantian hari (dari jam NTP), berat saat itu disimpan. Selisihnya dengan berat sehari sebelumnya adalah pemakaian kemarin. Sisa beras dibagi pemakaian per hari menghasilkan perkiraan "cukup untuk berapa hari". Pengingat beli dikirim sekali saat beras di bawah 1 kg, dan baru aktif lagi setelah wadah diisi kembali.

Load cell 5 kg membatasi isi wadah sekitar 4,5 kg beras, cukup untuk sekitar seminggu bagi keluarga kecil.

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
Sensor Berat Tekanan Range 5Kg dengan Modul HX71	1	Rp26.000
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 4	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp104.500

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Load cell + modul HX711 GND	→	GND	hitam
Load cell + modul HX711 DT	→	D26 GPIO26	biru
Load cell + modul HX711 SCK	→	D27 GPIO27	kuning
Load cell + modul HX711 VCC	→	3V3	merah

Langkah 2: Siapkan dashboard Klenik

Sisa Berasichibot/budi1234/p134/persen

0 detik lalu

Berat Berasichibot/budi1234/p134/gram

0 detik lalu

Cukup untukichibot/budi1234/p134/hari

0 detik lalu

Pengingatichibot/budi1234/p134/log

Beras tinggal 0.9 kg. Waktunya beli!

0 detik lalu

Cara cepat: unduh p134.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Gauge Sisa Beras	`ichibot/KODE/p134/persen`	0–100 %
Gauge Berat Beras	`ichibot/KODE/p134/gram`	0–5000 g
Gauge Cukup untuk	`ichibot/KODE/p134/hari`	0–14 hari
Text Log Pengingat	`ichibot/KODE/p134/log`	menampilkan teks masuk

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary), HX711 (Rob Tillaart). Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p134.inoUnduh .ino

// Proyek 134 - Stok Beras dengan Timbangan
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <HX711.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_GRAM   = "ichibot/budi1234/p134/gram";
const char* TOPIK_PERSEN = "ichibot/budi1234/p134/persen";
const char* TOPIK_HARI   = "ichibot/budi1234/p134/hari";
const char* TOPIK_LOG    = "ichibot/budi1234/p134/log";
const float FAKTOR = 420.0;           // dari kalibrasi proyek 131
const float PENUH_GRAM = 4500;        // isi wadah saat penuh
const float BATAS_BELI = 1000;        // ingatkan beli beras di bawah 1 kg

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
HX711 timbangan;
float beratPagi = -1, pakaiPerHari = 0;
int hariTadi = -1;
bool sudahDiingatkan = false;
unsigned long terakhir = 0;

void langganan() {}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  timbangan.begin(26, 27);
  timbangan.set_scale(FAKTOR);
  timbangan.tare(20);                 // wadah KOSONG saat pertama dinyalakan = 0
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org");
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (millis() - terakhir < 10000 || !timbangan.is_ready()) return;
  terakhir = millis();
  float gram = max(0.0f, timbangan.get_units(10));

  time_t t = time(nullptr);
  struct tm* w = localtime(&t);
  if (t > 1700000000 && w->tm_mday != hariTadi) {   // tiap hari: hitung pemakaian kemarin
    if (beratPagi > 0 && beratPagi > gram) pakaiPerHari = beratPagi - gram;
    beratPagi = gram;
    hariTadi = w->tm_mday;
  }

  mqtt.publish(TOPIK_GRAM, String(gram, 0).c_str());
  mqtt.publish(TOPIK_PERSEN, String(constrain(gram / PENUH_GRAM * 100, 0, 100), 0).c_str());
  if (pakaiPerHari > 50)
    mqtt.publish(TOPIK_HARI, String(gram / pakaiPerHari, 1).c_str());   // perkiraan cukup berapa hari

  if (gram < BATAS_BELI && !sudahDiingatkan) {
    sudahDiingatkan = true;
    mqtt.publish(TOPIK_LOG, ("Beras tinggal " + String(gram / 1000, 1) + " kg. Waktunya beli!").c_str());
  }
  if (gram > BATAS_BELI + 500) sudahDiingatkan = false;   // sudah diisi lagi
}

// Proyek 134 - Stok Beras dengan Timbangan
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <HX711.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_GRAM   = "ichibot/budi1234/p134/gram";
const char* TOPIK_PERSEN = "ichibot/budi1234/p134/persen";
const char* TOPIK_HARI   = "ichibot/budi1234/p134/hari";
const char* TOPIK_LOG    = "ichibot/budi1234/p134/log";
const float FAKTOR = 420.0;           // dari kalibrasi proyek 131
const float PENUH_GRAM = 4500;        // isi wadah saat penuh
const float BATAS_BELI = 1000;        // ingatkan beli beras di bawah 1 kg

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
HX711 timbangan;
float beratPagi = -1, pakaiPerHari = 0;
int hariTadi = -1;
bool sudahDiingatkan = false;
unsigned long terakhir = 0;

void langganan() {}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  timbangan.begin(26, 27);
  timbangan.set_scale(FAKTOR);
  timbangan.tare(20);                 // wadah KOSONG saat pertama dinyalakan = 0
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org");
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

if (millis() - terakhir < 10000 || !timbangan.is_ready()) return;
  terakhir = millis();
  float gram = max(0.0f, timbangan.get_units(10));

time_t t = time(nullptr);
  struct tm* w = localtime(&t);
  if (t > 1700000000 && w->tm_mday != hariTadi) {   // tiap hari: hitung pemakaian kemarin
    if (beratPagi > 0 && beratPagi > gram) pakaiPerHari = beratPagi - gram;
    beratPagi = gram;
    hariTadi = w->tm_mday;
  }

mqtt.publish(TOPIK_GRAM, String(gram, 0).c_str());
  mqtt.publish(TOPIK_PERSEN, String(constrain(gram / PENUH_GRAM * 100, 0, 100), 0).c_str());
  if (pakaiPerHari > 50)
    mqtt.publish(TOPIK_HARI, String(gram / pakaiPerHari, 1).c_str());   // perkiraan cukup berapa hari

if (gram < BATAS_BELI && !sudahDiingatkan) {
    sudahDiingatkan = true;
    mqtt.publish(TOPIK_LOG, ("Beras tinggal " + String(gram / 1000, 1) + " kg. Waktunya beli!").c_str());
  }
  if (gram > BATAS_BELI + 500) sudahDiingatkan = false;   // sudah diisi lagi
}

Langkah 4: Pahami kodenya

Pemakaian kemarin dihitung dari selisih berat. Kalau berat naik (beras baru diisi), pemakaian lama tetap dipakai.
Perkiraan sederhana: sisa dibagi pemakaian harian. Baru tampil setelah satu hari penuh tercatat.
Pengingat baru aktif lagi setelah beras bertambah jelas, jadi tidak berulang-ulang saat angkanya naik-turun di sekitar 1 kg.