Seperti sensor parkir mobil: bip makin cepat saat makin dekat dengan dinding, lalu bunyi panjang di bawah 20 cm. Jarak terakhir juga tampil di HP.

Jarak diukur setiap 100 ms seperti proyek 043. Fungsi jedaBip() mengubah jarak menjadi jeda antar-bip: di atas 150 cm diam, 20-150 cm bip dengan jeda 80-800 ms, di bawah 20 cm bunyi terus. Buzzer dinyalakan-dimatikan dengan millis(), jadi pengukuran tetap berjalan saat buzzer berbunyi. Pin ECHO HC-SR04 mengeluarkan 5V, sedangkan pin ESP32 hanya tahan 3,3V. Dua resistor 1K dan 2K membaginya menjadi 5 × 2/3 ≈ 3,3V. SRF05 bisa dipakai dengan kabel dan kode yang sama (pin OUT-nya dibiarkan).

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
Sensor ultrasonik HC-SR04	1	Rp15.520
Resistor 1K (isi 10)isi 10, terpakai 1	1	Rp1.800
Resistor 2K (isi 10)isi 10, terpakai 1	1	Rp1.800
Breadboard mini 170 titik	1	Rp4.875
Modul buzzer aktif KY-012	1	Rp7.500
Kabel jumper male-female 10 cm (isi 10)isi 10, terpakai 7	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp109.995

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
HC-SR04 + pembagi tegangan (1K seri, 2K ke GND) di ECHO VCC	→	VIN	merah
HC-SR04 + pembagi tegangan (1K seri, 2K ke GND) di ECHO TRIG	→	D5 GPIO5	kuning
HC-SR04 + pembagi tegangan (1K seri, 2K ke GND) di ECHO ECHO	→	D18 GPIO18	hijau
HC-SR04 + pembagi tegangan (1K seri, 2K ke GND) di ECHO GND	→	GND	hitam
Modul buzzer aktif KY-012 S	→	D26 GPIO26	biru
Modul buzzer aktif KY-012 +	→	3V3	merah
Modul buzzer aktif KY-012 −	→	GND	hitam

Langkah 2: Siapkan dashboard Klenik

Jarak ke Belakangichibot/budi1234/p044/jarak

0 detik lalu

Cara cepat: unduh p044.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Gauge Jarak ke Belakang	`ichibot/KODE/p044/jarak`	0–200 cm

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p044.inoUnduh .ino

// Proyek 044 - Sensor Parkir Mundur
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_JARAK = "ichibot/budi1234/p044/jarak";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int TRIG = 5, ECHO = 18, BUZZER = 26;
float jarak = 400;
unsigned long terakhirUkur = 0, terakhirBip = 0, terakhirLapor = 0;
bool bunyi = false;

float ukurCm() {                     // HC-SR04: pulsa 10 µs di TRIG, lama pulsa ECHO = waktu pantul
  digitalWrite(TRIG, LOW);  delayMicroseconds(2);
  digitalWrite(TRIG, HIGH); delayMicroseconds(10);
  digitalWrite(TRIG, LOW);
  unsigned long us = pulseIn(ECHO, HIGH, 30000);   // batas 30 ms (±5 m)
  if (us == 0) return -1;             // tidak ada pantulan
  return us * 0.0343 / 2;             // kecepatan suara 343 m/s, bolak-balik dibagi 2
}

int jedaBip(float cm) {               // makin dekat makin cepat, di bawah 20 cm bunyi terus
  if (cm < 20) return 0;
  if (cm > 150) return -1;            // jauh: diam
  return map((int)cm, 20, 150, 80, 800);
}

void langganan() {}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(TRIG, OUTPUT);
  pinMode(ECHO, INPUT);
  pinMode(BUZZER, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (millis() - terakhirUkur >= 100) {
    terakhirUkur = millis();
    float cm = ukurCm();
    if (cm > 0) jarak = cm;
  }
  int jeda = jedaBip(jarak);
  if (jeda == 0) digitalWrite(BUZZER, HIGH);
  else if (jeda < 0) digitalWrite(BUZZER, LOW);
  else if (millis() - terakhirBip >= (unsigned long)jeda) {
    terakhirBip = millis();
    bunyi = !bunyi;
    digitalWrite(BUZZER, bunyi);
  }
  if (millis() - terakhirLapor >= 1000) {
    terakhirLapor = millis();
    mqtt.publish(TOPIK_JARAK, String(jarak, 0).c_str());
  }
}

// Proyek 044 - Sensor Parkir Mundur
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_JARAK = "ichibot/budi1234/p044/jarak";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int TRIG = 5, ECHO = 18, BUZZER = 26;
float jarak = 400;
unsigned long terakhirUkur = 0, terakhirBip = 0, terakhirLapor = 0;
bool bunyi = false;

float ukurCm() {                     // HC-SR04: pulsa 10 µs di TRIG, lama pulsa ECHO = waktu pantul
  digitalWrite(TRIG, LOW);  delayMicroseconds(2);
  digitalWrite(TRIG, HIGH); delayMicroseconds(10);
  digitalWrite(TRIG, LOW);
  unsigned long us = pulseIn(ECHO, HIGH, 30000);   // batas 30 ms (±5 m)
  if (us == 0) return -1;             // tidak ada pantulan
  return us * 0.0343 / 2;             // kecepatan suara 343 m/s, bolak-balik dibagi 2
}

int jedaBip(float cm) {               // makin dekat makin cepat, di bawah 20 cm bunyi terus
  if (cm < 20) return 0;
  if (cm > 150) return -1;            // jauh: diam
  return map((int)cm, 20, 150, 80, 800);
}

void langganan() {}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(TRIG, OUTPUT);
  pinMode(ECHO, INPUT);
  pinMode(BUZZER, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

if (millis() - terakhirUkur >= 100) {
    terakhirUkur = millis();
    float cm = ukurCm();
    if (cm > 0) jarak = cm;
  }
  int jeda = jedaBip(jarak);
  if (jeda == 0) digitalWrite(BUZZER, HIGH);
  else if (jeda < 0) digitalWrite(BUZZER, LOW);
  else if (millis() - terakhirBip >= (unsigned long)jeda) {
    terakhirBip = millis();
    bunyi = !bunyi;
    digitalWrite(BUZZER, bunyi);
  }
  if (millis() - terakhirLapor >= 1000) {
    terakhirLapor = millis();
    mqtt.publish(TOPIK_JARAK, String(jarak, 0).c_str());
  }
}

Langkah 4: Pahami kodenya

Tiga zona: diam, bip, dan bunyi terus. map() membuat jeda bip turun mulus dari 800 ms (150 cm) ke 80 ms (20 cm).
Pengukuran gagal (-1) tidak menimpa jarak terakhir, jadi bip tidak tiba-tiba berhenti.
Setiap jeda habis, buzzer dibalik. Satu bip = satu kali nyala + satu kali mati.