Cek dari mana saja apakah pintu garasi atau gerbang sudah tertutup. Klenik menampilkan status TERBUKA/TERTUTUP, mencatat jam setiap buka-tutup, dan mengingatkan kalau garasi masih terbuka saat sudah malam.

Saklar magnet MC-38 dibaca seperti proyek 088. Statusnya dikirim dengan flag retained, jadi saat kamu membuka dashboard dari kantor, status terakhir langsung terlihat walaupun pintu tidak bergerak sejak pagi.

Setiap perubahan dicatat bersama jamnya (NTP), dan jumlah buka hari ini dikirim ke gauge. Antara jam 22:00 dan 05:00, kalau pintu masih terbuka, Text Log mendapat pengingat setiap 15 menit sampai pintu ditutup.

Untuk pintu garasi besi, pakai MC-38 versi besar atau beri jarak plastik di belakang magnetnya, karena besi melemahkan medan magnet.

Komponen

Komponen	Qty	Harga
NodeMCU ESP8266 V3 (Lolin)	1	Rp42.000
MC-38 Reed Switch Magnetic Sensor Door Window Se	1	Rp8.500
Kabel jumper male-female 10 cm (isi 10)isi 10, terpakai 2, sambung ke kabel panjang kalau pintu jauh	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp54.000

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Saklar magnet MC-38 (2 kabel) 1	→	G	hitam
Saklar magnet MC-38 (2 kabel) 2	→	D5 GPIO14	biru

Langkah 2: Siapkan dashboard Klenik

Garasiichibot/budi1234/p089/pintu

TERBUKA

0 detik lalu

Dibuka (sejak menyala)ichibot/budi1234/p089/jumlah

0 detik lalu

Riwayat Garasiichibot/budi1234/p089/log

06:45 Garasi DIBUKA

06:47 Garasi ditutup

22:15 Sudah malam, garasi masih terbuka!

0 detik lalu

Cara cepat: unduh p089.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Indikator Boolean Garasi	`ichibot/KODE/p089/pintu`	ON = `1` “TERBUKA”, OFF = `0`
Gauge Dibuka (sejak menyala)	`ichibot/KODE/p089/jumlah`	0–30 x
Text Log Riwayat Garasi	`ichibot/KODE/p089/log`	menampilkan teks masuk

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: NodeMCU 1.0 (ESP-12E Module). Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p089.inoUnduh .ino

// Proyek 089 - Status Pintu Garasi
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_PINTU  = "ichibot/budi1234/p089/pintu";
const char* TOPIK_LOG    = "ichibot/budi1234/p089/log";
const char* TOPIK_JUMLAH = "ichibot/budi1234/p089/jumlah";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PINTU = D5;
int terbuka = -1;                     // -1 = belum diketahui
int jumlahBuka = 0;

String jamSekarang() {
  time_t t = time(nullptr);
  char buf[6];
  strftime(buf, sizeof(buf), "%H:%M", localtime(&t));
  return String(buf);
}

void langganan() {}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(PINTU, INPUT_PULLUP);
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org");
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) { sambungMQTT(); terbuka = -1; }
  mqtt.loop();

  int sekarang = digitalRead(PINTU) == HIGH ? 1 : 0;
  if (sekarang != terbuka) {
    delay(100);
    if ((digitalRead(PINTU) == HIGH ? 1 : 0) != sekarang) return;
    bool pertama = (terbuka == -1);
    terbuka = sekarang;
    mqtt.publish(TOPIK_PINTU, terbuka ? "1" : "0", true);
    if (!pertama) {
      if (terbuka) jumlahBuka++;
      mqtt.publish(TOPIK_LOG, (jamSekarang() + (terbuka ? " Garasi DIBUKA" : " Garasi ditutup")).c_str());
      mqtt.publish(TOPIK_JUMLAH, String(jumlahBuka).c_str());
    }
  }

  // malam hari (22:00-05:00) pintu masih terbuka: ingatkan setiap 15 menit
  static unsigned long ingatTerakhir = 0;
  time_t t = time(nullptr);
  int jam = localtime(&t)->tm_hour;
  if (terbuka == 1 && t > 1700000000 && (jam >= 22 || jam < 5) && millis() - ingatTerakhir > 900000UL) {
    ingatTerakhir = millis();
    mqtt.publish(TOPIK_LOG, (jamSekarang() + " Sudah malam, garasi masih terbuka!").c_str());
  }
}

// Proyek 089 - Status Pintu Garasi
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_PINTU  = "ichibot/budi1234/p089/pintu";
const char* TOPIK_LOG    = "ichibot/budi1234/p089/log";
const char* TOPIK_JUMLAH = "ichibot/budi1234/p089/jumlah";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PINTU = D5;
int terbuka = -1;                     // -1 = belum diketahui
int jumlahBuka = 0;

String jamSekarang() {
  time_t t = time(nullptr);
  char buf[6];
  strftime(buf, sizeof(buf), "%H:%M", localtime(&t));
  return String(buf);
}

void langganan() {}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(PINTU, INPUT_PULLUP);
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org");
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) { sambungMQTT(); terbuka = -1; }
  mqtt.loop();

int sekarang = digitalRead(PINTU) == HIGH ? 1 : 0;
  if (sekarang != terbuka) {
    delay(100);
    if ((digitalRead(PINTU) == HIGH ? 1 : 0) != sekarang) return;
    bool pertama = (terbuka == -1);
    terbuka = sekarang;
    mqtt.publish(TOPIK_PINTU, terbuka ? "1" : "0", true);
    if (!pertama) {
      if (terbuka) jumlahBuka++;
      mqtt.publish(TOPIK_LOG, (jamSekarang() + (terbuka ? " Garasi DIBUKA" : " Garasi ditutup")).c_str());
      mqtt.publish(TOPIK_JUMLAH, String(jumlahBuka).c_str());
    }
  }

// malam hari (22:00-05:00) pintu masih terbuka: ingatkan setiap 15 menit
  static unsigned long ingatTerakhir = 0;
  time_t t = time(nullptr);
  int jam = localtime(&t)->tm_hour;
  if (terbuka == 1 && t > 1700000000 && (jam >= 22 || jam < 5) && millis() - ingatTerakhir > 900000UL) {
    ingatTerakhir = millis();
    mqtt.publish(TOPIK_LOG, (jamSekarang() + " Sudah malam, garasi masih terbuka!").c_str());
  }
}

Langkah 4: Pahami kodenya

Setelah koneksi putus, status dikirim ulang begitu tersambung tanpa dicatat sebagai buka-tutup baru.
static di dalam fungsi membuat variabel ini tidak hilang di putaran loop() berikutnya, sama seperti variabel global tetapi hanya dipakai di bagian ini.
Rentang malam yang melewati tengah malam memakai ATAU, sama seperti jadwal di proyek 084.