Nyalakan perangkat untuk waktu tertentu, misalnya charger HP 2 jam, pompa akuarium 30 menit, atau rice cooker. Relay mati sendiri saat waktu habis. Lama waktunya diatur dengan slider, dan sisa waktunya tampil di HP.

Proyek ini menggabungkan saklar relay (proyek 081) dan timer (proyek 060). Saat switch Kontak dinyalakan, relay menyala dan waktu mulai dicatat. Setiap 10 detik sisa waktu dikirim ke gauge. Begitu waktu habis, relay dimatikan dan switch di dashboard dikembalikan ke OFF lewat pesan retained.

Kamu tetap bisa mematikan kontak lebih cepat dengan switch. Mengubah slider saat timer berjalan langsung mengubah lama timer, dihitung dari saat kontak dinyalakan.

Keamanan: stop kontak 220V harus dirakit dalam kotak tertutup oleh orang yang paham listrik. Relay modul ini maksimal 10A di 250V, jadi jangan dipakai untuk setrika, pemanas air, atau AC.

Komponen

Komponen	Qty	Harga
NodeMCU ESP8266 V3 (Lolin)	1	Rp42.000
Modul relay 1 channel 5V	1	Rp17.000
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 3	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp62.500

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Relay 1 ch 5V (jumper H) DC+	→	VU	oranye
Relay 1 ch 5V (jumper H) DC−	→	G	hitam
Relay 1 ch 5V (jumper H) IN	→	D1 GPIO5	biru

Langkah 2: Siapkan dashboard Klenik

Kontakichibot/budi1234/p083/kontak

Nyalakan

0 detik lalu

Lama Nyalaichibot/budi1234/p083/menit

30 menit30 of 240 menit

0 detik lalu

Sisa Waktuichibot/budi1234/p083/sisa

0 detik lalu

Riwayatichibot/budi1234/p083/log

Nyala 30 menit (dashboard)

Mati (waktu habis)

0 detik lalu

Cara cepat: unduh p083.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Switch Kontak	`ichibot/KODE/p083/kontak`	payload ON / OFF
Slider Output Lama Nyala	`ichibot/KODE/p083/menit`	1–240 menit
Gauge Sisa Waktu	`ichibot/KODE/p083/sisa`	0–240 mnt
Text Log Riwayat	`ichibot/KODE/p083/log`	menampilkan teks masuk

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: NodeMCU 1.0 (ESP-12E Module). Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p083.inoUnduh .ino

// Proyek 083 - Stop Kontak Timer dari Dashboard
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_KONTAK = "ichibot/budi1234/p083/kontak";
const char* TOPIK_LOG    = "ichibot/budi1234/p083/log";
const char* TOPIK_SISA   = "ichibot/budi1234/p083/sisa";
const char* TOPIK_MENIT  = "ichibot/budi1234/p083/menit";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int RELAY = D1;
int menit = 30;
bool nyala = false;
unsigned long mulai = 0, kirimTerakhir = 0;

void atur(bool v, const char* sebab) {
  nyala = v;
  digitalWrite(RELAY, v ? HIGH : LOW);
  if (v) mulai = millis();
  mqtt.publish(TOPIK_KONTAK, v ? "ON" : "OFF", true);
  mqtt.publish(TOPIK_LOG, (String(v ? "Nyala " + String(menit) + " menit" : "Mati") + " (" + sebab + ")").c_str());
  if (!v) mqtt.publish(TOPIK_SISA, "0");
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t;
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (topik == TOPIK_MENIT) menit = p.toInt();
  else if (topik == TOPIK_KONTAK) {
    bool v = (p == "ON");
    if (v != nyala) atur(v, "dashboard");
  }
}

void langganan() {
  mqtt.subscribe(TOPIK_MENIT);
  mqtt.subscribe(TOPIK_KONTAK);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(RELAY, OUTPUT);
  digitalWrite(RELAY, LOW);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (nyala) {
    unsigned long lama = (unsigned long)menit * 60000UL;
    unsigned long lewat = millis() - mulai;
    if (lewat >= lama) {
      atur(false, "waktu habis");
    } else if (millis() - kirimTerakhir >= 10000) {
      kirimTerakhir = millis();
      mqtt.publish(TOPIK_SISA, String((lama - lewat) / 60000.0, 1).c_str());
    }
  }
}

// Proyek 083 - Stop Kontak Timer dari Dashboard
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_KONTAK = "ichibot/budi1234/p083/kontak";
const char* TOPIK_LOG    = "ichibot/budi1234/p083/log";
const char* TOPIK_SISA   = "ichibot/budi1234/p083/sisa";
const char* TOPIK_MENIT  = "ichibot/budi1234/p083/menit";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int RELAY = D1;
int menit = 30;
bool nyala = false;
unsigned long mulai = 0, kirimTerakhir = 0;

void atur(bool v, const char* sebab) {
  nyala = v;
  digitalWrite(RELAY, v ? HIGH : LOW);
  if (v) mulai = millis();
  mqtt.publish(TOPIK_KONTAK, v ? "ON" : "OFF", true);
  mqtt.publish(TOPIK_LOG, (String(v ? "Nyala " + String(menit) + " menit" : "Mati") + " (" + sebab + ")").c_str());
  if (!v) mqtt.publish(TOPIK_SISA, "0");
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t;
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (topik == TOPIK_MENIT) menit = p.toInt();
  else if (topik == TOPIK_KONTAK) {
    bool v = (p == "ON");
    if (v != nyala) atur(v, "dashboard");
  }
}

void langganan() {
  mqtt.subscribe(TOPIK_MENIT);
  mqtt.subscribe(TOPIK_KONTAK);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(RELAY, OUTPUT);
  digitalWrite(RELAY, LOW);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

if (nyala) {
    unsigned long lama = (unsigned long)menit * 60000UL;
    unsigned long lewat = millis() - mulai;
    if (lewat >= lama) {
      atur(false, "waktu habis");
    } else if (millis() - kirimTerakhir >= 10000) {
      kirimTerakhir = millis();
      mqtt.publish(TOPIK_SISA, String((lama - lewat) / 60000.0, 1).c_str());
    }
  }
}

Langkah 4: Pahami kodenya

Pesan kontak yang dikirim sendiri oleh NodeMCU akan kembali karena kita berlangganan topic yang sama. Pesan yang sama dengan keadaan sekarang diabaikan.
Switch di dashboard ikut kembali ke OFF saat waktu habis, karena NodeMCU mengirim OFF ke topic switch itu.
Sama seperti proyek 060: menit diubah ke milidetik dengan tipe unsigned long supaya tidak meluap.