Akselerometer 3 sumbu membaca kemiringan benda dalam derajat dan mendeteksi guncangan. Pasang di rak, tiang, atau mesin untuk tahu kalau ada yang miring atau terbentur.

Akselerometer mengukur percepatan, termasuk gravitasi bumi (1 g) yang selalu mengarah ke bawah. Saat benda diam, arah gravitasi terhadap sumbu X, Y, Z menunjukkan kemiringannya. Sudutnya dihitung dengan atan2. Guncangan dideteksi dari perubahan mendadak: kalau jumlah perubahan ketiga sumbu antar-bacaan lebih dari 0,5 g, kejadian itu dicatat ke log.

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
Akselerometer MMA8452	1	Rp8.000
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 4	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp86.500

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
MMA8452 (I2C) VCC	→	3V3	merah
MMA8452 (I2C) SDA	→	D21 GPIO21	hijau
MMA8452 (I2C) SCL	→	D22 GPIO22	kuning
MMA8452 (I2C) GND	→	GND	hitam

Langkah 2: Siapkan dashboard Klenik

Miring Kiri-Kananichibot/budi1234/p049/miringx

0 detik lalu

Miring Depan-Belakangichibot/budi1234/p049/miringy

0 detik lalu

Guncanganichibot/budi1234/p049/log

Guncangan 0.82 g

Guncangan 1.40 g

0 detik lalu

Cara cepat: unduh p049.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Gauge Miring Kiri-Kanan	`ichibot/KODE/p049/miringx`	-90–90 °
Gauge Miring Depan-Belakang	`ichibot/KODE/p049/miringy`	-90–90 °
Text Log Guncangan	`ichibot/KODE/p049/log`	menampilkan teks masuk

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary), SparkFun MMA8452Q Accelerometer. Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p049.inoUnduh .ino

// Proyek 049 - Deteksi Kemiringan & Guncangan MMA8452
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <Wire.h>
#include <SparkFun_MMA8452Q.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_MIRINGX = "ichibot/budi1234/p049/miringx";
const char* TOPIK_MIRINGY = "ichibot/budi1234/p049/miringy";
const char* TOPIK_LOG     = "ichibot/budi1234/p049/log";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
MMA8452Q akselero;                    // I2C: SDA D21, SCL D22
float batasGuncang = 0.5;             // g, perubahan di atas ini dianggap guncangan
float xTadi = 0, yTadi = 0, zTadi = 1;
unsigned long terakhir = 0;

void langganan() {}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  Wire.begin();
  if (!akselero.begin()) Serial.println("MMA8452 tidak ditemukan, cek SDA/SCL");
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
  if (!akselero.available() || millis() - terakhir < 100) return;
  terakhir = millis();

  float x = akselero.getCalculatedX(), y = akselero.getCalculatedY(), z = akselero.getCalculatedZ();
  float miringX = atan2(x, sqrt(y * y + z * z)) * 180 / PI;   // derajat
  float miringY = atan2(y, sqrt(x * x + z * z)) * 180 / PI;
  float guncang = abs(x - xTadi) + abs(y - yTadi) + abs(z - zTadi);
  xTadi = x; yTadi = y; zTadi = z;

  static unsigned long lapor = 0;
  if (millis() - lapor >= 1000) {
    lapor = millis();
    mqtt.publish(TOPIK_MIRINGX, String(miringX, 0).c_str());
    mqtt.publish(TOPIK_MIRINGY, String(miringY, 0).c_str());
  }
  if (guncang > batasGuncang) {
    mqtt.publish(TOPIK_LOG, ("Guncangan " + String(guncang, 2) + " g").c_str());
    delay(300);                       // satu guncangan dilaporkan sekali
  }
}

// Proyek 049 - Deteksi Kemiringan & Guncangan MMA8452
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <Wire.h>
#include <SparkFun_MMA8452Q.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_MIRINGX = "ichibot/budi1234/p049/miringx";
const char* TOPIK_MIRINGY = "ichibot/budi1234/p049/miringy";
const char* TOPIK_LOG     = "ichibot/budi1234/p049/log";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
MMA8452Q akselero;                    // I2C: SDA D21, SCL D22
float batasGuncang = 0.5;             // g, perubahan di atas ini dianggap guncangan
float xTadi = 0, yTadi = 0, zTadi = 1;
unsigned long terakhir = 0;

void langganan() {}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  Wire.begin();
  if (!akselero.begin()) Serial.println("MMA8452 tidak ditemukan, cek SDA/SCL");
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
  if (!akselero.available() || millis() - terakhir < 100) return;
  terakhir = millis();

float x = akselero.getCalculatedX(), y = akselero.getCalculatedY(), z = akselero.getCalculatedZ();
  float miringX = atan2(x, sqrt(y * y + z * z)) * 180 / PI;   // derajat
  float miringY = atan2(y, sqrt(x * x + z * z)) * 180 / PI;
  float guncang = abs(x - xTadi) + abs(y - yTadi) + abs(z - zTadi);
  xTadi = x; yTadi = y; zTadi = z;

static unsigned long lapor = 0;
  if (millis() - lapor >= 1000) {
    lapor = millis();
    mqtt.publish(TOPIK_MIRINGX, String(miringX, 0).c_str());
    mqtt.publish(TOPIK_MIRINGY, String(miringY, 0).c_str());
  }
  if (guncang > batasGuncang) {
    mqtt.publish(TOPIK_LOG, ("Guncangan " + String(guncang, 2) + " g").c_str());
    delay(300);                       // satu guncangan dilaporkan sekali
  }
}

Langkah 4: Pahami kodenya

Sudut kemiringan dari komponen gravitasi. Rumus ini tetap benar walaupun sensor dipasang miring ke dua arah sekaligus.
Perubahan total antar-bacaan (100 ms). Benda diam: hampir 0. Diketuk atau terbentur: melonjak.
Satu guncangan biasanya menghasilkan beberapa bacaan besar berturut-turut. Jeda ini membuatnya dilaporkan sekali.