LDR memantau lampu ruangan. Kalau lampu tiba-tiba padam karena listrik PLN mati, relay langsung menyalakan lampu darurat bertenaga baterai, lalu mematikannya lagi begitu listrik kembali. Alat ini tetap bekerja walaupun WiFi ikut mati.

Saat listrik padam, router WiFi juga mati. Karena itu proyek ini tidak memakai sambungWiFi() dan sambungMQTT() dari blok umum, yang menunggu sampai tersambung. Kalau dipakai, lampu darurat tidak akan menyala sebelum WiFi kembali. ESP32 hanya memulai WiFi lalu langsung lanjut. Koneksi ke Klenik dicoba setiap 10 detik, dan logika lampu tetap berjalan di setiap putaran.

LDR dibaca terus. Gelap yang bertahan 2 detik dianggap lampu padam, karena bayangan orang lewat tidak bertahan selama itu. Lampu darurat padam saat ruangan terang lagi atau setelah 30 menit untuk menghemat baterai.

ESP32 dan lampu darurat harus mendapat daya dari power bank atau baterai, bukan dari colokan PLN. Matikan switch Siaga di siang hari, saat lampu ruangan memang sengaja dimatikan.

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
Modul sensor cahaya LDR	1	Rp7.200
Modul relay 1 channel 5V	1	Rp17.000
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 6	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp102.700

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Modul LDR KY-018 S	→	D34 GPIO34	kuning
Modul LDR KY-018 +	→	3V3	merah
Modul LDR KY-018 −	→	GND	hitam
Relay 1 ch 5V (jumper H) DC+	→	VIN	oranye
Relay 1 ch 5V (jumper H) DC−	→	GND	hitam
Relay 1 ch 5V (jumper H) IN	→	D26 GPIO26	biru

Langkah 2: Siapkan dashboard Klenik

Mode Siagaichibot/budi1234/p090/siaga

Siaga

0 detik lalu

Lampu Daruratichibot/budi1234/p090/darurat

MENYALA

0 detik lalu

Bacaan LDRichibot/budi1234/p090/ldr

0 detik lalu

Cara cepat: unduh p090.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Switch Mode Siaga	`ichibot/KODE/p090/siaga`	payload ON / OFF
Indikator Boolean Lampu Darurat	`ichibot/KODE/p090/darurat`	ON = `1` “MENYALA”, OFF = `0`
Gauge Bacaan LDR	`ichibot/KODE/p090/ldr`	0–4095

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p090.inoUnduh .ino

// Proyek 090 - Lampu Darurat Saat Listrik Padam
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_DARURAT = "ichibot/budi1234/p090/darurat";
const char* TOPIK_SIAGA   = "ichibot/budi1234/p090/siaga";
const char* TOPIK_LDR     = "ichibot/budi1234/p090/ldr";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PIN_LDR = 34, RELAY = 26;
const int GELAP = 3000;               // angka LDR di atas ini = lampu ruangan padam
const unsigned long LAMA_DARURAT = 30UL * 60 * 1000;   // hemat baterai: maks 30 menit
bool siaga = true, darurat = false;
unsigned long gelapSejak = 0, daruratSejak = 0, cobaMQTT = 0, kirimTerakhir = 0;

void aturDarurat(bool v) {
  darurat = v;
  digitalWrite(RELAY, v ? HIGH : LOW);
  if (v) daruratSejak = millis();
  if (mqtt.connected()) mqtt.publish(TOPIK_DARURAT, v ? "1" : "0", true);
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  siaga = (p == "ON");
  if (!siaga && darurat) aturDarurat(false);
}

void langganan() {
  mqtt.subscribe(TOPIK_SIAGA);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(RELAY, OUTPUT);
  WiFi.begin(WIFI_NAMA, WIFI_PASS);   // tidak menunggu: lampu darurat harus jalan tanpa WiFi
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  // koneksi dicoba sesekali saja, supaya logika lampu tidak pernah tertahan
  if (WiFi.status() == WL_CONNECTED && !mqtt.connected() && millis() - cobaMQTT > 10000) {
    cobaMQTT = millis();
    if (mqtt.connect(WiFi.macAddress().c_str())) langganan();
  }
  mqtt.loop();

  int ldr = analogRead(PIN_LDR);
  bool gelap = ldr > GELAP;
  if (!gelap) gelapSejak = 0;
  else if (gelapSejak == 0) gelapSejak = millis();

  if (siaga && !darurat && gelapSejak && millis() - gelapSejak > 2000) aturDarurat(true);
  if (darurat && (!gelap || millis() - daruratSejak > LAMA_DARURAT)) aturDarurat(false);

  if (mqtt.connected() && millis() - kirimTerakhir > 5000) {
    kirimTerakhir = millis();
    mqtt.publish(TOPIK_LDR, String(ldr).c_str());
  }
}

// Proyek 090 - Lampu Darurat Saat Listrik Padam
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_DARURAT = "ichibot/budi1234/p090/darurat";
const char* TOPIK_SIAGA   = "ichibot/budi1234/p090/siaga";
const char* TOPIK_LDR     = "ichibot/budi1234/p090/ldr";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PIN_LDR = 34, RELAY = 26;
const int GELAP = 3000;               // angka LDR di atas ini = lampu ruangan padam
const unsigned long LAMA_DARURAT = 30UL * 60 * 1000;   // hemat baterai: maks 30 menit
bool siaga = true, darurat = false;
unsigned long gelapSejak = 0, daruratSejak = 0, cobaMQTT = 0, kirimTerakhir = 0;

void aturDarurat(bool v) {
  darurat = v;
  digitalWrite(RELAY, v ? HIGH : LOW);
  if (v) daruratSejak = millis();
  if (mqtt.connected()) mqtt.publish(TOPIK_DARURAT, v ? "1" : "0", true);
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  siaga = (p == "ON");
  if (!siaga && darurat) aturDarurat(false);
}

void langganan() {
  mqtt.subscribe(TOPIK_SIAGA);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(RELAY, OUTPUT);
  WiFi.begin(WIFI_NAMA, WIFI_PASS);   // tidak menunggu: lampu darurat harus jalan tanpa WiFi
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  // koneksi dicoba sesekali saja, supaya logika lampu tidak pernah tertahan
  if (WiFi.status() == WL_CONNECTED && !mqtt.connected() && millis() - cobaMQTT > 10000) {
    cobaMQTT = millis();
    if (mqtt.connect(WiFi.macAddress().c_str())) langganan();
  }
  mqtt.loop();

int ldr = analogRead(PIN_LDR);
  bool gelap = ldr > GELAP;
  if (!gelap) gelapSejak = 0;
  else if (gelapSejak == 0) gelapSejak = millis();

if (siaga && !darurat && gelapSejak && millis() - gelapSejak > 2000) aturDarurat(true);
  if (darurat && (!gelap || millis() - daruratSejak > LAMA_DARURAT)) aturDarurat(false);

if (mqtt.connected() && millis() - kirimTerakhir > 5000) {
    kirimTerakhir = millis();
    mqtt.publish(TOPIK_LDR, String(ldr).c_str());
  }
}

Langkah 4: Pahami kodenya

Bandingkan dengan sambungWiFi() di blok umum yang berputar di while sampai tersambung. Alat keselamatan tidak boleh bergantung pada internet.
Sambung ke broker hanya kalau WiFi ada, dan dicoba paling sering 10 detik sekali. mqtt.connect() gagal dengan cepat, jadi lampu tidak tertahan.
Batas gelap. Lihat angka di gauge saat lampu ruangan menyala dan saat dimatikan, lalu pilih angka di antaranya.
Pesan hanya dikirim kalau tersambung. Saat listrik padam, status dikirim belakangan setelah WiFi kembali.