Sensor "mata kelelawar" HC-SR04 mengukur jarak benda di depannya, 2-400 cm. Jaraknya tampil di HP setiap setengah detik. Ini dasar untuk sensor parkir, level air, dan pengukur tinggi badan di proyek berikutnya.

ESP32 memberi pulsa 10 mikrodetik ke TRIG. Sensor memancarkan 8 gelombang suara 40 kHz yang tidak terdengar, lalu menaikkan ECHO sampai pantulannya kembali. Lama pulsa ECHO adalah waktu bolak-balik suara. Jarak = waktu × kecepatan suara (343 m/s = 0,0343 cm/µs) ÷ 2. Pin ECHO HC-SR04 mengeluarkan 5V, sedangkan pin ESP32 hanya tahan 3,3V. Dua resistor 1K dan 2K membaginya menjadi 5 × 2/3 ≈ 3,3V. SRF05 bisa dipakai dengan kabel dan kode yang sama (pin OUT-nya dibiarkan).

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
Sensor ultrasonik HC-SR04	1	Rp15.520
Resistor 1K (isi 10)isi 10, terpakai 1	1	Rp1.800
Resistor 2K (isi 10)isi 10, terpakai 1	1	Rp1.800
Breadboard mini 170 titik	1	Rp4.875
Kabel jumper male-female 10 cm (isi 10)isi 10, terpakai 4	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp102.495

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
HC-SR04 + pembagi tegangan (1K seri, 2K ke GND) di ECHO VCC	→	VIN	merah
HC-SR04 + pembagi tegangan (1K seri, 2K ke GND) di ECHO TRIG	→	D5 GPIO5	kuning
HC-SR04 + pembagi tegangan (1K seri, 2K ke GND) di ECHO ECHO	→	D18 GPIO18	hijau
HC-SR04 + pembagi tegangan (1K seri, 2K ke GND) di ECHO GND	→	GND	hitam

Langkah 2: Siapkan dashboard Klenik

Jarakichibot/budi1234/p043/jarak

0 detik lalu

Riwayat Jarakichibot/budi1234/p043/jarak

110cm

0.0cm10 titik200.0cm

0 detik lalu

Cara cepat: unduh p043.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Gauge Jarak	`ichibot/KODE/p043/jarak`	0–200 cm
Chart Riwayat Jarak	`ichibot/KODE/p043/jarak`	0–200 cm

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p043.inoUnduh .ino

// Proyek 043 - Pengukur Jarak Ultrasonik
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_JARAK = "ichibot/budi1234/p043/jarak";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int TRIG = 5, ECHO = 18;        // ECHO lewat pembagi tegangan 1K/2K
unsigned long terakhir = 0;

float ukurCm() {                     // HC-SR04: pulsa 10 µs di TRIG, lama pulsa ECHO = waktu pantul
  digitalWrite(TRIG, LOW);  delayMicroseconds(2);
  digitalWrite(TRIG, HIGH); delayMicroseconds(10);
  digitalWrite(TRIG, LOW);
  unsigned long us = pulseIn(ECHO, HIGH, 30000);   // batas 30 ms (±5 m)
  if (us == 0) return -1;             // tidak ada pantulan
  return us * 0.0343 / 2;             // kecepatan suara 343 m/s, bolak-balik dibagi 2
}

void langganan() {}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(TRIG, OUTPUT);
  pinMode(ECHO, INPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
  if (millis() - terakhir < 500) return;
  terakhir = millis();

  float cm = ukurCm();
  if (cm < 0) return;
  mqtt.publish(TOPIK_JARAK, String(cm, 1).c_str());
  Serial.printf("%.1f cm\n", cm);
}

// Proyek 043 - Pengukur Jarak Ultrasonik
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_JARAK = "ichibot/budi1234/p043/jarak";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int TRIG = 5, ECHO = 18;        // ECHO lewat pembagi tegangan 1K/2K
unsigned long terakhir = 0;

float ukurCm() {                     // HC-SR04: pulsa 10 µs di TRIG, lama pulsa ECHO = waktu pantul
  digitalWrite(TRIG, LOW);  delayMicroseconds(2);
  digitalWrite(TRIG, HIGH); delayMicroseconds(10);
  digitalWrite(TRIG, LOW);
  unsigned long us = pulseIn(ECHO, HIGH, 30000);   // batas 30 ms (±5 m)
  if (us == 0) return -1;             // tidak ada pantulan
  return us * 0.0343 / 2;             // kecepatan suara 343 m/s, bolak-balik dibagi 2
}

void langganan() {}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(TRIG, OUTPUT);
  pinMode(ECHO, INPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
  if (millis() - terakhir < 500) return;
  terakhir = millis();

float cm = ukurCm();
  if (cm < 0) return;
  mqtt.publish(TOPIK_JARAK, String(cm, 1).c_str());
  Serial.printf("%.1f cm\n", cm);
}

Langkah 4: Pahami kodenya

pulseIn() mengukur lama ECHO HIGH dalam mikrodetik. Batas 30 ms mencegah program menunggu terlalu lama kalau tidak ada pantulan.
Waktu dikali kecepatan suara, dibagi 2 karena suara berjalan pergi dan kembali.
0 berarti tidak ada pantulan: benda terlalu jauh, terlalu miring, atau terlalu lembut (kain dan busa menyerap suara).