Sensor inframerah di kusen pintu menghitung setiap orang yang lewat. Jumlahnya tampil di HP dan bisa dinolkan tiap pagi. Cocok untuk toko kecil, perpustakaan, atau mushola.

KY-032 memancarkan inframerah dari LED bening dan menangkap pantulannya dengan penerima hitam. Kalau ada benda dalam jarak 2-40 cm (diatur trimpot), OUT menjadi LOW. Satu orang lewat menghasilkan satu periode LOW. Hitungan bertambah di awal periode itu. Perubahan yang lebih cepat dari 0,3 detik diabaikan, jadi kaki dan tangan yang berayun tidak terhitung sebagai orang tambahan.

Komponen

Komponen	Qty	Harga
NodeMCU ESP8266 V3 (Lolin)	1	Rp42.000
Sensor IR KY-032	1	Rp7.500
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 3	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp53.000

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Sensor IR KY-032 GND	→	G	hitam
Sensor IR KY-032 +	→	3V	merah
Sensor IR KY-032 OUT	→	D5 GPIO14	kuning

Langkah 2: Siapkan dashboard Klenik

Pengunjung Hari Iniichibot/budi1234/p045/jumlah

0 detik lalu

Pintuichibot/budi1234/p045/lewat

ADA YANG LEWAT

0 detik lalu

Nolkanichibot/budi1234/p045/nolkan

Nolkan

Belum pernah ditekan

Cara cepat: unduh p045.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Gauge Pengunjung Hari Ini	`ichibot/KODE/p045/jumlah`	0–200
Indikator Boolean Pintu	`ichibot/KODE/p045/lewat`	ON = `1` “ADA YANG LEWAT”, OFF = `0`
Switch Nolkan	`ichibot/KODE/p045/nolkan`	payload ON / OFF

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: NodeMCU 1.0 (ESP-12E Module). Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p045.inoUnduh .ino

// Proyek 045 - Penghitung Orang Lewat Pintu
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_JUMLAH = "ichibot/budi1234/p045/jumlah";
const char* TOPIK_NOLKAN = "ichibot/budi1234/p045/nolkan";
const char* TOPIK_LEWAT  = "ichibot/budi1234/p045/lewat";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PIN_IR = D5;                // OUT KY-032: LOW saat ada benda di depan
bool adaTadi = false;
unsigned long berubah = 0;
int jumlah = 0;

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (p == "ON") { jumlah = 0; mqtt.publish(TOPIK_JUMLAH, "0", true); }
}

void langganan() {
  mqtt.subscribe(TOPIK_NOLKAN);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(PIN_IR, INPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  bool ada = digitalRead(PIN_IR) == LOW;
  if (ada != adaTadi && millis() - berubah > 300) {   // abaikan kedipan < 0,3 detik
    berubah = millis();
    adaTadi = ada;
    if (ada) {                        // dihitung saat orang mulai lewat
      jumlah++;
      mqtt.publish(TOPIK_JUMLAH, String(jumlah).c_str(), true);
    }
    mqtt.publish(TOPIK_LEWAT, ada ? "1" : "0");
  }
}

// Proyek 045 - Penghitung Orang Lewat Pintu
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_JUMLAH = "ichibot/budi1234/p045/jumlah";
const char* TOPIK_NOLKAN = "ichibot/budi1234/p045/nolkan";
const char* TOPIK_LEWAT  = "ichibot/budi1234/p045/lewat";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PIN_IR = D5;                // OUT KY-032: LOW saat ada benda di depan
bool adaTadi = false;
unsigned long berubah = 0;
int jumlah = 0;

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (p == "ON") { jumlah = 0; mqtt.publish(TOPIK_JUMLAH, "0", true); }
}

void langganan() {
  mqtt.subscribe(TOPIK_NOLKAN);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(PIN_IR, INPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

bool ada = digitalRead(PIN_IR) == LOW;
  if (ada != adaTadi && millis() - berubah > 300) {   // abaikan kedipan < 0,3 detik
    berubah = millis();
    adaTadi = ada;
    if (ada) {                        // dihitung saat orang mulai lewat
      jumlah++;
      mqtt.publish(TOPIK_JUMLAH, String(jumlah).c_str(), true);
    }
    mqtt.publish(TOPIK_LEWAT, ada ? "1" : "0");
  }
}

Langkah 4: Pahami kodenya

KY-032 aktif LOW: LED hijau di modul menyala dan OUT = LOW saat ada benda.
Debounce 0,3 detik. Kalau orang yang lewat beriringan terhitung satu, perkecil angkanya.
Penghitung ini tidak tahu arah. Untuk membedakan masuk dan keluar, pakai dua sensor berjarak 10 cm dan lihat mana yang terpicu duluan.