Lampu lorong atau toilet yang menyala saat ada orang lewat dan mati sendiri setelah sepi. Lama nyala diatur dari HP, dan setiap gerakan baru memperpanjang waktunya.

Setiap kali PIR HIGH, waktu gerakan terakhir diperbarui dan lampu dinyalakan kalau sedang mati. Lampu baru dimatikan kalau sudah lewat detikNyala sejak gerakan TERAKHIR, bukan sejak lampu menyala. Jadi lampu tidak padam saat orang masih di dalam ruangan. Bebannya lampu USB lewat relay dan 3 baterai AA, sama seperti proyek 032.

Komponen

Komponen	Qty	Harga
NodeMCU ESP8266 V3 (Lolin)	1	Rp42.000
Sensor gerak PIR HC-SR501	1	Rp15.000
Modul relay 1 channel 5V	1	Rp17.000
Soket USB female ke pin DIP	1	Rp3.500
Lampu USB mini	1	Rp8.775
Holder baterai 3×AA + kabelbaterai AA dibeli terpisah	1	Rp6.000
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 6	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp95.775

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
PIR HC-SR501 VCC	→	VU	merah
PIR HC-SR501 OUT	→	D5 GPIO14	kuning
PIR HC-SR501 GND	→	G	hitam
Relay 1 ch 5V (jumper H) DC+	→	VU	oranye
Relay 1 ch 5V (jumper H) DC−	→	G	hitam
Relay 1 ch 5V (jumper H) IN	→	D1 GPIO5	biru
Baterai 3×AA (4,5V) +	→	Relay 1 ch 5V (jumper H) COM	merah
Relay 1 ch 5V (jumper H) NO	→	Soket USB + lampu USB VCC	merah
Soket USB + lampu USB GND	→	Baterai 3×AA (4,5V) −	hitam

Langkah 2: Siapkan dashboard Klenik

Lampu Lorongichibot/budi1234/p042/lampu

NYALA

0 detik lalu

Lama Nyalaichibot/budi1234/p042/detik

30detik30 of 600detik

0 detik lalu

Cara cepat: unduh p042.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Indikator Boolean Lampu Lorong	`ichibot/KODE/p042/lampu`	ON = `1` “NYALA”, OFF = `0`
Slider Output Lama Nyala	`ichibot/KODE/p042/detik`	5–600 detik

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: NodeMCU 1.0 (ESP-12E Module). Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p042.inoUnduh .ino

// Proyek 042 - Lampu Lorong Otomatis PIR
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LAMPU = "ichibot/budi1234/p042/lampu";
const char* TOPIK_DETIK = "ichibot/budi1234/p042/detik";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PIN_PIR = D5, PIN_RELAY = D1;
int detikNyala = 30;                  // lama lampu menyala setelah gerakan terakhir
bool lampu = false;
unsigned long gerakTerakhir = 0;

void atur(bool nyala) {
  lampu = nyala;
  digitalWrite(PIN_RELAY, nyala ? HIGH : LOW);
  mqtt.publish(TOPIK_LAMPU, nyala ? "1" : "0", true);
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  detikNyala = constrain(p.toInt(), 5, 600);
}

void langganan() {
  mqtt.subscribe(TOPIK_DETIK);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(PIN_PIR, INPUT);
  pinMode(PIN_RELAY, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (digitalRead(PIN_PIR) == HIGH) {
    gerakTerakhir = millis();         // setiap gerakan memperpanjang waktu nyala
    if (!lampu) atur(true);
  }
  if (lampu && millis() - gerakTerakhir > (unsigned long)detikNyala * 1000) atur(false);
}

// Proyek 042 - Lampu Lorong Otomatis PIR
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LAMPU = "ichibot/budi1234/p042/lampu";
const char* TOPIK_DETIK = "ichibot/budi1234/p042/detik";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PIN_PIR = D5, PIN_RELAY = D1;
int detikNyala = 30;                  // lama lampu menyala setelah gerakan terakhir
bool lampu = false;
unsigned long gerakTerakhir = 0;

void atur(bool nyala) {
  lampu = nyala;
  digitalWrite(PIN_RELAY, nyala ? HIGH : LOW);
  mqtt.publish(TOPIK_LAMPU, nyala ? "1" : "0", true);
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  detikNyala = constrain(p.toInt(), 5, 600);
}

void langganan() {
  mqtt.subscribe(TOPIK_DETIK);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(PIN_PIR, INPUT);
  pinMode(PIN_RELAY, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

if (digitalRead(PIN_PIR) == HIGH) {
    gerakTerakhir = millis();         // setiap gerakan memperpanjang waktu nyala
    if (!lampu) atur(true);
  }
  if (lampu && millis() - gerakTerakhir > (unsigned long)detikNyala * 1000) atur(false);
}

Langkah 4: Pahami kodenya

Setiap gerakan memperbarui waktu ini, jadi hitungan mundur selalu dimulai dari gerakan paling akhir.
Lampu mati kalau sudah sepi selama detikNyala detik. Trimpot "Time" di PIR sebaiknya di minimum, karena pengaturan waktu sudah dipegang kode.