Kunci Pintu RFID + Solenoid

// Proyek 113 - Kunci Pintu RFID + Solenoid
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <SPI.h>
#include <MFRC522.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_TERBUKA = "ichibot/budi1234/p113/terbuka";
const char* TOPIK_LOG     = "ichibot/budi1234/p113/log";
const char* TOPIK_BUKA    = "ichibot/budi1234/p113/buka";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
MFRC522 rfid(5, 4);
const int RELAY = 26;
const unsigned long LAMA_BUKA = 5000;
const char* KARTU_BOLEH[] = {"A3 4F 19 0B", "04 7C 2E 1A"};   // UID dari proyek 111
unsigned long bukaSampai = 0;

String bacaUID() {
  String uid;
  for (byte i = 0; i < rfid.uid.size; i++) {
    if (rfid.uid.uidByte[i] < 0x10) uid += "0";
    uid += String(rfid.uid.uidByte[i], HEX);
    if (i < rfid.uid.size - 1) uid += " ";
  }
  uid.toUpperCase();
  return uid;
}

bool boleh(String uid) {
  for (const char* k : KARTU_BOLEH) if (uid == k) return true;
  return false;
}

void buka(String oleh) {
  digitalWrite(RELAY, HIGH);
  bukaSampai = millis() + LAMA_BUKA;
  mqtt.publish(TOPIK_TERBUKA, "1");
  mqtt.publish(TOPIK_LOG, ("Dibuka: " + oleh).c_str());
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (p == "ON" && !bukaSampai) buka("dashboard");
}

void langganan() {
  mqtt.subscribe(TOPIK_BUKA);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(RELAY, OUTPUT);
  SPI.begin();
  rfid.PCD_Init();
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (bukaSampai && (long)(millis() - bukaSampai) >= 0) {
    bukaSampai = 0;
    digitalWrite(RELAY, LOW);
    mqtt.publish(TOPIK_TERBUKA, "0");
    mqtt.publish(TOPIK_BUKA, "OFF");
  }

  if (!rfid.PICC_IsNewCardPresent() || !rfid.PICC_ReadCardSerial()) return;
  String uid = bacaUID();
  rfid.PICC_HaltA();
  rfid.PCD_StopCrypto1();
  if (boleh(uid)) {
    if (!bukaSampai) buka("kartu " + uid);
  } else {
    mqtt.publish(TOPIK_LOG, ("DITOLAK: kartu " + uid).c_str());
  }
  delay(500);
}