Lampu bisa dinyalakan dari tombol di dinding atau dari HP, dan keduanya selalu sinkron. Tekan tombol untuk menyalakan, matikan dari HP, lalu tekan tombol lagi untuk menyalakan. Switch di Klenik selalu menunjukkan posisi yang benar.

Saklar two-way di rumah memakai dua saklar mekanik dan kabel khusus. Di sini cara kerjanya lebih sederhana: NodeMCU yang memegang keadaan lampu (nyala), dan tombol maupun HP hanya mengirim perintah.

Tombol bekerja sebagai toggle: setiap tekan membalik keadaan. Setelah keadaan berubah, NodeMCU mengirim ON atau OFF ke topic switch dengan flag retained, jadi switch di dashboard ikut bergeser. Pesan itu juga kembali ke NodeMCU, tetapi diabaikan karena isinya sama dengan keadaan sekarang. Teknik ini sama dengan proyek 055.

Di instalasi sungguhan, push button kecil ini menggantikan saklar dinding. Kabel tombol hanya membawa 3,3V, jadi aman disentuh.

Komponen

Komponen	Qty	Harga
NodeMCU ESP8266 V3 (Lolin)	1	Rp42.000
Modul relay 1 channel 5V	1	Rp17.000
Push button 6×6 mm (isi 10)isi 10, terpakai 1	1	Rp4.750
Breadboard mini 170 titik	1	Rp4.875
Kabel jumper male-female 10 cm (isi 10)isi 10, terpakai 2	1	Rp3.500
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 3	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp75.625

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Relay 1 ch 5V (jumper H) DC+	→	VU	oranye
Relay 1 ch 5V (jumper H) DC−	→	G	hitam
Relay 1 ch 5V (jumper H) IN	→	D1 GPIO5	biru
Push button 6×6 mm 1	→	G	hitam
Push button 6×6 mm 2	→	D5 GPIO14	hijau

Langkah 2: Siapkan dashboard Klenik

Lampuichibot/budi1234/p085/lampu

Lampu

0 detik lalu

Riwayatichibot/budi1234/p085/log

Nyala dari tombol

Mati dari HP

Nyala dari tombol

0 detik lalu

Cara cepat: unduh p085.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Switch Lampu	`ichibot/KODE/p085/lampu`	payload ON / OFF
Text Log Riwayat	`ichibot/KODE/p085/log`	menampilkan teks masuk

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: NodeMCU 1.0 (ESP-12E Module). Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p085.inoUnduh .ino

// Proyek 085 - Saklar Fisik + Saklar HP (Two-Way)
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LAMPU = "ichibot/budi1234/p085/lampu";
const char* TOPIK_LOG   = "ichibot/budi1234/p085/log";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int RELAY = D1, TOMBOL = D5;
bool nyala = false, tadi = HIGH;
unsigned long waktuTekan = 0;

void atur(bool v, const char* dari) {
  nyala = v;
  digitalWrite(RELAY, v ? HIGH : LOW);
  mqtt.publish(TOPIK_LAMPU, v ? "ON" : "OFF", true);
  mqtt.publish(TOPIK_LOG, (String(v ? "Nyala" : "Mati") + " dari " + dari).c_str());
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  bool v = (p == "ON");
  if (v != nyala) atur(v, "HP");
}

void langganan() {
  mqtt.subscribe(TOPIK_LAMPU);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(RELAY, OUTPUT);
  pinMode(TOMBOL, INPUT_PULLUP);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  bool sekarang = digitalRead(TOMBOL);
  if (sekarang != tadi && millis() - waktuTekan > 50) {
    waktuTekan = millis();
    tadi = sekarang;
    if (sekarang == LOW) atur(!nyala, "tombol");   // setiap tekan: balik keadaan
  }
}

// Proyek 085 - Saklar Fisik + Saklar HP (Two-Way)
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LAMPU = "ichibot/budi1234/p085/lampu";
const char* TOPIK_LOG   = "ichibot/budi1234/p085/log";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int RELAY = D1, TOMBOL = D5;
bool nyala = false, tadi = HIGH;
unsigned long waktuTekan = 0;

void atur(bool v, const char* dari) {
  nyala = v;
  digitalWrite(RELAY, v ? HIGH : LOW);
  mqtt.publish(TOPIK_LAMPU, v ? "ON" : "OFF", true);
  mqtt.publish(TOPIK_LOG, (String(v ? "Nyala" : "Mati") + " dari " + dari).c_str());
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  bool v = (p == "ON");
  if (v != nyala) atur(v, "HP");
}

void langganan() {
  mqtt.subscribe(TOPIK_LAMPU);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(RELAY, OUTPUT);
  pinMode(TOMBOL, INPUT_PULLUP);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

bool sekarang = digitalRead(TOMBOL);
  if (sekarang != tadi && millis() - waktuTekan > 50) {
    waktuTekan = millis();
    tadi = sekarang;
    if (sekarang == LOW) atur(!nyala, "tombol");   // setiap tekan: balik keadaan
  }
}

Langkah 4: Pahami kodenya

!nyala membalik keadaan: nyala jadi mati, mati jadi nyala. Hanya saat tombol mulai ditekan (LOW), bukan saat dilepas.
Pesan yang kembali dari broker diabaikan kalau keadaannya sudah sama. Tanpa baris ini, log akan berisi "dari HP" untuk setiap tekan tombol.
Retained: setelah listrik padam, NodeMCU menerima keadaan terakhir dari broker dan lampu kembali seperti sebelumnya.