Tombol bel di pintu membunyikan buzzer di dalam rumah dan sekaligus mengirim pesan ke dashboard. Kamu tetap tahu ada tamu walaupun sedang di kamar atas atau di luar rumah.

Tombol dibaca dengan INPUT_PULLUP dan debounce seperti proyek 011. Saat ditekan, buzzer dinyalakan dan waktu matinya dicatat (bunyiSampai), jadi bunyinya berhenti sendiri setelah 0,8 detik tanpa delay(). Pesan "Ada tamu" dikirim ke Text Log, dan indikator TAMU menyala selama buzzer berbunyi. Dari HP kamu juga bisa mengetes bel lewat topic tes.

Komponen

Komponen	Qty	Harga
NodeMCU ESP8266 V3 (Lolin)	1	Rp42.000
Push button 6×6 mm (isi 10)isi 10, terpakai 1	1	Rp4.750
Modul buzzer aktif KY-012	1	Rp7.500
Breadboard mini 170 titik	1	Rp4.875
Kabel jumper male-female 10 cm (isi 10)isi 10, terpakai 5	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp62.625

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Push button 6×6 mm 1	→	D5 GPIO14	biru
Push button 6×6 mm 2	→	G	hitam
Modul buzzer aktif KY-012 S	→	D2 GPIO4	kuning
Modul buzzer aktif KY-012 +	→	3V	merah
Modul buzzer aktif KY-012 −	→	G	hitam

Langkah 2: Siapkan dashboard Klenik

Ada Tamuichibot/budi1234/p012/tamu

TAMU!

0 detik lalu

Riwayat Belichibot/budi1234/p012/bel

Ada tamu di depan!

0 detik lalu

Tes Belichibot/budi1234/p012/tes

tes

Belum pernah dikirim

Cara cepat: unduh p012.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Indikator Boolean Ada Tamu	`ichibot/KODE/p012/tamu`	ON = `1` “TAMU!”, OFF = `0`
Text Log Riwayat Bel	`ichibot/KODE/p012/bel`	menampilkan teks masuk
TEXT_INPUT Tes Bel	`ichibot/KODE/p012/tes`	teks bebas

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: NodeMCU 1.0 (ESP-12E Module). Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p012.inoUnduh .ino

// Proyek 012 - Bel Rumah WiFi
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_TES  = "ichibot/budi1234/p012/tes";
const char* TOPIK_BEL  = "ichibot/budi1234/p012/bel";
const char* TOPIK_TAMU = "ichibot/budi1234/p012/tamu";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int TOMBOL = D5, BUZZER = D2;
bool tadi = HIGH;
unsigned long waktuTekan = 0, bunyiSampai = 0;

void bunyi(unsigned long ms) {
  digitalWrite(BUZZER, HIGH);
  bunyiSampai = millis() + ms;
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  bunyi(300);                         // tes bel dari HP
}

void langganan() {
  mqtt.subscribe(TOPIK_TES);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(TOMBOL, INPUT_PULLUP);
  pinMode(BUZZER, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  bool sekarang = digitalRead(TOMBOL);
  if (sekarang != tadi && millis() - waktuTekan > 50) {
    waktuTekan = millis();
    tadi = sekarang;
    if (sekarang == LOW) {
      bunyi(800);
      mqtt.publish(TOPIK_BEL, "Ada tamu di depan!");
      mqtt.publish(TOPIK_TAMU, "1");
    }
  }
  if (bunyiSampai && (long)(millis() - bunyiSampai) >= 0) {
    digitalWrite(BUZZER, LOW);
    bunyiSampai = 0;
    mqtt.publish(TOPIK_TAMU, "0");
  }
}

// Proyek 012 - Bel Rumah WiFi
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_TES  = "ichibot/budi1234/p012/tes";
const char* TOPIK_BEL  = "ichibot/budi1234/p012/bel";
const char* TOPIK_TAMU = "ichibot/budi1234/p012/tamu";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int TOMBOL = D5, BUZZER = D2;
bool tadi = HIGH;
unsigned long waktuTekan = 0, bunyiSampai = 0;

void bunyi(unsigned long ms) {
  digitalWrite(BUZZER, HIGH);
  bunyiSampai = millis() + ms;
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  bunyi(300);                         // tes bel dari HP
}

void langganan() {
  mqtt.subscribe(TOPIK_TES);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(TOMBOL, INPUT_PULLUP);
  pinMode(BUZZER, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

bool sekarang = digitalRead(TOMBOL);
  if (sekarang != tadi && millis() - waktuTekan > 50) {
    waktuTekan = millis();
    tadi = sekarang;
    if (sekarang == LOW) {
      bunyi(800);
      mqtt.publish(TOPIK_BEL, "Ada tamu di depan!");
      mqtt.publish(TOPIK_TAMU, "1");
    }
  }
  if (bunyiSampai && (long)(millis() - bunyiSampai) >= 0) {
    digitalWrite(BUZZER, LOW);
    bunyiSampai = 0;
    mqtt.publish(TOPIK_TAMU, "0");
  }
}

Langkah 4: Pahami kodenya

Buzzer dinyalakan, lalu waktu matinya disimpan. loop() yang mematikannya nanti, jadi program tidak berhenti menunggu.
Pesan ini muncul di widget Text Log. Pesannya bisa diganti, misalnya nama ruangan kalau belnya lebih dari satu.
Kalau waktu bunyi sudah habis, buzzer dimatikan dan indikator TAMU kembali ke 0.
Teks apa pun yang dikirim lewat widget Tes Bel membuat buzzer berbunyi sebentar. Berguna untuk mengecek alat tanpa ke pintu.