Jam dinding digital merah dengan titik dua berkedip. Jamnya diambil dari internet sehingga selalu tepat, dan layarnya otomatis lebih redup di malam hari supaya tidak menyilaukan di kamar. Tingkat terang siang dan malam diatur dari Klenik.

Jam diambil lewat NTP seperti proyek 102. Jam dan menit digabung menjadi satu bilangan 4 digit: 14:05 menjadi 1405. Bilangan itu ditampilkan dengan showNumberDecEx(), yang juga mengatur titik dua di tengah. Titik dua dinyalakan pada detik ganjil dan dimatikan pada detik genap, sehingga terlihat berkedip.

Antara jam 21:00 dan 06:00 dipakai tingkat terang malam. Selama menunggu jam dari internet, layar menampilkan empat garis ---- yang digambar langsung per segmen dengan setSegments().

Komponen

Komponen	Qty	Harga
NodeMCU ESP8266 V3 (Lolin)	1	Rp42.000
TM1637 Seven Segment 4 Digit Modul	1	Rp9.500
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 4	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp55.000

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Display 7 segmen 4 digit TM1637 CLK	→	D1 GPIO5	kuning
Display 7 segmen 4 digit TM1637 DIO	→	D2 GPIO4	biru
Display 7 segmen 4 digit TM1637 VCC	→	3V	merah
Display 7 segmen 4 digit TM1637 GND	→	G	hitam

Langkah 2: Siapkan dashboard Klenik

Terang Siangichibot/budi1234/p107/siang

55 of 7

0 detik lalu

Terang Malamichibot/budi1234/p107/malam

11 of 7

0 detik lalu

Cara cepat: unduh p107.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Slider Output Terang Siang	`ichibot/KODE/p107/siang`	0–7
Slider Output Terang Malam	`ichibot/KODE/p107/malam`	0–7

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary), TM1637 (Avishay Orpaz). Board di Arduino IDE: NodeMCU 1.0 (ESP-12E Module). Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p107.inoUnduh .ino

// Proyek 107 - Jam Digital TM1637 + NTP
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <TM1637Display.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_SIANG = "ichibot/budi1234/p107/siang";
const char* TOPIK_MALAM = "ichibot/budi1234/p107/malam";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
TM1637Display angka(D1, D2);
int terangSiang = 5, terangMalam = 1;
int detikTadi = -1;

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t;
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (topik == TOPIK_SIANG) terangSiang = constrain(p.toInt(), 0, 7);
  else if (topik == TOPIK_MALAM) terangMalam = constrain(p.toInt(), 0, 7);
}

void langganan() {
  mqtt.subscribe(TOPIK_SIANG);
  mqtt.subscribe(TOPIK_MALAM);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  angka.setBrightness(4);
  const uint8_t garis[] = {SEG_G, SEG_G, SEG_G, SEG_G};
  angka.setSegments(garis);           // "----" selama menunggu jam
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org", "time.google.com");
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  time_t t = time(nullptr);
  if (t < 1700000000) return;
  struct tm* w = localtime(&t);
  if (w->tm_sec == detikTadi) return;
  detikTadi = w->tm_sec;

  bool malam = w->tm_hour >= 21 || w->tm_hour < 6;
  angka.setBrightness(malam ? terangMalam : terangSiang);
  uint8_t titikDua = (w->tm_sec % 2) ? 0b01000000 : 0;   // titik dua berkedip tiap detik
  angka.showNumberDecEx(w->tm_hour * 100 + w->tm_min, titikDua, true);
}

// Proyek 107 - Jam Digital TM1637 + NTP
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <TM1637Display.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_SIANG = "ichibot/budi1234/p107/siang";
const char* TOPIK_MALAM = "ichibot/budi1234/p107/malam";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
TM1637Display angka(D1, D2);
int terangSiang = 5, terangMalam = 1;
int detikTadi = -1;

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t;
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (topik == TOPIK_SIANG) terangSiang = constrain(p.toInt(), 0, 7);
  else if (topik == TOPIK_MALAM) terangMalam = constrain(p.toInt(), 0, 7);
}

void langganan() {
  mqtt.subscribe(TOPIK_SIANG);
  mqtt.subscribe(TOPIK_MALAM);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  angka.setBrightness(4);
  const uint8_t garis[] = {SEG_G, SEG_G, SEG_G, SEG_G};
  angka.setSegments(garis);           // "----" selama menunggu jam
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org", "time.google.com");
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

time_t t = time(nullptr);
  if (t < 1700000000) return;
  struct tm* w = localtime(&t);
  if (w->tm_sec == detikTadi) return;
  detikTadi = w->tm_sec;

bool malam = w->tm_hour >= 21 || w->tm_hour < 6;
  angka.setBrightness(malam ? terangMalam : terangSiang);
  uint8_t titikDua = (w->tm_sec % 2) ? 0b01000000 : 0;   // titik dua berkedip tiap detik
  angka.showNumberDecEx(w->tm_hour * 100 + w->tm_min, titikDua, true);
}

Langkah 4: Pahami kodenya

Bit ke-6 menyalakan titik dua pada modul TM1637 jam. % 2 bernilai 1 pada detik ganjil.
Parameter true menampilkan nol di depan, jadi jam 07:05 tampil 07:05, bukan 7:05.
SEG_G adalah batang tengah. Dengan setSegments() kamu bisa menggambar huruf sendiri, misalnya SEG_A | SEG_B | SEG_G untuk bagian atas angka 2.