Dua Saklar Lampu dari HP

// Proyek 082 - Dua Saklar Lampu dari HP
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LAMPU[] = {
  "ichibot/budi1234/p082/lampu1",
  "ichibot/budi1234/p082/lampu2",
};
const char* TOPIK_STATUS[] = {
  "ichibot/budi1234/p082/lampu1/status",
  "ichibot/budi1234/p082/lampu2/status",
};

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int RELAY[] = {D1, D2};         // IN1, IN2

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t;
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  for (int i = 0; i < 2; i++) {
    if (topik == TOPIK_LAMPU[i]) {
      bool nyala = (p == "ON");
      digitalWrite(RELAY[i], nyala ? HIGH : LOW);
      mqtt.publish(TOPIK_STATUS[i], nyala ? "1" : "0", true);
    }
  }
}

void langganan() {
  for (int i = 0; i < 2; i++) mqtt.subscribe(TOPIK_LAMPU[i]);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  for (int i = 0; i < 2; i++) {
    pinMode(RELAY[i], OUTPUT);
    digitalWrite(RELAY[i], LOW);
  }
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
}