Jadwal Nyala Lampu Harian

// Proyek 084 - Jadwal Nyala Lampu Harian
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LOG    = "ichibot/budi1234/p084/log";
const char* TOPIK_JADWAL = "ichibot/budi1234/p084/jadwal";
const char* TOPIK_AKTIF  = "ichibot/budi1234/p084/aktif";
const char* TOPIK_STATUS = "ichibot/budi1234/p084/status";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int RELAY = D1;
int menitNyala = 18 * 60, menitMati = 5 * 60 + 30;   // 18:00 sampai 05:30
bool aktif = true;
int statusTadi = -1;

int keMenit(String jam) {             // "18:30" -> 1110
  return jam.substring(0, 2).toInt() * 60 + jam.substring(3, 5).toInt();
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t;
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  p.trim();
  if (topik == TOPIK_JADWAL && p.length() == 11 && p[5] == '-') {      // format 18:00-05:30
    menitNyala = keMenit(p.substring(0, 5));
    menitMati = keMenit(p.substring(6));
    mqtt.publish(TOPIK_LOG, ("Jadwal: nyala " + p.substring(0, 5) + ", mati " + p.substring(6)).c_str());
    statusTadi = -1;                  // cek ulang sekarang juga
  } else if (topik == TOPIK_AKTIF) {
    aktif = (p == "ON");
    statusTadi = -1;
  }
}

void langganan() {
  mqtt.subscribe(TOPIK_JADWAL);
  mqtt.subscribe(TOPIK_AKTIF);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(RELAY, OUTPUT);
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org");
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  time_t t = time(nullptr);
  if (t < 1700000000) return;         // tunggu jam internet
  struct tm* w = localtime(&t);
  int sekarang = w->tm_hour * 60 + w->tm_min;

  bool dalamJadwal;
  if (menitNyala < menitMati) dalamJadwal = sekarang >= menitNyala && sekarang < menitMati;   // jadwal siang
  else dalamJadwal = sekarang >= menitNyala || sekarang < menitMati;                          // melewati tengah malam
  int nyala = (aktif && dalamJadwal) ? 1 : 0;

  if (nyala != statusTadi) {
    statusTadi = nyala;
    digitalWrite(RELAY, nyala ? HIGH : LOW);
    mqtt.publish(TOPIK_STATUS, nyala ? "1" : "0", true);
    char jam[6];
    strftime(jam, sizeof(jam), "%H:%M", w);
    mqtt.publish(TOPIK_LOG, (String(jam) + (nyala ? " Lampu nyala" : " Lampu mati")).c_str());
  }
}