Kirim teks dari HP, misalnya SELAMAT DATANG atau TOKO BUKA, dan teks itu berjalan di dot matrix merah 8×8. Satu modul sudah cukup untuk belajar, dan modul tambahan bisa disambung berderet untuk papan berjalan yang lebih lebar.

Dot matrix 8×8 berisi 64 LED. Chip MAX7219 di belakangnya menyimpan pola nyala setiap LED dan menyalakannya bergantian sangat cepat, sehingga ESP32 cukup mengirim data lewat SPI: DIN (data), CLK (detak), dan CS (pilih chip). Modul bisa disambung berantai (DOUT ke DIN modul berikutnya) untuk layar yang lebih panjang.

Pustaka MD_Parola mengurus huruf dan animasi geser. Kodenya cukup memanggil displayAnimate() di setiap loop(). Fungsi itu bernilai true saat teks sudah lewat seluruhnya. Teks baru dari dashboard tidak langsung dipasang, melainkan ditunggu sampai putaran selesai supaya animasinya tidak terpotong di tengah huruf.

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
MAX7219 Modul Dot Matrix 8×8 DIP Display LED Mer	1	Rp26.325
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 5	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp104.825

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Dot matrix 8×8 MAX7219 VCC	→	VIN	merah
Dot matrix 8×8 MAX7219 GND	→	GND	hitam
Dot matrix 8×8 MAX7219 DIN	→	D23 GPIO23	biru
Dot matrix 8×8 MAX7219 CS	→	D5 GPIO5	kuning
Dot matrix 8×8 MAX7219 CLK	→	D18 GPIO18	hijau

Langkah 2: Siapkan dashboard Klenik

Teks Berjalanichibot/budi1234/p108/teks

SELAMAT DATANG

Belum pernah dikirim

Kecepatan (kecil = cepat)ichibot/budi1234/p108/kecepatan

60 ms60 of 200 ms

0 detik lalu

Sedang Tampilichibot/budi1234/p108/tampil

SELAMAT DATANG

TOKO BUKA 08.00-17.00

0 detik lalu

Cara cepat: unduh p108.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
TEXT_INPUT Teks Berjalan	`ichibot/KODE/p108/teks`	teks bebas
Slider Output Kecepatan (kecil = cepat)	`ichibot/KODE/p108/kecepatan`	20–200 ms
Text Log Sedang Tampil	`ichibot/KODE/p108/tampil`	menampilkan teks masuk

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary), MD_Parola, MD_MAX72XX. Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p108.inoUnduh .ino

// Proyek 108 - Teks Berjalan Dot Matrix
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <MD_Parola.h>
#include <MD_MAX72xx.h>
#include <SPI.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_TEKS      = "ichibot/budi1234/p108/teks";
const char* TOPIK_KECEPATAN = "ichibot/budi1234/p108/kecepatan";
const char* TOPIK_TAMPIL    = "ichibot/budi1234/p108/tampil";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
#define JENIS_MODUL MD_MAX72XX::GENERIC_HW   // ganti FC16_HW kalau huruf terbalik
const int PIN_CS = 5, JUMLAH_MODUL = 1;      // DIN = GPIO23, CLK = GPIO18 (SPI)
MD_Parola matriks = MD_Parola(JENIS_MODUL, PIN_CS, JUMLAH_MODUL);
char teks[120] = "Halo Ichibot!";
char baru[120] = "";
int kecepatan = 60;                   // ms per langkah geser, kecil = cepat

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t;
  if (topik == TOPIK_TEKS) {
    unsigned int n = min(panjang, (unsigned int)sizeof(baru) - 1);
    memcpy(baru, isi, n);
    baru[n] = 0;                      // disalin saat animasi selesai
  } else if (topik == TOPIK_KECEPATAN) {
    String p;
    for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
    kecepatan = constrain(p.toInt(), 20, 200);
    matriks.setSpeed(kecepatan);
  }
}

void langganan() {
  mqtt.subscribe(TOPIK_TEKS);
  mqtt.subscribe(TOPIK_KECEPATAN);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  matriks.begin();
  matriks.setIntensity(4);            // 0..15
  matriks.displayText(teks, PA_LEFT, kecepatan, 0, PA_SCROLL_LEFT, PA_SCROLL_LEFT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (matriks.displayAnimate()) {     // true = satu putaran teks selesai
    if (baru[0]) {
      strcpy(teks, baru);
      baru[0] = 0;
      mqtt.publish(TOPIK_TAMPIL, teks);
    }
    matriks.displayReset();
  }
}

// Proyek 108 - Teks Berjalan Dot Matrix
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <MD_Parola.h>
#include <MD_MAX72xx.h>
#include <SPI.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_TEKS      = "ichibot/budi1234/p108/teks";
const char* TOPIK_KECEPATAN = "ichibot/budi1234/p108/kecepatan";
const char* TOPIK_TAMPIL    = "ichibot/budi1234/p108/tampil";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
#define JENIS_MODUL MD_MAX72XX::GENERIC_HW   // ganti FC16_HW kalau huruf terbalik
const int PIN_CS = 5, JUMLAH_MODUL = 1;      // DIN = GPIO23, CLK = GPIO18 (SPI)
MD_Parola matriks = MD_Parola(JENIS_MODUL, PIN_CS, JUMLAH_MODUL);
char teks[120] = "Halo Ichibot!";
char baru[120] = "";
int kecepatan = 60;                   // ms per langkah geser, kecil = cepat

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t;
  if (topik == TOPIK_TEKS) {
    unsigned int n = min(panjang, (unsigned int)sizeof(baru) - 1);
    memcpy(baru, isi, n);
    baru[n] = 0;                      // disalin saat animasi selesai
  } else if (topik == TOPIK_KECEPATAN) {
    String p;
    for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
    kecepatan = constrain(p.toInt(), 20, 200);
    matriks.setSpeed(kecepatan);
  }
}

void langganan() {
  mqtt.subscribe(TOPIK_TEKS);
  mqtt.subscribe(TOPIK_KECEPATAN);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  matriks.begin();
  matriks.setIntensity(4);            // 0..15
  matriks.displayText(teks, PA_LEFT, kecepatan, 0, PA_SCROLL_LEFT, PA_SCROLL_LEFT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

if (matriks.displayAnimate()) {     // true = satu putaran teks selesai
    if (baru[0]) {
      strcpy(teks, baru);
      baru[0] = 0;
      mqtt.publish(TOPIK_TAMPIL, teks);
    }
    matriks.displayReset();
  }
}

Langkah 4: Pahami kodenya

Pabrik modul memasang LED dengan arah berbeda-beda. Kalau huruf terlihat terbalik atau tercermin, coba FC16_HW, PAROLA_HW, atau ICSTATION_HW.
DIN dan CLK memakai pin SPI bawaan ESP32 (23 dan 18), jadi hanya CS yang ditulis. Ubah JUMLAH_MODUL kalau memasang beberapa modul berderet.
Teks dari MQTT bukan teks C biasa karena tidak berakhir dengan angka 0. Angka 0 ditambahkan supaya strcpy() tahu di mana teks berakhir.