Saklar tanpa tombol mekanis: cukup sentuh bantalan sensor. Setiap sentuhan membalik lampu (LED biru di NodeMCU), dan lampu yang sama bisa dinyalakan dari HP. Status di HP dan di meja selalu sama.

TTP223 mendeteksi perubahan kapasitansi saat jari mendekat, lalu mengeluarkan HIGH di pin I/O selama disentuh. NodeMCU membalik variabel lampu setiap kali sinyal berubah dari LOW ke HIGH. Switch di Klenik mengirim ON/OFF ke topic saklar. Dua-duanya memanggil kirim(), yang mengatur LED dan melaporkan status dengan retain. Karena itu tampilan HP selalu sesuai keadaan sebenarnya.

Komponen

Komponen	Qty	Harga
NodeMCU ESP8266 V3 (Lolin)	1	Rp42.000
Sensor sentuh TTP223	1	Rp5.000
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 3	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp50.500

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Sensor sentuh TTP223 VCC	→	3V	merah
Sensor sentuh TTP223 I/O	→	D5 GPIO14	kuning
Sensor sentuh TTP223 GND	→	G	hitam

Langkah 2: Siapkan dashboard Klenik

Saklar dari HPichibot/budi1234/p014/saklar

Lampu

0 detik lalu

Status Lampuichibot/budi1234/p014/lampu

NYALA

0 detik lalu

Riwayat Sentuhanichibot/budi1234/p014/log

Disentuh: lampu NYALA

Disentuh: lampu MATI

Disentuh: lampu NYALA

0 detik lalu

Cara cepat: unduh p014.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Switch Saklar dari HP	`ichibot/KODE/p014/saklar`	payload ON / OFF
Indikator Boolean Status Lampu	`ichibot/KODE/p014/lampu`	ON = `1` “NYALA”, OFF = `0`
Text Log Riwayat Sentuhan	`ichibot/KODE/p014/log`	menampilkan teks masuk

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: NodeMCU 1.0 (ESP-12E Module). Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p014.inoUnduh .ino

// Proyek 014 - Saklar Sentuh TTP223 ke Dashboard
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LAMPU  = "ichibot/budi1234/p014/lampu";
const char* TOPIK_SAKLAR = "ichibot/budi1234/p014/saklar";
const char* TOPIK_LOG    = "ichibot/budi1234/p014/log";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int SENTUH = D5;                // OUT modul TTP223: HIGH saat disentuh
const int LED_PAPAN = LED_BUILTIN;    // LED biru di NodeMCU, menyala saat LOW
bool tadi = LOW;
bool lampu = false;

void kirim() {
  digitalWrite(LED_PAPAN, lampu ? LOW : HIGH);
  mqtt.publish(TOPIK_LAMPU, lampu ? "1" : "0", true);
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  lampu = (p == "ON");
  kirim();
}

void langganan() {
  mqtt.subscribe(TOPIK_SAKLAR);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(SENTUH, INPUT);
  pinMode(LED_PAPAN, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
  kirim();
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  bool sekarang = digitalRead(SENTUH);
  if (sekarang != tadi) {
    tadi = sekarang;
    if (sekarang == HIGH) {           // tiap sentuhan membalik lampu
      lampu = !lampu;
      kirim();
      mqtt.publish(TOPIK_LOG, lampu ? "Disentuh: lampu NYALA" : "Disentuh: lampu MATI");
    }
  }
}

// Proyek 014 - Saklar Sentuh TTP223 ke Dashboard
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LAMPU  = "ichibot/budi1234/p014/lampu";
const char* TOPIK_SAKLAR = "ichibot/budi1234/p014/saklar";
const char* TOPIK_LOG    = "ichibot/budi1234/p014/log";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int SENTUH = D5;                // OUT modul TTP223: HIGH saat disentuh
const int LED_PAPAN = LED_BUILTIN;    // LED biru di NodeMCU, menyala saat LOW
bool tadi = LOW;
bool lampu = false;

void kirim() {
  digitalWrite(LED_PAPAN, lampu ? LOW : HIGH);
  mqtt.publish(TOPIK_LAMPU, lampu ? "1" : "0", true);
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  lampu = (p == "ON");
  kirim();
}

void langganan() {
  mqtt.subscribe(TOPIK_SAKLAR);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(SENTUH, INPUT);
  pinMode(LED_PAPAN, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
  kirim();
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

bool sekarang = digitalRead(SENTUH);
  if (sekarang != tadi) {
    tadi = sekarang;
    if (sekarang == HIGH) {           // tiap sentuhan membalik lampu
      lampu = !lampu;
      kirim();
      mqtt.publish(TOPIK_LOG, lampu ? "Disentuh: lampu NYALA" : "Disentuh: lampu MATI");
    }
  }
}

Langkah 4: Pahami kodenya

LED biru kecil di NodeMCU (GPIO2). Logikanya terbalik: menyala saat pin LOW.
Satu fungsi untuk semua perubahan: menyalakan/mematikan LED lalu melapor. Sentuhan maupun switch HP lewat sini.
Hanya awal sentuhan yang dihitung. Jari yang ditempel lama tidak membuat lampu berkedip-kedip.