Pembuka bab Servo & Motor: geser slider di Klenik dan lengan servo MG90 berputar ke sudut yang sama, 0 sampai 180 derajat. Gerakannya dibuat halus, tidak melompat, dan posisi akhirnya dilaporkan kembali ke dashboard.

Servo adalah motor kecil dengan gearbox dan pengendali posisi di dalamnya. Posisinya diatur dengan lebar pulsa yang dikirim setiap 20 ms: sekitar 0,5 ms berarti 0°, 1,45 ms berarti 90°, dan 2,4 ms berarti 180°. Pustaka ESP32Servo membuat pulsa itu memakai PWM hardware ESP32, jadi kamu cukup memanggil servo.write(sudut).

Kalau langsung disuruh ke sudut tujuan, servo melompat dengan kecepatan penuh dan menarik arus besar sesaat. Di sini sudut digeser 1° setiap 10 ms, jadi 180° ditempuh dalam ±1,8 detik dengan gerakan halus.

Kabel servo: coklat GND, merah 5V (VIN), oranye sinyal ke GPIO13. MG90 bisa menarik arus hingga ±700 mA saat tertahan, jadi pakai adaptor 5V 2A kalau ESP32 sering restart.

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
Servo MG90 Metal Gear Micro 9g Tower Pro 180 Der	1	Rp33.950
Kabel jumper male-female 10 cm (isi 10)isi 10, terpakai 3	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp112.450

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Servo MG90 (coklat −, merah +, oranye S) −	→	GND	coklat
Servo MG90 (coklat −, merah +, oranye S) +	→	VIN	merah
Servo MG90 (coklat −, merah +, oranye S) S	→	D13 GPIO13	oranye

Langkah 2: Siapkan dashboard Klenik

Sudut Servoichibot/budi1234/p091/sudut

90°90 of 180°

0 detik lalu

Posisiichibot/budi1234/p091/posisi

0 detik lalu

Cara cepat: unduh p091.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Slider Output Sudut Servo	`ichibot/KODE/p091/sudut`	0–180 °
Gauge Posisi	`ichibot/KODE/p091/posisi`	0–180 °

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary), ESP32Servo. Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p091.inoUnduh .ino

// Proyek 091 - Servo Diputar dari Slider HP
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <ESP32Servo.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_SUDUT  = "ichibot/budi1234/p091/sudut";
const char* TOPIK_POSISI = "ichibot/budi1234/p091/posisi";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
Servo servo;
const int PIN_SERVO = 13;
int sudutTujuan = 90, sudutSekarang = 90;
unsigned long langkahTerakhir = 0;

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  sudutTujuan = constrain(p.toInt(), 0, 180);
}

void langganan() {
  mqtt.subscribe(TOPIK_SUDUT);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  servo.setPeriodHertz(50);           // servo standar: pulsa setiap 20 ms
  servo.attach(PIN_SERVO, 500, 2400); // lebar pulsa 0,5 ms = 0°, 2,4 ms = 180°
  servo.write(sudutSekarang);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  // bergerak 1° setiap 10 ms supaya halus, bukan melompat
  if (sudutSekarang != sudutTujuan && millis() - langkahTerakhir >= 10) {
    langkahTerakhir = millis();
    sudutSekarang += (sudutTujuan > sudutSekarang) ? 1 : -1;
    servo.write(sudutSekarang);
    if (sudutSekarang == sudutTujuan) mqtt.publish(TOPIK_POSISI, String(sudutSekarang).c_str());
  }
}

// Proyek 091 - Servo Diputar dari Slider HP
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <ESP32Servo.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_SUDUT  = "ichibot/budi1234/p091/sudut";
const char* TOPIK_POSISI = "ichibot/budi1234/p091/posisi";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
Servo servo;
const int PIN_SERVO = 13;
int sudutTujuan = 90, sudutSekarang = 90;
unsigned long langkahTerakhir = 0;

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  sudutTujuan = constrain(p.toInt(), 0, 180);
}

void langganan() {
  mqtt.subscribe(TOPIK_SUDUT);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  servo.setPeriodHertz(50);           // servo standar: pulsa setiap 20 ms
  servo.attach(PIN_SERVO, 500, 2400); // lebar pulsa 0,5 ms = 0°, 2,4 ms = 180°
  servo.write(sudutSekarang);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

// bergerak 1° setiap 10 ms supaya halus, bukan melompat
  if (sudutSekarang != sudutTujuan && millis() - langkahTerakhir >= 10) {
    langkahTerakhir = millis();
    sudutSekarang += (sudutTujuan > sudutSekarang) ? 1 : -1;
    servo.write(sudutSekarang);
    if (sudutSekarang == sudutTujuan) mqtt.publish(TOPIK_POSISI, String(sudutSekarang).c_str());
  }
}

Langkah 4: Pahami kodenya

Batas lebar pulsa dalam mikrodetik untuk 0° dan 180°. Kalau servo bergetar atau berbunyi di ujung, persempit menjadi 600-2300.
Satu langkah ke arah tujuan. Ubah jeda 10 ms untuk mengatur kecepatan: 5 ms lebih cepat, 20 ms lebih lambat.
Posisi dilaporkan sekali saat servo sampai, bukan setiap derajat, supaya broker tidak dibanjiri pesan.