Saklar magnet MC-38 menempel di pintu kulkas. Kalau pintu terbuka lebih dari 1 menit, buzzer berbunyi bip-bip dan Klenik mencatatnya, sehingga makanan tidak cepat basi dan listrik kulkas tidak boros.

MC-38 terdiri dari dua bagian. Bagian berkabel berisi saklar reed, dan bagian satunya hanya magnet. Saat keduanya berdekatan (pintu tertutup), magnet menutup saklar sehingga D5 tersambung ke GND dan terbaca LOW. Saat pintu dibuka, magnet menjauh, saklar terbuka, dan pull-up internal membuat D5 HIGH.

Saat pintu mulai terbuka, waktunya dicatat. Buzzer baru berbunyi setelah 1 menit, karena membuka kulkas sebentar untuk mengambil minum itu wajar. Pesan peringatan dikirim sekali saja, lalu pesan "sudah ditutup" mengikuti saat pintu akhirnya ditutup.

Pasang bagian berkabel di badan kulkas dan magnetnya di pintu, berjarak kurang dari 1,5 cm saat pintu tertutup.

Komponen

Komponen	Qty	Harga
NodeMCU ESP8266 V3 (Lolin)	1	Rp42.000
MC-38 Reed Switch Magnetic Sensor Door Window Se	1	Rp8.500
Modul buzzer aktif KY-012	1	Rp7.500
Kabel jumper male-female 10 cm (isi 10)isi 10, terpakai 2	1	Rp3.500
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 3	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp65.000

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Saklar magnet MC-38 (2 kabel) 1	→	D5 GPIO14	biru
Saklar magnet MC-38 (2 kabel) 2	→	G	hitam
Modul buzzer aktif KY-012 S	→	D2 GPIO4	kuning
Modul buzzer aktif KY-012 +	→	3V	merah
Modul buzzer aktif KY-012 −	→	G	hitam

Langkah 2: Siapkan dashboard Klenik

Pintu Kulkasichibot/budi1234/p088/pintu

TERBUKA

0 detik lalu

Peringatanichibot/budi1234/p088/log

Pintu kulkas terbuka lebih dari 1 menit!

Pintu kulkas sudah ditutup

0 detik lalu

Cara cepat: unduh p088.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Indikator Boolean Pintu Kulkas	`ichibot/KODE/p088/pintu`	ON = `1` “TERBUKA”, OFF = `0`
Text Log Peringatan	`ichibot/KODE/p088/log`	menampilkan teks masuk

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: NodeMCU 1.0 (ESP-12E Module). Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p088.inoUnduh .ino

// Proyek 088 - Pengingat Pintu Kulkas Terbuka
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_PINTU = "ichibot/budi1234/p088/pintu";
const char* TOPIK_LOG   = "ichibot/budi1234/p088/log";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PINTU = D5, BUZZER = D2;
const unsigned long BATAS_BUKA = 60000;   // boleh terbuka 1 menit
bool terbuka = false, sudahDiingatkan = false;
unsigned long bukaSejak = 0;

void langganan() {}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(PINTU, INPUT_PULLUP);
  pinMode(BUZZER, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  bool sekarang = digitalRead(PINTU) == HIGH;   // magnet menjauh = saklar terbuka = HIGH
  if (sekarang != terbuka) {
    delay(50);                                  // abaikan getaran pintu
    if ((digitalRead(PINTU) == HIGH) != sekarang) return;
    terbuka = sekarang;
    mqtt.publish(TOPIK_PINTU, terbuka ? "1" : "0", true);
    if (terbuka) { bukaSejak = millis(); sudahDiingatkan = false; }
    else if (sudahDiingatkan) mqtt.publish(TOPIK_LOG, "Pintu kulkas sudah ditutup");
  }

  bool kelamaan = terbuka && millis() - bukaSejak > BATAS_BUKA;
  if (kelamaan && !sudahDiingatkan) {
    sudahDiingatkan = true;
    mqtt.publish(TOPIK_LOG, "Pintu kulkas terbuka lebih dari 1 menit!");
  }
  digitalWrite(BUZZER, kelamaan && (millis() / 500) % 2);   // bip-bip sampai pintu ditutup
}

// Proyek 088 - Pengingat Pintu Kulkas Terbuka
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_PINTU = "ichibot/budi1234/p088/pintu";
const char* TOPIK_LOG   = "ichibot/budi1234/p088/log";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PINTU = D5, BUZZER = D2;
const unsigned long BATAS_BUKA = 60000;   // boleh terbuka 1 menit
bool terbuka = false, sudahDiingatkan = false;
unsigned long bukaSejak = 0;

void langganan() {}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(PINTU, INPUT_PULLUP);
  pinMode(BUZZER, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

bool sekarang = digitalRead(PINTU) == HIGH;   // magnet menjauh = saklar terbuka = HIGH
  if (sekarang != terbuka) {
    delay(50);                                  // abaikan getaran pintu
    if ((digitalRead(PINTU) == HIGH) != sekarang) return;
    terbuka = sekarang;
    mqtt.publish(TOPIK_PINTU, terbuka ? "1" : "0", true);
    if (terbuka) { bukaSejak = millis(); sudahDiingatkan = false; }
    else if (sudahDiingatkan) mqtt.publish(TOPIK_LOG, "Pintu kulkas sudah ditutup");
  }

bool kelamaan = terbuka && millis() - bukaSejak > BATAS_BUKA;
  if (kelamaan && !sudahDiingatkan) {
    sudahDiingatkan = true;
    mqtt.publish(TOPIK_LOG, "Pintu kulkas terbuka lebih dari 1 menit!");
  }
  digitalWrite(BUZZER, kelamaan && (millis() / 500) % 2);   // bip-bip sampai pintu ditutup
}

Langkah 4: Pahami kodenya

Dengan INPUT_PULLUP, saklar tertutup (magnet dekat) = LOW, saklar terbuka (pintu terbuka) = HIGH.
Debounce sederhana: baca ulang setelah 50 ms, dan kalau hasilnya beda, abaikan. Pintu yang bergetar saat ditutup tidak dihitung buka-tutup berkali-kali.
Pintu terbuka lebih lama dari batas. Buzzer berbunyi selama kondisi ini benar, dan pesan dikirim sekali.