Dekatkan tangan ke sensor, dan tutup tempat sampah terbuka sendiri, lalu menutup lagi 3 detik setelah tangan menjauh. Tidak perlu menyentuh tutup yang kotor. Klenik menghitung berapa kali tempat sampah dipakai.

HC-SR04 di depan tutup mengukur jarak 10 kali per detik, seperti proyek 043. Kalau ada benda lebih dekat dari 15 cm, servo memutar tutup ke 100°. Selama tangan masih di depan sensor, waktu tutup terus diundur, jadi tutup tidak menjepit tangan yang sedang membuang sampah. Begitu tangan pergi, tutup menunggu 3 detik lalu kembali ke 0°.

Lengan servo dipasang ke engsel tutup dengan kawat atau lengan servo yang lebih panjang. Tutup yang berat butuh servo bertorsi besar. MG90 dengan gear logam cukup untuk tutup plastik ringan tempat sampah kecil.

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
Servo MG90 Metal Gear Micro 9g Tower Pro 180 Der	1	Rp33.950
Sensor ultrasonik HC-SR04	1	Rp15.520
Resistor 1K (isi 10)isi 10, terpakai 1	1	Rp1.800
Resistor 2K (isi 10)isi 10, terpakai 1	1	Rp1.800
Breadboard mini 170 titik	1	Rp4.875
Kabel jumper male-female 10 cm (isi 10)isi 10, terpakai 7	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp136.445

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
HC-SR04 + pembagi tegangan (1K seri, 2K ke GND) di ECHO VCC	→	VIN	merah
HC-SR04 + pembagi tegangan (1K seri, 2K ke GND) di ECHO TRIG	→	D5 GPIO5	kuning
HC-SR04 + pembagi tegangan (1K seri, 2K ke GND) di ECHO ECHO	→	D18 GPIO18	hijau
HC-SR04 + pembagi tegangan (1K seri, 2K ke GND) di ECHO GND	→	GND	hitam
Servo MG90 (coklat −, merah +, oranye S) −	→	GND	coklat
Servo MG90 (coklat −, merah +, oranye S) +	→	VIN	merah
Servo MG90 (coklat −, merah +, oranye S) S	→	D13 GPIO13	oranye

Langkah 2: Siapkan dashboard Klenik

Tutupichibot/budi1234/p093/tutup

TERBUKA

0 detik lalu

Dipakai (sejak menyala)ichibot/budi1234/p093/jumlah

0 detik lalu

Cara cepat: unduh p093.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Indikator Boolean Tutup	`ichibot/KODE/p093/tutup`	ON = `1` “TERBUKA”, OFF = `0`
Gauge Dipakai (sejak menyala)	`ichibot/KODE/p093/jumlah`	0–100 x

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary), ESP32Servo. Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p093.inoUnduh .ino

// Proyek 093 - Tempat Sampah Buka Sendiri
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <ESP32Servo.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_TUTUP  = "ichibot/budi1234/p093/tutup";
const char* TOPIK_JUMLAH = "ichibot/budi1234/p093/jumlah";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
Servo servo;
const int TRIG = 5, ECHO = 18, PIN_SERVO = 13;
const int TUTUP = 0, BUKA = 100;
const float JARAK_TANGAN = 15;        // cm
const unsigned long LAMA_BUKA = 3000;
bool terbuka = false;
unsigned long tutupPada = 0, ukurTerakhir = 0;
int jumlahBuka = 0;

float ukurCm() {
  digitalWrite(TRIG, LOW);  delayMicroseconds(2);
  digitalWrite(TRIG, HIGH); delayMicroseconds(10);
  digitalWrite(TRIG, LOW);
  unsigned long us = pulseIn(ECHO, HIGH, 30000);
  if (us == 0) return -1;
  return us * 0.0343 / 2;
}

void langganan() {}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(TRIG, OUTPUT);
  pinMode(ECHO, INPUT);
  servo.setPeriodHertz(50);
  servo.attach(PIN_SERVO, 500, 2400);
  servo.write(TUTUP);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (millis() - ukurTerakhir < 100) return;
  ukurTerakhir = millis();

  float cm = ukurCm();
  bool adaTangan = cm > 0 && cm < JARAK_TANGAN;
  if (adaTangan) {
    tutupPada = millis() + LAMA_BUKA;  // selama tangan ada, waktu tutup terus diperpanjang
    if (!terbuka) {
      terbuka = true;
      servo.write(BUKA);
      jumlahBuka++;
      mqtt.publish(TOPIK_TUTUP, "1");
      mqtt.publish(TOPIK_JUMLAH, String(jumlahBuka).c_str());
    }
  }
  if (terbuka && (long)(millis() - tutupPada) >= 0) {
    terbuka = false;
    servo.write(TUTUP);
    mqtt.publish(TOPIK_TUTUP, "0");
  }
}

// Proyek 093 - Tempat Sampah Buka Sendiri
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <ESP32Servo.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_TUTUP  = "ichibot/budi1234/p093/tutup";
const char* TOPIK_JUMLAH = "ichibot/budi1234/p093/jumlah";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
Servo servo;
const int TRIG = 5, ECHO = 18, PIN_SERVO = 13;
const int TUTUP = 0, BUKA = 100;
const float JARAK_TANGAN = 15;        // cm
const unsigned long LAMA_BUKA = 3000;
bool terbuka = false;
unsigned long tutupPada = 0, ukurTerakhir = 0;
int jumlahBuka = 0;

float ukurCm() {
  digitalWrite(TRIG, LOW);  delayMicroseconds(2);
  digitalWrite(TRIG, HIGH); delayMicroseconds(10);
  digitalWrite(TRIG, LOW);
  unsigned long us = pulseIn(ECHO, HIGH, 30000);
  if (us == 0) return -1;
  return us * 0.0343 / 2;
}

void langganan() {}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(TRIG, OUTPUT);
  pinMode(ECHO, INPUT);
  servo.setPeriodHertz(50);
  servo.attach(PIN_SERVO, 500, 2400);
  servo.write(TUTUP);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

if (millis() - ukurTerakhir < 100) return;
  ukurTerakhir = millis();

float cm = ukurCm();
  bool adaTangan = cm > 0 && cm < JARAK_TANGAN;
  if (adaTangan) {
    tutupPada = millis() + LAMA_BUKA;  // selama tangan ada, waktu tutup terus diperpanjang
    if (!terbuka) {
      terbuka = true;
      servo.write(BUKA);
      jumlahBuka++;
      mqtt.publish(TOPIK_TUTUP, "1");
      mqtt.publish(TOPIK_JUMLAH, String(jumlahBuka).c_str());
    }
  }
  if (terbuka && (long)(millis() - tutupPada) >= 0) {
    terbuka = false;
    servo.write(TUTUP);
    mqtt.publish(TOPIK_TUTUP, "0");
  }
}

Langkah 4: Pahami kodenya

Setiap kali tangan terdeteksi, waktu tutup diundur 3 detik lagi. Tutup hanya menutup setelah 3 detik tanpa tangan.
cm > 0 membuang hasil -1 (tidak ada pantulan), supaya tidak dianggap ada tangan.
Sudut tutup dan buka. Coba dulu tanpa tutup terpasang, lalu sesuaikan dengan engsel tempat sampahmu.