Pembuka bab Keamanan: tempelkan kartu atau gantungan kunci RFID ke modul RC522, dan nomor unik kartu langsung muncul di Klenik. Proyek ini dasar untuk absensi (112) dan kunci pintu kartu (113). Catat nomor kartu-kartumu di sini dulu.

RC522 memancarkan medan radio 13,56 MHz lewat antena tembaga di papannya. Kartu RFID tidak punya baterai. Kumparan di dalam kartu mendapat daya dari medan itu, lalu chip kartu menjawab dengan nomor uniknya (UID), biasanya 4 byte. Jangkauannya hanya 2-4 cm, jadi kartu memang harus ditempelkan.

RC522 terhubung lewat SPI. ESP32 memakai pin SPI bawaannya (SCK 18, MOSI 23, MISO 19), ditambah SS (pilih chip) di GPIO5 dan RST di GPIO4. Modul ini hanya tahan 3,3V, jadi jangan disambung ke 5V.

UID diubah ke teks heksadesimal seperti A3 4F 19 0B. Setiap byte selalu ditulis dua huruf (nol di depan kalau perlu), supaya nomor kartu yang sama selalu menghasilkan teks yang persis sama.

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
RC522 RFID Reader Writer Module 13.56MHz Arduino	1	Rp17.500
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 7	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp96.000

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
RFID RC522 SDA	→	D5 GPIO5	kuning
RFID RC522 SCK	→	D18 GPIO18	hijau
RFID RC522 MOSI	→	D23 GPIO23	biru
RFID RC522 MISO	→	D19 GPIO19	ungu
RFID RC522 GND	→	GND	hitam
RFID RC522 RST	→	D4 GPIO4	oranye
RFID RC522 3V3	→	3V3	merah

Langkah 2: Siapkan dashboard Klenik

Kartu Terbacaichibot/budi1234/p111/kartu

A3 4F 19 0B

04 7C 2E 1A

A3 4F 19 0B

0 detik lalu

Jumlah Tapichibot/budi1234/p111/jumlah

0 detik lalu

Cara cepat: unduh p111.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Text Log Kartu Terbaca	`ichibot/KODE/p111/kartu`	menampilkan teks masuk
Gauge Jumlah Tap	`ichibot/KODE/p111/jumlah`	0–100 x

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary), MFRC522 (GithubCommunity). Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p111.inoUnduh .ino

// Proyek 111 - Pembaca Kartu RFID ke Dashboard
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <SPI.h>
#include <MFRC522.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_KARTU  = "ichibot/budi1234/p111/kartu";
const char* TOPIK_JUMLAH = "ichibot/budi1234/p111/jumlah";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PIN_SS = 5, PIN_RST = 4;    // SCK 18, MOSI 23, MISO 19 = SPI bawaan
MFRC522 rfid(PIN_SS, PIN_RST);
int jumlahTap = 0;

String bacaUID() {                    // nomor unik kartu, misalnya "A3 4F 19 0B"
  String uid;
  for (byte i = 0; i < rfid.uid.size; i++) {
    if (rfid.uid.uidByte[i] < 0x10) uid += "0";
    uid += String(rfid.uid.uidByte[i], HEX);
    if (i < rfid.uid.size - 1) uid += " ";
  }
  uid.toUpperCase();
  return uid;
}

void langganan() {}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  SPI.begin();
  rfid.PCD_Init();
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (!rfid.PICC_IsNewCardPresent() || !rfid.PICC_ReadCardSerial()) return;   // belum ada kartu

  String uid = bacaUID();
  jumlahTap++;
  Serial.println("Kartu: " + uid);
  mqtt.publish(TOPIK_KARTU, uid.c_str());
  mqtt.publish(TOPIK_JUMLAH, String(jumlahTap).c_str());

  rfid.PICC_HaltA();                  // selesai dengan kartu ini
  rfid.PCD_StopCrypto1();
  delay(1000);                        // kartu yang sama tidak terbaca berulang-ulang
}

// Proyek 111 - Pembaca Kartu RFID ke Dashboard
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <SPI.h>
#include <MFRC522.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_KARTU  = "ichibot/budi1234/p111/kartu";
const char* TOPIK_JUMLAH = "ichibot/budi1234/p111/jumlah";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PIN_SS = 5, PIN_RST = 4;    // SCK 18, MOSI 23, MISO 19 = SPI bawaan
MFRC522 rfid(PIN_SS, PIN_RST);
int jumlahTap = 0;

String bacaUID() {                    // nomor unik kartu, misalnya "A3 4F 19 0B"
  String uid;
  for (byte i = 0; i < rfid.uid.size; i++) {
    if (rfid.uid.uidByte[i] < 0x10) uid += "0";
    uid += String(rfid.uid.uidByte[i], HEX);
    if (i < rfid.uid.size - 1) uid += " ";
  }
  uid.toUpperCase();
  return uid;
}

void langganan() {}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  SPI.begin();
  rfid.PCD_Init();
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

if (!rfid.PICC_IsNewCardPresent() || !rfid.PICC_ReadCardSerial()) return;   // belum ada kartu

String uid = bacaUID();
  jumlahTap++;
  Serial.println("Kartu: " + uid);
  mqtt.publish(TOPIK_KARTU, uid.c_str());
  mqtt.publish(TOPIK_JUMLAH, String(jumlahTap).c_str());

rfid.PICC_HaltA();                  // selesai dengan kartu ini
  rfid.PCD_StopCrypto1();
  delay(1000);                        // kartu yang sama tidak terbaca berulang-ulang
}

Langkah 4: Pahami kodenya

Dua langkah: ada kartu baru di dekat antena, lalu nomor serialnya berhasil dibaca. Kalau salah satu gagal, loop() lanjut seperti biasa.
Byte di bawah 16 hanya punya satu huruf heksa (misalnya B). Nol di depan membuatnya 0B, jadi panjang teks selalu sama.
Menyuruh kartu "tidur" supaya tidak terbaca lagi sebelum diangkat dan ditempel ulang.