Status Rapat: Sibuk / Kosong di LCD

// Proyek 110 - Status Rapat: Sibuk / Kosong di LCD
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_SIBUK_STATUS = "ichibot/budi1234/p110/sibuk/status";
const char* TOPIK_SIBUK        = "ichibot/budi1234/p110/sibuk";
const char* TOPIK_KETERANGAN   = "ichibot/budi1234/p110/keterangan";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
LiquidCrystal_I2C lcd(0x27, 16, 2);
const int LED_MERAH = 25, LED_HIJAU = 26;
bool sibuk = false;
String keterangan = "Silakan masuk";

void tampilkan() {
  digitalWrite(LED_MERAH, sibuk);
  digitalWrite(LED_HIJAU, !sibuk);
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print(sibuk ? ">> SEDANG RAPAT" : "   RUANG KOSONG");
  lcd.setCursor(0, 1);
  lcd.print(keterangan.substring(0, 16));
  mqtt.publish(TOPIK_SIBUK_STATUS, sibuk ? "1" : "0", true);
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t;
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (topik == TOPIK_SIBUK) {
    sibuk = (p == "ON");
    keterangan = sibuk ? "Mohon tidak masuk" : "Silakan masuk";   // teks bawaan
  } else if (topik == TOPIK_KETERANGAN) {
    keterangan = p;                   // misalnya "Selesai 11.30"
  }
  tampilkan();
}

void langganan() {
  mqtt.subscribe(TOPIK_SIBUK);
  mqtt.subscribe(TOPIK_KETERANGAN);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(LED_MERAH, OUTPUT);
  pinMode(LED_HIJAU, OUTPUT);
  lcd.init();
  lcd.backlight();
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
  tampilkan();
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
}