Pembuka bab Relay: switch di Klenik menyalakan dan mematikan relay, dan relay itulah yang menjadi saklar untuk lampu atau perangkat lain. Kodenya pendek sekali, karena hampir semua pekerjaan sudah dilakukan blok koneksi umum.

Relay adalah saklar yang digerakkan magnet listrik. Saat pin IN mendapat HIGH, kumparan di dalam kotak biru menarik kontak sehingga terdengar klik, dan terminal COM tersambung ke NO (Normally Open). Saat IN LOW, COM kembali tersambung ke NC (Normally Closed). Sisi kontak terisolasi dari ESP8266, jadi relay bisa menyambung arus yang jauh lebih besar dari yang sanggup diberikan pin GPIO.

Modul relay 5V mengambil daya kumparannya dari pin VU (5V dari USB), sedangkan sinyal IN cukup 3,3V dari D1. Setiap kali switch di dashboard berubah, NodeMCU membalas dengan topic status (retained), jadi indikator di HP selalu menunjukkan keadaan relay yang sebenarnya.

Keamanan: belajar dulu dengan beban tegangan rendah, misalnya lampu USB dan baterai. Menyambung lampu 220V ke terminal relay harus dilakukan atau diawasi orang yang paham instalasi listrik, dengan papan dan kabel tertutup.

Komponen

Komponen	Qty	Harga
NodeMCU ESP8266 V3 (Lolin)	1	Rp42.000
Modul relay 1 channel 5V	1	Rp17.000
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 3	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp62.500

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Relay 1 ch 5V (jumper H) DC+	→	VU	oranye
Relay 1 ch 5V (jumper H) DC−	→	G	hitam
Relay 1 ch 5V (jumper H) IN	→	D1 GPIO5	biru

Langkah 2: Siapkan dashboard Klenik

Lampuichibot/budi1234/p081/lampu

Lampu

0 detik lalu

Status Relayichibot/budi1234/p081/status

NYALA

0 detik lalu

Cara cepat: unduh p081.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Switch Lampu	`ichibot/KODE/p081/lampu`	payload ON / OFF
Indikator Boolean Status Relay	`ichibot/KODE/p081/status`	ON = `1` “NYALA”, OFF = `0`

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: NodeMCU 1.0 (ESP-12E Module). Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p081.inoUnduh .ino

// Proyek 081 - Saklar Lampu WiFi (Relay 1 Channel)
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_STATUS = "ichibot/budi1234/p081/status";
const char* TOPIK_LAMPU  = "ichibot/budi1234/p081/lampu";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int RELAY = D1;

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  bool nyala = (p == "ON");
  digitalWrite(RELAY, nyala ? HIGH : LOW);
  mqtt.publish(TOPIK_STATUS, nyala ? "1" : "0", true);
  Serial.println(nyala ? "Lampu nyala" : "Lampu mati");
}

void langganan() {
  mqtt.subscribe(TOPIK_LAMPU);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(RELAY, OUTPUT);
  digitalWrite(RELAY, LOW);           // mati dulu sampai ada perintah
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
}

// Proyek 081 - Saklar Lampu WiFi (Relay 1 Channel)
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_STATUS = "ichibot/budi1234/p081/status";
const char* TOPIK_LAMPU  = "ichibot/budi1234/p081/lampu";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int RELAY = D1;

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  bool nyala = (p == "ON");
  digitalWrite(RELAY, nyala ? HIGH : LOW);
  mqtt.publish(TOPIK_STATUS, nyala ? "1" : "0", true);
  Serial.println(nyala ? "Lampu nyala" : "Lampu mati");
}

void langganan() {
  mqtt.subscribe(TOPIK_LAMPU);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(RELAY, OUTPUT);
  digitalWrite(RELAY, LOW);           // mati dulu sampai ada perintah
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
}

Langkah 4: Pahami kodenya

Saat NodeMCU baru menyala, relay dipastikan mati. Lampu tidak menyala sendiri setelah listrik padam lalu hidup kembali.
Balasan status. Kalau indikator tidak ikut berubah saat switch ditekan, berarti NodeMCU tidak menerima perintah. Itu petunjuk penting saat mencari masalah.
Widget Switch Klenik mengirim teks ON dan OFF. Teks lain dianggap OFF.