Servo membuka penutup wadah pakan pada jam makan, misalnya 07:00,17:00, lalu menutupnya lagi. Banyaknya pakan diatur dengan jumlah porsi. Kalau lupa atau sedang pergi, beri makan dari HP dengan sekali tekan, dan setiap pemberian makan tercatat di Klenik.

Wadahnya bisa dibuat dari botol plastik terbalik dengan lubang di tutupnya. Lengan servo dipasang sebagai penutup lubang itu. Pada sudut 0° lubang tertutup, pada 70° terbuka, dan pakan jatuh selama terbuka. Satu porsi adalah satu kali buka-tutup 0,4 detik. Ubah sudut dan lama buka sesuai ukuran lubang dan pakanmu.

Jadwal bekerja seperti bel sekolah (proyek 057): jam dari internet, dicek setiap menit, dan daftar jam disimpan di broker (retained) supaya tidak hilang saat listrik padam. Switch Beri Makan Sekarang menjalankan satu kali pemberian makan, lalu kembali ke OFF sendiri.

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
Servo MG90 Metal Gear Micro 9g Tower Pro 180 Der	1	Rp33.950
Kabel jumper male-female 10 cm (isi 10)isi 10, terpakai 3	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp112.450

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Servo MG90 (coklat −, merah +, oranye S) −	→	GND	coklat
Servo MG90 (coklat −, merah +, oranye S) +	→	VIN	merah
Servo MG90 (coklat −, merah +, oranye S) S	→	D13 GPIO13	oranye

Langkah 2: Siapkan dashboard Klenik

Jadwal Makanichibot/budi1234/p092/jadwal

07:00,17:00

Belum pernah dikirim

Porsiichibot/budi1234/p092/porsi

2x2 of 5x

0 detik lalu

Beri Makan Sekarangichibot/budi1234/p092/sekarang

Beri makan

0 detik lalu

Catatan Makanichibot/budi1234/p092/log

07:00 Diberi makan 2 porsi (jadwal)

12:31 Diberi makan 1 porsi (manual)

17:00 Diberi makan 2 porsi (jadwal)

0 detik lalu

Cara cepat: unduh p092.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
TEXT_INPUT Jadwal Makan	`ichibot/KODE/p092/jadwal`	teks bebas
Slider Output Porsi	`ichibot/KODE/p092/porsi`	1–5 x
Switch Beri Makan Sekarang	`ichibot/KODE/p092/sekarang`	payload ON / OFF
Text Log Catatan Makan	`ichibot/KODE/p092/log`	menampilkan teks masuk

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary), ESP32Servo. Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p092.inoUnduh .ino

// Proyek 092 - Pemberi Makan Kucing/Ikan Otomatis
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <ESP32Servo.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LOG      = "ichibot/budi1234/p092/log";
const char* TOPIK_JADWAL   = "ichibot/budi1234/p092/jadwal";
const char* TOPIK_SEKARANG = "ichibot/budi1234/p092/sekarang";
const char* TOPIK_PORSI    = "ichibot/budi1234/p092/porsi";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
Servo servo;
const int PIN_SERVO = 13;
const int TUTUP = 0, BUKA = 70;       // sudut penutup wadah pakan
String jadwal = "07:00,17:00";
int porsi = 2;                        // berapa kali buka-tutup per jadwal
String menitTadi = "";

String jamSekarang() {
  time_t t = time(nullptr);
  char buf[6];
  strftime(buf, sizeof(buf), "%H:%M", localtime(&t));
  return String(buf);
}

void beriMakan(const char* sebab) {
  for (int i = 0; i < porsi; i++) {
    servo.write(BUKA);
    delay(400);                       // pakan jatuh selama penutup terbuka
    servo.write(TUTUP);
    delay(400);
  }
  mqtt.publish(TOPIK_LOG, (jamSekarang() + " Diberi makan " + String(porsi) + " porsi (" + sebab + ")").c_str());
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t;
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  p.trim();
  if (topik == TOPIK_JADWAL && p.length() && p != jadwal) {
    jadwal = p;
    mqtt.publish(TOPIK_JADWAL, jadwal.c_str(), true);
    mqtt.publish(TOPIK_LOG, ("Jadwal makan: " + jadwal).c_str());
  } else if (topik == TOPIK_PORSI) {
    porsi = constrain(p.toInt(), 1, 5);
  } else if (topik == TOPIK_SEKARANG && p == "ON") {
    beriMakan("manual");
    mqtt.publish(TOPIK_SEKARANG, "OFF");
  }
}

void langganan() {
  mqtt.subscribe(TOPIK_JADWAL);
  mqtt.subscribe(TOPIK_PORSI);
  mqtt.subscribe(TOPIK_SEKARANG);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  servo.setPeriodHertz(50);
  servo.attach(PIN_SERVO, 500, 2400);
  servo.write(TUTUP);
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org");
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (time(nullptr) < 1700000000) return;
  String menit = jamSekarang();
  if (menit != menitTadi) {
    menitTadi = menit;
    if (("," + jadwal + ",").indexOf("," + menit + ",") >= 0) beriMakan("jadwal");
  }
}

// Proyek 092 - Pemberi Makan Kucing/Ikan Otomatis
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <ESP32Servo.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LOG      = "ichibot/budi1234/p092/log";
const char* TOPIK_JADWAL   = "ichibot/budi1234/p092/jadwal";
const char* TOPIK_SEKARANG = "ichibot/budi1234/p092/sekarang";
const char* TOPIK_PORSI    = "ichibot/budi1234/p092/porsi";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
Servo servo;
const int PIN_SERVO = 13;
const int TUTUP = 0, BUKA = 70;       // sudut penutup wadah pakan
String jadwal = "07:00,17:00";
int porsi = 2;                        // berapa kali buka-tutup per jadwal
String menitTadi = "";

String jamSekarang() {
  time_t t = time(nullptr);
  char buf[6];
  strftime(buf, sizeof(buf), "%H:%M", localtime(&t));
  return String(buf);
}

void beriMakan(const char* sebab) {
  for (int i = 0; i < porsi; i++) {
    servo.write(BUKA);
    delay(400);                       // pakan jatuh selama penutup terbuka
    servo.write(TUTUP);
    delay(400);
  }
  mqtt.publish(TOPIK_LOG, (jamSekarang() + " Diberi makan " + String(porsi) + " porsi (" + sebab + ")").c_str());
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t;
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  p.trim();
  if (topik == TOPIK_JADWAL && p.length() && p != jadwal) {
    jadwal = p;
    mqtt.publish(TOPIK_JADWAL, jadwal.c_str(), true);
    mqtt.publish(TOPIK_LOG, ("Jadwal makan: " + jadwal).c_str());
  } else if (topik == TOPIK_PORSI) {
    porsi = constrain(p.toInt(), 1, 5);
  } else if (topik == TOPIK_SEKARANG && p == "ON") {
    beriMakan("manual");
    mqtt.publish(TOPIK_SEKARANG, "OFF");
  }
}

void langganan() {
  mqtt.subscribe(TOPIK_JADWAL);
  mqtt.subscribe(TOPIK_PORSI);
  mqtt.subscribe(TOPIK_SEKARANG);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  servo.setPeriodHertz(50);
  servo.attach(PIN_SERVO, 500, 2400);
  servo.write(TUTUP);
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org");
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

if (time(nullptr) < 1700000000) return;
  String menit = jamSekarang();
  if (menit != menitTadi) {
    menitTadi = menit;
    if (("," + jadwal + ",").indexOf("," + menit + ",") >= 0) beriMakan("jadwal");
  }
}

Langkah 4: Pahami kodenya

Dua sudut kerja servo. Pasang lengan servo saat posisi TUTUP (upload dulu, baru pasang lengan), supaya lengan benar-benar menutup lubang.
Satu porsi = satu kali buka-tutup. Di sini delay() boleh dipakai karena prosesnya singkat (kurang dari 4 detik untuk 5 porsi).
Porsi dibatasi 1-5 supaya salah geser slider tidak mengosongkan wadah.