Penghitung (counter) yang angkanya tampil di HP. Cocok untuk menghitung pengunjung, produk yang lewat, atau putaran lari. Angkanya bisa di-nol-kan dari dashboard.

Setiap tekanan menambah jumlah lalu mengirimnya dengan retain, jadi dashboard yang baru dibuka langsung menampilkan angka terakhir. Untuk reset, ketik reset di widget Text Input. NodeMCU membalas dengan angka 0 dan catatan di Text Log. Angka disimpan di RAM, jadi kembali ke 0 kalau NodeMCU restart.

Komponen

Komponen	Qty	Harga
NodeMCU ESP8266 V3 (Lolin)	1	Rp42.000
Push button 6×6 mm (isi 10)isi 10, terpakai 1	1	Rp4.750
Breadboard mini 170 titik	1	Rp4.875
Kabel jumper male-female 10 cm (isi 10)isi 10, terpakai 2	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp55.125

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Push button 6×6 mm 1	→	D5 GPIO14	biru
Push button 6×6 mm 2	→	G	hitam

Langkah 2: Siapkan dashboard Klenik

Jumlahichibot/budi1234/p013/jumlah

0 detik lalu

Perintahichibot/budi1234/p013/perintah

reset

Belum pernah dikirim

Catatanichibot/budi1234/p013/log

Penghitung di-reset dari HP

0 detik lalu

Cara cepat: unduh p013.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Gauge Jumlah	`ichibot/KODE/p013/jumlah`	0–100
TEXT_INPUT Perintah	`ichibot/KODE/p013/perintah`	teks bebas
Text Log Catatan	`ichibot/KODE/p013/log`	menampilkan teks masuk

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: NodeMCU 1.0 (ESP-12E Module). Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p013.inoUnduh .ino

// Proyek 013 - Penghitung Tekanan Tombol
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_JUMLAH   = "ichibot/budi1234/p013/jumlah";
const char* TOPIK_LOG      = "ichibot/budi1234/p013/log";
const char* TOPIK_PERINTAH = "ichibot/budi1234/p013/perintah";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int TOMBOL = D5;
bool tadi = HIGH;
unsigned long waktuTekan = 0;
int jumlah = 0;

void kirim() {
  mqtt.publish(TOPIK_JUMLAH, String(jumlah).c_str(), true);
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  p.trim(); p.toLowerCase();
  if (p == "reset") {
    jumlah = 0;
    kirim();
    mqtt.publish(TOPIK_LOG, "Penghitung di-reset dari HP");
  }
}

void langganan() {
  mqtt.subscribe(TOPIK_PERINTAH);
  kirim();
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(TOMBOL, INPUT_PULLUP);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  bool sekarang = digitalRead(TOMBOL);
  if (sekarang != tadi && millis() - waktuTekan > 50) {
    waktuTekan = millis();
    tadi = sekarang;
    if (sekarang == LOW) {
      jumlah++;
      kirim();
    }
  }
}

// Proyek 013 - Penghitung Tekanan Tombol
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_JUMLAH   = "ichibot/budi1234/p013/jumlah";
const char* TOPIK_LOG      = "ichibot/budi1234/p013/log";
const char* TOPIK_PERINTAH = "ichibot/budi1234/p013/perintah";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int TOMBOL = D5;
bool tadi = HIGH;
unsigned long waktuTekan = 0;
int jumlah = 0;

void kirim() {
  mqtt.publish(TOPIK_JUMLAH, String(jumlah).c_str(), true);
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  p.trim(); p.toLowerCase();
  if (p == "reset") {
    jumlah = 0;
    kirim();
    mqtt.publish(TOPIK_LOG, "Penghitung di-reset dari HP");
  }
}

void langganan() {
  mqtt.subscribe(TOPIK_PERINTAH);
  kirim();
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(TOMBOL, INPUT_PULLUP);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

bool sekarang = digitalRead(TOMBOL);
  if (sekarang != tadi && millis() - waktuTekan > 50) {
    waktuTekan = millis();
    tadi = sekarang;
    if (sekarang == LOW) {
      jumlah++;
      kirim();
    }
  }
}

Langkah 4: Pahami kodenya

Retain true: broker menyimpan angka terakhir, jadi gauge langsung terisi begitu dashboard dibuka.
Spasi dan huruf besar dibuang dulu, jadi Reset atau reset tetap dikenali.
Saat tersambung ke broker, proyek ini mendengarkan topic perintah dan langsung mengirim angka sekarang, supaya gauge tidak kosong.
Ditambah hanya saat tombol berubah dari lepas ke ditekan, jadi tombol yang ditahan tetap dihitung satu.