Pengunci Pintu Solenoid

// Proyek 087 - Pengunci Pintu Solenoid
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_TERBUKA = "ichibot/budi1234/p087/terbuka";
const char* TOPIK_LOG     = "ichibot/budi1234/p087/log";
const char* TOPIK_BUKA    = "ichibot/budi1234/p087/buka";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int RELAY = 26;
const unsigned long LAMA_BUKA = 5000;   // solenoid tidak boleh dialiri terlalu lama
unsigned long bukaSampai = 0;

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (p == "ON" && !bukaSampai) {
    digitalWrite(RELAY, HIGH);          // solenoid tertarik = kunci terbuka
    bukaSampai = millis() + LAMA_BUKA;
    mqtt.publish(TOPIK_TERBUKA, "1");
    mqtt.publish(TOPIK_LOG, "Pintu dibuka dari dashboard");
  }
}

void langganan() {
  mqtt.subscribe(TOPIK_BUKA);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(RELAY, OUTPUT);
  digitalWrite(RELAY, LOW);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (bukaSampai && (long)(millis() - bukaSampai) >= 0) {
    bukaSampai = 0;
    digitalWrite(RELAY, LOW);           // kunci kembali
    mqtt.publish(TOPIK_TERBUKA, "0");
    mqtt.publish(TOPIK_BUKA, "OFF");
  }
}