Angka merah besar 4 digit yang bisa ditambah, dikurangi, atau diisi langsung dari HP. Cocok untuk penghitung pengunjung, stok barang, atau hitung mundur hari menuju acara. Terangnya juga bisa diatur dari Klenik.

Setiap digit 7 segmen terdiri dari 7 batang LED (a sampai g) yang dinyalakan bergantian untuk membentuk angka. Untuk empat digit saja dibutuhkan puluhan LED. Chip TM1637 di belakang modul mengurus semua itu, jadi NodeMCU cukup mengirim angka lewat dua kabel: CLK (detak) dan DIO (data).

Pustaka TM1637Display menyediakan showNumberDec() yang langsung menampilkan bilangan bulat. Angka dibatasi -999 sampai 9999 karena hanya ada 4 digit, dan untuk angka negatif tanda minus memakai satu digit. Setiap perubahan dikirim kembali ke dashboard dengan flag retained.

Urutan pin modul (CLK, DIO, VCC, GND) sama dengan urutan D1, D2, 3V, G di NodeMCU, jadi keempat kabelnya lurus sejajar.

Komponen

Komponen	Qty	Harga
NodeMCU ESP8266 V3 (Lolin)	1	Rp42.000
TM1637 Seven Segment 4 Digit Modul	1	Rp9.500
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 4	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp55.000

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Display 7 segmen 4 digit TM1637 CLK	→	D1 GPIO5	kuning
Display 7 segmen 4 digit TM1637 DIO	→	D2 GPIO4	biru
Display 7 segmen 4 digit TM1637 VCC	→	3V	merah
Display 7 segmen 4 digit TM1637 GND	→	G	hitam

Langkah 2: Siapkan dashboard Klenik

Tambah 1ichibot/budi1234/p106/tambah

0 detik lalu

Kurangi 1ichibot/budi1234/p106/kurang

−1

0 detik lalu

Atur Angkaichibot/budi1234/p106/atur

250

Belum pernah dikirim

Kecerahanichibot/budi1234/p106/terang

44 of 7

0 detik lalu

Hitunganichibot/budi1234/p106/hitungan

0 detik lalu

Cara cepat: unduh p106.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Switch Tambah 1	`ichibot/KODE/p106/tambah`	payload ON / OFF
Switch Kurangi 1	`ichibot/KODE/p106/kurang`	payload ON / OFF
TEXT_INPUT Atur Angka	`ichibot/KODE/p106/atur`	teks bebas
Slider Output Kecerahan	`ichibot/KODE/p106/terang`	0–7
Gauge Hitungan	`ichibot/KODE/p106/hitungan`	0–9999

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary), TM1637 (Avishay Orpaz). Board di Arduino IDE: NodeMCU 1.0 (ESP-12E Module). Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p106.inoUnduh .ino

// Proyek 106 - Penghitung 7 Segmen TM1637
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <TM1637Display.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_HITUNGAN = "ichibot/budi1234/p106/hitungan";
const char* TOPIK_TAMBAH   = "ichibot/budi1234/p106/tambah";
const char* TOPIK_KURANG   = "ichibot/budi1234/p106/kurang";
const char* TOPIK_ATUR     = "ichibot/budi1234/p106/atur";
const char* TOPIK_TERANG   = "ichibot/budi1234/p106/terang";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
TM1637Display angka(D1, D2);          // CLK, DIO
int hitungan = 0;

void tampilkan() {
  angka.showNumberDec(hitungan, false);   // false = tanpa nol di depan
  mqtt.publish(TOPIK_HITUNGAN, String(hitungan).c_str(), true);
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t;
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (topik == TOPIK_TAMBAH && p == "ON") { hitungan++; mqtt.publish(TOPIK_TAMBAH, "OFF"); }
  else if (topik == TOPIK_KURANG && p == "ON") { hitungan--; mqtt.publish(TOPIK_KURANG, "OFF"); }
  else if (topik == TOPIK_ATUR) hitungan = p.toInt();
  else if (topik == TOPIK_TERANG) angka.setBrightness(constrain(p.toInt(), 0, 7));
  else return;
  hitungan = constrain(hitungan, -999, 9999);   // batas 4 digit
  tampilkan();
}

void langganan() {
  mqtt.subscribe(TOPIK_TAMBAH);
  mqtt.subscribe(TOPIK_KURANG);
  mqtt.subscribe(TOPIK_ATUR);
  mqtt.subscribe(TOPIK_TERANG);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  angka.setBrightness(4);             // 0 (redup) .. 7 (terang)
  angka.showNumberDec(0);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
}

// Proyek 106 - Penghitung 7 Segmen TM1637
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <TM1637Display.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_HITUNGAN = "ichibot/budi1234/p106/hitungan";
const char* TOPIK_TAMBAH   = "ichibot/budi1234/p106/tambah";
const char* TOPIK_KURANG   = "ichibot/budi1234/p106/kurang";
const char* TOPIK_ATUR     = "ichibot/budi1234/p106/atur";
const char* TOPIK_TERANG   = "ichibot/budi1234/p106/terang";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
TM1637Display angka(D1, D2);          // CLK, DIO
int hitungan = 0;

void tampilkan() {
  angka.showNumberDec(hitungan, false);   // false = tanpa nol di depan
  mqtt.publish(TOPIK_HITUNGAN, String(hitungan).c_str(), true);
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t;
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (topik == TOPIK_TAMBAH && p == "ON") { hitungan++; mqtt.publish(TOPIK_TAMBAH, "OFF"); }
  else if (topik == TOPIK_KURANG && p == "ON") { hitungan--; mqtt.publish(TOPIK_KURANG, "OFF"); }
  else if (topik == TOPIK_ATUR) hitungan = p.toInt();
  else if (topik == TOPIK_TERANG) angka.setBrightness(constrain(p.toInt(), 0, 7));
  else return;
  hitungan = constrain(hitungan, -999, 9999);   // batas 4 digit
  tampilkan();
}

void langganan() {
  mqtt.subscribe(TOPIK_TAMBAH);
  mqtt.subscribe(TOPIK_KURANG);
  mqtt.subscribe(TOPIK_ATUR);
  mqtt.subscribe(TOPIK_TERANG);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  angka.setBrightness(4);             // 0 (redup) .. 7 (terang)
  angka.showNumberDec(0);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
}

Langkah 4: Pahami kodenya

Dua pin apa saja bisa dipakai. TM1637 bukan I2C walaupun sama-sama dua kabel, jadi tidak perlu pin SDA/SCL khusus.
Ganti false menjadi true untuk menampilkan 0042 alih-alih 42.
Topic yang tidak dikenal tidak membuat layar digambar ulang.