Putar knob potensiometer, jarum gauge di HP ikut bergerak. Proyek ini mengajarkan cara membaca input analog, dasar untuk semua sensor yang hasilnya berupa tegangan.

Potensiometer adalah resistor dengan kaki tengah (wiper) yang bisa digeser. Kaki ujung disambung ke 3,3V dan G, sehingga kaki tengah mengeluarkan tegangan 0 sampai 3,3V sesuai putaran. Pin A0 NodeMCU mengubah tegangan itu menjadi angka 0-1023, lalu map() mengubahnya jadi 0-100%. Nilai dikirim tiap 200 ms, dan hanya kalau berubah, supaya broker tidak dibanjiri angka yang sama.

Komponen

Komponen	Qty	Harga
NodeMCU ESP8266 V3 (Lolin)	1	Rp42.000
Potensiometer 10K	1	Rp2.910
Breadboard mini 170 titik	1	Rp4.875
Kabel jumper male-female 10 cm (isi 10)isi 10, terpakai 3	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp53.285

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Potensiometer 10K 1	→	3V	merah
Potensiometer 10K W	→	A0	hijau
Potensiometer 10K 3	→	G	hitam

Langkah 2: Siapkan dashboard Klenik

Posisi Knobichibot/budi1234/p015/putar

0 detik lalu

Riwayat Putaranichibot/budi1234/p015/putar

64%

0.0%12 titik100.0%

0 detik lalu

Cara cepat: unduh p015.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Gauge Posisi Knob	`ichibot/KODE/p015/putar`	0–100 %
Chart Riwayat Putaran	`ichibot/KODE/p015/putar`	0–100 %

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: NodeMCU 1.0 (ESP-12E Module). Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p015.inoUnduh .ino

// Proyek 015 - Potensiometer jadi Gauge di HP
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_PUTAR = "ichibot/budi1234/p015/putar";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int POT = A0;                   // satu-satunya pin analog NodeMCU (0-1023)
int tadi = -1;
unsigned long terakhir = 0;

void langganan() {}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
  if (millis() - terakhir < 200) return;
  terakhir = millis();

  int mentah = analogRead(POT);
  int persen = map(mentah, 0, 1023, 0, 100);
  if (abs(persen - tadi) >= 1) {     // kirim hanya kalau berubah
    tadi = persen;
    mqtt.publish(TOPIK_PUTAR, String(persen).c_str());
    Serial.printf("mentah %d -> %d%%\n", mentah, persen);
  }
}

// Proyek 015 - Potensiometer jadi Gauge di HP
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_PUTAR = "ichibot/budi1234/p015/putar";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int POT = A0;                   // satu-satunya pin analog NodeMCU (0-1023)
int tadi = -1;
unsigned long terakhir = 0;

void langganan() {}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
  if (millis() - terakhir < 200) return;
  terakhir = millis();

int mentah = analogRead(POT);
  int persen = map(mentah, 0, 1023, 0, 100);
  if (abs(persen - tadi) >= 1) {     // kirim hanya kalau berubah
    tadi = persen;
    mqtt.publish(TOPIK_PUTAR, String(persen).c_str());
    Serial.printf("mentah %d -> %d%%\n", mentah, persen);
  }
}

Langkah 4: Pahami kodenya

NodeMCU hanya punya satu pin analog. Di board V3 sudah ada pembagi tegangan, jadi A0 aman menerima 0-3,3V.
Angka mentah 0-1023 diubah menjadi persen. Kalau putar penuh hanya sampai ±95%, itu wajar: ujung potensiometer jarang tepat 0 ohm.
Kirim hanya kalau berubah. Pembacaan analog sering bergetar ±1, jadi syarat ini juga mencegah pesan berulang yang sama.