Mesin absensi kartu untuk kelas, ekskul, atau kantor kecil. Setiap anggota punya kartu RFID. Saat ditempel, buzzer berbunyi sekali dan Klenik mencatat nama serta jam kehadirannya. Kartu yang tidak terdaftar ditolak dengan tiga bunyi cepat.

Kartu dibaca seperti proyek 111. Bedanya, UID dicocokkan dengan daftar anggota di kode. Daftar itu berupa array struct: setiap isi berisi pasangan UID dan nama. Perulangan for membandingkan UID kartu dengan setiap UID di daftar. Kalau cocok, nama anggota diambil.

Jam kehadiran diambil dari internet (NTP) dan dikirim bersama nama ke Text Log, misalnya 07:12 Budi hadir. Bunyi buzzer membedakan hasilnya tanpa perlu melihat layar: satu bip = tercatat, tiga bip cepat = kartu tidak dikenal.

Untuk mendaftarkan kartu baru, pakai proyek 111 untuk melihat UID-nya, lalu tambahkan satu baris di daftar[].

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
RC522 RFID Reader Writer Module 13.56MHz Arduino	1	Rp17.500
Modul buzzer aktif KY-012	1	Rp7.500
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 10	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp103.500

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
RFID RC522 SDA	→	D5 GPIO5	kuning
RFID RC522 SCK	→	D18 GPIO18	hijau
RFID RC522 MOSI	→	D23 GPIO23	biru
RFID RC522 MISO	→	D19 GPIO19	ungu
RFID RC522 GND	→	GND	hitam
RFID RC522 RST	→	D4 GPIO4	oranye
RFID RC522 3V3	→	3V3	merah
Modul buzzer aktif KY-012 S	→	D27 GPIO27	kuning
Modul buzzer aktif KY-012 +	→	VIN	merah
Modul buzzer aktif KY-012 −	→	GND	hitam

Langkah 2: Siapkan dashboard Klenik

Daftar Hadirichibot/budi1234/p112/log

07:02 Siti hadir

07:05 Budi hadir

07:09 Kartu tidak dikenal: 5E 22 A1 07

0 detik lalu

Jumlah Hadirichibot/budi1234/p112/hadir

0 detik lalu

Cara cepat: unduh p112.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Text Log Daftar Hadir	`ichibot/KODE/p112/log`	menampilkan teks masuk
Gauge Jumlah Hadir	`ichibot/KODE/p112/hadir`	0–40 orang

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary), MFRC522 (GithubCommunity). Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p112.inoUnduh .ino

// Proyek 112 - Absensi RFID
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <SPI.h>
#include <MFRC522.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LOG   = "ichibot/budi1234/p112/log";
const char* TOPIK_HADIR = "ichibot/budi1234/p112/hadir";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
MFRC522 rfid(5, 4);                   // SS, RST
const int BUZZER = 27;

struct Anggota { const char* uid; const char* nama; };
Anggota daftar[] = {                  // isi dengan UID dari proyek 111
  {"A3 4F 19 0B", "Budi"},
  {"04 7C 2E 1A", "Siti"},
  {"9B 11 C0 33", "Andi"},
};
const int JUMLAH = sizeof(daftar) / sizeof(daftar[0]);
int hadirHariIni = 0;

String bacaUID() {
  String uid;
  for (byte i = 0; i < rfid.uid.size; i++) {
    if (rfid.uid.uidByte[i] < 0x10) uid += "0";
    uid += String(rfid.uid.uidByte[i], HEX);
    if (i < rfid.uid.size - 1) uid += " ";
  }
  uid.toUpperCase();
  return uid;
}

String jamSekarang() {
  time_t t = time(nullptr);
  char buf[6];
  strftime(buf, sizeof(buf), "%H:%M", localtime(&t));
  return String(buf);
}

void bip(int kali, int lama) {
  for (int i = 0; i < kali; i++) {
    digitalWrite(BUZZER, HIGH); delay(lama);
    digitalWrite(BUZZER, LOW);  delay(100);
  }
}

void langganan() {}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(BUZZER, OUTPUT);
  SPI.begin();
  rfid.PCD_Init();
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org");
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (!rfid.PICC_IsNewCardPresent() || !rfid.PICC_ReadCardSerial()) return;
  String uid = bacaUID();
  rfid.PICC_HaltA();
  rfid.PCD_StopCrypto1();

  const char* nama = nullptr;
  for (int i = 0; i < JUMLAH; i++) if (uid == daftar[i].uid) nama = daftar[i].nama;

  if (nama) {
    hadirHariIni++;
    bip(1, 120);                      // satu bip pendek: tercatat
    mqtt.publish(TOPIK_LOG, (jamSekarang() + " " + nama + " hadir").c_str());
    mqtt.publish(TOPIK_HADIR, String(hadirHariIni).c_str());
  } else {
    bip(3, 60);                       // tiga bip cepat: kartu tidak dikenal
    mqtt.publish(TOPIK_LOG, (jamSekarang() + " Kartu tidak dikenal: " + uid).c_str());
  }
  delay(1000);
}

// Proyek 112 - Absensi RFID
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <SPI.h>
#include <MFRC522.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LOG   = "ichibot/budi1234/p112/log";
const char* TOPIK_HADIR = "ichibot/budi1234/p112/hadir";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
MFRC522 rfid(5, 4);                   // SS, RST
const int BUZZER = 27;

struct Anggota { const char* uid; const char* nama; };
Anggota daftar[] = {                  // isi dengan UID dari proyek 111
  {"A3 4F 19 0B", "Budi"},
  {"04 7C 2E 1A", "Siti"},
  {"9B 11 C0 33", "Andi"},
};
const int JUMLAH = sizeof(daftar) / sizeof(daftar[0]);
int hadirHariIni = 0;

String bacaUID() {
  String uid;
  for (byte i = 0; i < rfid.uid.size; i++) {
    if (rfid.uid.uidByte[i] < 0x10) uid += "0";
    uid += String(rfid.uid.uidByte[i], HEX);
    if (i < rfid.uid.size - 1) uid += " ";
  }
  uid.toUpperCase();
  return uid;
}

String jamSekarang() {
  time_t t = time(nullptr);
  char buf[6];
  strftime(buf, sizeof(buf), "%H:%M", localtime(&t));
  return String(buf);
}

void bip(int kali, int lama) {
  for (int i = 0; i < kali; i++) {
    digitalWrite(BUZZER, HIGH); delay(lama);
    digitalWrite(BUZZER, LOW);  delay(100);
  }
}

void langganan() {}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(BUZZER, OUTPUT);
  SPI.begin();
  rfid.PCD_Init();
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org");
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

if (!rfid.PICC_IsNewCardPresent() || !rfid.PICC_ReadCardSerial()) return;
  String uid = bacaUID();
  rfid.PICC_HaltA();
  rfid.PCD_StopCrypto1();

const char* nama = nullptr;
  for (int i = 0; i < JUMLAH; i++) if (uid == daftar[i].uid) nama = daftar[i].nama;

if (nama) {
    hadirHariIni++;
    bip(1, 120);                      // satu bip pendek: tercatat
    mqtt.publish(TOPIK_LOG, (jamSekarang() + " " + nama + " hadir").c_str());
    mqtt.publish(TOPIK_HADIR, String(hadirHariIni).c_str());
  } else {
    bip(3, 60);                       // tiga bip cepat: kartu tidak dikenal
    mqtt.publish(TOPIK_LOG, (jamSekarang() + " Kartu tidak dikenal: " + uid).c_str());
  }
  delay(1000);
}

Langkah 4: Pahami kodenya

struct menggabungkan beberapa data jadi satu paket. Di sini satu anggota = UID + nama.
Jumlah anggota dihitung otomatis dari ukuran array, jadi tidak perlu diubah saat anggota ditambah.
Pencocokan kartu. Kalau tidak ada yang cocok, nama tetap nullptr (kosong).