Tatakan pintar di meja belajar atau kerja. Setiap kali botol diangkat lalu diletakkan lagi, berat yang berkurang dicatat sebagai air yang diminum. Klenik menjumlahkan total minum hari ini dan mengingatkan kalau sudah satu jam belum minum.

Air seberat 1 gram sama dengan 1 ml, jadi timbangan bisa mengukur banyaknya air yang diminum. Load cell 5 kg (seperti proyek 131) dipasang di bawah tatakan. ESP32 mengingat berat botol saat terakhir diletakkan. Kalau botol diletakkan lagi dan beratnya berkurang lebih dari 20 gram, selisihnya dicatat sebagai minum.

Saat botol diangkat, beratnya di bawah 50 gram, jadi tidak ada yang dihitung. Saat botol diisi ulang, beratnya naik, dan berat baru itu menjadi patokan untuk minum berikutnya. Pengingat dikirim sekali kalau 1 jam tidak ada catatan minum.

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
Sensor Berat Tekanan Range 5Kg dengan Modul HX71	1	Rp26.000
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 4	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp104.500

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Load cell + modul HX711 GND	→	GND	hitam
Load cell + modul HX711 DT	→	D26 GPIO26	biru
Load cell + modul HX711 SCK	→	D27 GPIO27	kuning
Load cell + modul HX711 VCC	→	3V3	merah

Langkah 2: Siapkan dashboard Klenik

Minum Hari Iniichibot/budi1234/p133/total

0 detik lalu

Botolichibot/budi1234/p133/botol

DI TATAKAN

0 detik lalu

Catatan Minumichibot/budi1234/p133/log

Minum 180 ml

Minum 220 ml

Sudah 1 jam belum minum. Ayo minum!

0 detik lalu

Hari Baruichibot/budi1234/p133/ulang

Ulang

0 detik lalu

Cara cepat: unduh p133.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Gauge Minum Hari Ini	`ichibot/KODE/p133/total`	0–2500 ml
Indikator Boolean Botol	`ichibot/KODE/p133/botol`	ON = `1` “DI TATAKAN”, OFF = `0`
Text Log Catatan Minum	`ichibot/KODE/p133/log`	menampilkan teks masuk
Switch Hari Baru	`ichibot/KODE/p133/ulang`	payload ON / OFF

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary), HX711 (Rob Tillaart). Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p133.inoUnduh .ino

// Proyek 133 - Tatakan Botol Pengingat Minum
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <HX711.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_TOTAL = "ichibot/budi1234/p133/total";
const char* TOPIK_ULANG = "ichibot/budi1234/p133/ulang";
const char* TOPIK_LOG   = "ichibot/budi1234/p133/log";
const char* TOPIK_BOTOL = "ichibot/budi1234/p133/botol";
const float FAKTOR = 420.0;           // dari kalibrasi proyek 131
const unsigned long JEDA_INGAT = 60UL * 60 * 1000;   // ingatkan kalau 1 jam tidak minum

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
HX711 timbangan;
float beratTadi = -1;                 // berat botol saat terakhir diletakkan
float minumHariIni = 0;               // ml (1 gram air = 1 ml)
unsigned long minumTerakhir = 0, terakhir = 0;
bool sudahDiingatkan = false;

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  minumHariIni = 0;                   // hari baru
  mqtt.publish(TOPIK_TOTAL, "0");
  mqtt.publish(TOPIK_ULANG, "OFF");
}

void langganan() {
  mqtt.subscribe(TOPIK_ULANG);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  timbangan.begin(26, 27);
  timbangan.set_scale(FAKTOR);
  timbangan.tare(20);                 // tatakan kosong = 0
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
  minumTerakhir = millis();
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (millis() - terakhir < 2000 || !timbangan.is_ready()) return;
  terakhir = millis();
  float gram = timbangan.get_units(10);
  bool adaBotol = gram > 50;

  if (adaBotol) {
    if (beratTadi > 0 && beratTadi - gram > 20) {     // botol kembali lebih ringan = diminum
      float ml = beratTadi - gram;
      minumHariIni += ml;
      minumTerakhir = millis();
      sudahDiingatkan = false;
      mqtt.publish(TOPIK_LOG, ("Minum " + String(ml, 0) + " ml").c_str());
      mqtt.publish(TOPIK_TOTAL, String(minumHariIni, 0).c_str());
    }
    beratTadi = gram;                 // isi ulang botol juga tercatat sebagai berat baru
  }
  mqtt.publish(TOPIK_BOTOL, adaBotol ? "1" : "0");

  if (!sudahDiingatkan && millis() - minumTerakhir > JEDA_INGAT) {
    sudahDiingatkan = true;
    mqtt.publish(TOPIK_LOG, "Sudah 1 jam belum minum. Ayo minum!");
  }
}

// Proyek 133 - Tatakan Botol Pengingat Minum
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <HX711.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_TOTAL = "ichibot/budi1234/p133/total";
const char* TOPIK_ULANG = "ichibot/budi1234/p133/ulang";
const char* TOPIK_LOG   = "ichibot/budi1234/p133/log";
const char* TOPIK_BOTOL = "ichibot/budi1234/p133/botol";
const float FAKTOR = 420.0;           // dari kalibrasi proyek 131
const unsigned long JEDA_INGAT = 60UL * 60 * 1000;   // ingatkan kalau 1 jam tidak minum

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
HX711 timbangan;
float beratTadi = -1;                 // berat botol saat terakhir diletakkan
float minumHariIni = 0;               // ml (1 gram air = 1 ml)
unsigned long minumTerakhir = 0, terakhir = 0;
bool sudahDiingatkan = false;

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  minumHariIni = 0;                   // hari baru
  mqtt.publish(TOPIK_TOTAL, "0");
  mqtt.publish(TOPIK_ULANG, "OFF");
}

void langganan() {
  mqtt.subscribe(TOPIK_ULANG);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  timbangan.begin(26, 27);
  timbangan.set_scale(FAKTOR);
  timbangan.tare(20);                 // tatakan kosong = 0
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
  minumTerakhir = millis();
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

if (millis() - terakhir < 2000 || !timbangan.is_ready()) return;
  terakhir = millis();
  float gram = timbangan.get_units(10);
  bool adaBotol = gram > 50;

if (adaBotol) {
    if (beratTadi > 0 && beratTadi - gram > 20) {     // botol kembali lebih ringan = diminum
      float ml = beratTadi - gram;
      minumHariIni += ml;
      minumTerakhir = millis();
      sudahDiingatkan = false;
      mqtt.publish(TOPIK_LOG, ("Minum " + String(ml, 0) + " ml").c_str());
      mqtt.publish(TOPIK_TOTAL, String(minumHariIni, 0).c_str());
    }
    beratTadi = gram;                 // isi ulang botol juga tercatat sebagai berat baru
  }
  mqtt.publish(TOPIK_BOTOL, adaBotol ? "1" : "0");

if (!sudahDiingatkan && millis() - minumTerakhir > JEDA_INGAT) {
    sudahDiingatkan = true;
    mqtt.publish(TOPIK_LOG, "Sudah 1 jam belum minum. Ayo minum!");
  }
}

Langkah 4: Pahami kodenya

Minum dihitung dari selisih berat sebelum diangkat dan setelah diletakkan. Batas 20 gram menyaring goyangan kecil.
Berat terakhir selalu diperbarui saat botol ada, jadi isi ulang tidak dianggap minum negatif.
Jarak waktu pengingat. Untuk anak sekolah, 45 menit (satu jam pelajaran) mungkin lebih cocok.