HC-SR04 dipasang di atas kusen pintu menghadap lantai. Siapa pun yang berdiri di bawahnya langsung terukur tingginya, dan hasilnya muncul di HP. Cocok untuk posyandu, UKS, atau acara sekolah.

Pertama, kalibrasi: saat tidak ada orang, sensor mengukur jarak ke lantai. Setelah itu tinggi badan = jarak lantai - jarak ke kepala. Setiap pengukuran adalah rata-rata 5 kali ukur, supaya rambut atau gerakan kecil tidak membuat angkanya loncat. Kalau hasilnya di bawah 50 cm, dianggap tidak ada orang. Pin ECHO HC-SR04 mengeluarkan 5V, sedangkan pin ESP32 hanya tahan 3,3V. Dua resistor 1K dan 2K membaginya menjadi 5 × 2/3 ≈ 3,3V. SRF05 bisa dipakai dengan kabel dan kode yang sama (pin OUT-nya dibiarkan).

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
Sensor ultrasonik HC-SR04	1	Rp15.520
Resistor 1K (isi 10)isi 10, terpakai 1	1	Rp1.800
Resistor 2K (isi 10)isi 10, terpakai 1	1	Rp1.800
Breadboard mini 170 titik	1	Rp4.875
Kabel jumper male-female 10 cm (isi 10)isi 10, terpakai 4	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp102.495

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
HC-SR04 + pembagi tegangan (1K seri, 2K ke GND) di ECHO VCC	→	VIN	merah
HC-SR04 + pembagi tegangan (1K seri, 2K ke GND) di ECHO TRIG	→	D5 GPIO5	kuning
HC-SR04 + pembagi tegangan (1K seri, 2K ke GND) di ECHO ECHO	→	D18 GPIO18	hijau
HC-SR04 + pembagi tegangan (1K seri, 2K ke GND) di ECHO GND	→	GND	hitam

Langkah 2: Siapkan dashboard Klenik

Tinggi Badanichibot/budi1234/p048/tinggi

0 detik lalu

Kalibrasi Lantaiichibot/budi1234/p048/kalibrasi

Kalibrasi

Belum pernah ditekan

Hasil Ukurichibot/budi1234/p048/log

Kalibrasi: jarak ke lantai 212.4 cm

Tinggi terukur: 163 cm

Tinggi terukur: 148 cm

0 detik lalu

Cara cepat: unduh p048.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Gauge Tinggi Badan	`ichibot/KODE/p048/tinggi`	0–200 cm
Switch Kalibrasi Lantai	`ichibot/KODE/p048/kalibrasi`	payload ON / OFF
Text Log Hasil Ukur	`ichibot/KODE/p048/log`	menampilkan teks masuk

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p048.inoUnduh .ino

// Proyek 048 - Pengukur Tinggi Badan
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LOG       = "ichibot/budi1234/p048/log";
const char* TOPIK_KALIBRASI = "ichibot/budi1234/p048/kalibrasi";
const char* TOPIK_TINGGI    = "ichibot/budi1234/p048/tinggi";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int TRIG = 5, ECHO = 18;        // sensor dipasang di atas, menghadap lantai
float jarakLantai = 0;                // dari kalibrasi saat tidak ada orang
float tinggiTadi = 0;
unsigned long terakhir = 0;

float ukurCm() {                     // HC-SR04: pulsa 10 µs di TRIG, lama pulsa ECHO = waktu pantul
  digitalWrite(TRIG, LOW);  delayMicroseconds(2);
  digitalWrite(TRIG, HIGH); delayMicroseconds(10);
  digitalWrite(TRIG, LOW);
  unsigned long us = pulseIn(ECHO, HIGH, 30000);   // batas 30 ms (±5 m)
  if (us == 0) return -1;             // tidak ada pantulan
  return us * 0.0343 / 2;             // kecepatan suara 343 m/s, bolak-balik dibagi 2
}

float rataRata() {                    // 5 kali ukur, buang yang gagal
  float total = 0; int n = 0;
  for (int i = 0; i < 5; i++) {
    float cm = ukurCm();
    if (cm > 0) { total += cm; n++; }
    delay(30);
  }
  return n ? total / n : -1;
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (p == "ON") {
    jarakLantai = rataRata();
    mqtt.publish(TOPIK_LOG, ("Kalibrasi: jarak ke lantai " + String(jarakLantai, 1) + " cm").c_str());
  }
}

void langganan() {
  mqtt.subscribe(TOPIK_KALIBRASI);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(TRIG, OUTPUT);
  pinMode(ECHO, INPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
  if (jarakLantai <= 0 || millis() - terakhir < 1000) return;
  terakhir = millis();

  float kepala = rataRata();
  if (kepala < 0) return;
  float tinggi = jarakLantai - kepala;
  if (tinggi < 50) tinggi = 0;        // tidak ada orang di bawah sensor
  if (abs(tinggi - tinggiTadi) >= 1) {
    tinggiTadi = tinggi;
    mqtt.publish(TOPIK_TINGGI, String(tinggi, 0).c_str());
    if (tinggi > 0) mqtt.publish(TOPIK_LOG, ("Tinggi terukur: " + String(tinggi, 0) + " cm").c_str());
  }
}

// Proyek 048 - Pengukur Tinggi Badan
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LOG       = "ichibot/budi1234/p048/log";
const char* TOPIK_KALIBRASI = "ichibot/budi1234/p048/kalibrasi";
const char* TOPIK_TINGGI    = "ichibot/budi1234/p048/tinggi";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int TRIG = 5, ECHO = 18;        // sensor dipasang di atas, menghadap lantai
float jarakLantai = 0;                // dari kalibrasi saat tidak ada orang
float tinggiTadi = 0;
unsigned long terakhir = 0;

float ukurCm() {                     // HC-SR04: pulsa 10 µs di TRIG, lama pulsa ECHO = waktu pantul
  digitalWrite(TRIG, LOW);  delayMicroseconds(2);
  digitalWrite(TRIG, HIGH); delayMicroseconds(10);
  digitalWrite(TRIG, LOW);
  unsigned long us = pulseIn(ECHO, HIGH, 30000);   // batas 30 ms (±5 m)
  if (us == 0) return -1;             // tidak ada pantulan
  return us * 0.0343 / 2;             // kecepatan suara 343 m/s, bolak-balik dibagi 2
}

float rataRata() {                    // 5 kali ukur, buang yang gagal
  float total = 0; int n = 0;
  for (int i = 0; i < 5; i++) {
    float cm = ukurCm();
    if (cm > 0) { total += cm; n++; }
    delay(30);
  }
  return n ? total / n : -1;
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (p == "ON") {
    jarakLantai = rataRata();
    mqtt.publish(TOPIK_LOG, ("Kalibrasi: jarak ke lantai " + String(jarakLantai, 1) + " cm").c_str());
  }
}

void langganan() {
  mqtt.subscribe(TOPIK_KALIBRASI);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(TRIG, OUTPUT);
  pinMode(ECHO, INPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
  if (jarakLantai <= 0 || millis() - terakhir < 1000) return;
  terakhir = millis();

float kepala = rataRata();
  if (kepala < 0) return;
  float tinggi = jarakLantai - kepala;
  if (tinggi < 50) tinggi = 0;        // tidak ada orang di bawah sensor
  if (abs(tinggi - tinggiTadi) >= 1) {
    tinggiTadi = tinggi;
    mqtt.publish(TOPIK_TINGGI, String(tinggi, 0).c_str());
    if (tinggi > 0) mqtt.publish(TOPIK_LOG, ("Tinggi terukur: " + String(tinggi, 0) + " cm").c_str());
  }
}

Langkah 4: Pahami kodenya

Lima kali ukur dengan jeda 30 ms. Hasil gagal dibuang sebelum dirata-rata.
Kalibrasi lewat switch di HP. Lakukan sekali setelah sensor terpasang, saat area di bawahnya kosong.
Inti perhitungan. Akurasinya sekitar ±1 cm, cukup untuk keperluan non-medis.