Delapan LED pintar dalam satu batang, dikendalikan hanya lewat satu kabel data. Dari HP kamu menyalakan, mengatur warna, dan mengatur kecerahan.

Setiap LED WS2812 punya chip kecil di dalamnya. ESP32 mengirim deretan data lewat satu pin. LED pertama mengambil 24 bit pertama (warnanya sendiri) lalu meneruskan sisanya ke LED berikutnya. Library Adafruit NeoPixel mengurus waktu kirimnya yang sangat ketat. Modul ini dijual dengan bantalan solder, jadi perlu menyolder 3 pin header dulu ke bantalan 5V, GND, dan DIN.

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
Modul WS2812 8 LED (stick)	1	Rp11.640
Pin header male 40 pindipotong 3 pin, disolder ke modul	1	Rp1.455
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 3	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp91.595

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
WS2812 8 LED (pin header disolder) 5V	→	VIN	merah
WS2812 8 LED (pin header disolder) GND	→	GND	hitam
WS2812 8 LED (pin header disolder) DIN	→	D13 GPIO13	hijau

Langkah 2: Siapkan dashboard Klenik

Strip LEDichibot/budi1234/p006/nyala

Nyala

0 detik lalu

Kecerahanichibot/budi1234/p006/terang

40%40 of 100%

0 detik lalu

Merahichibot/budi1234/p006/r

255255 of 255

0 detik lalu

Hijauichibot/budi1234/p006/g

120120 of 255

0 detik lalu

Biruichibot/budi1234/p006/b

00 of 255

0 detik lalu

Cara cepat: unduh p006.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Switch Strip LED	`ichibot/KODE/p006/nyala`	payload ON / OFF
Slider Output Kecerahan	`ichibot/KODE/p006/terang`	0–100 %
Slider Output Merah	`ichibot/KODE/p006/r`	0–255
Slider Output Hijau	`ichibot/KODE/p006/g`	0–255
Slider Output Biru	`ichibot/KODE/p006/b`	0–255

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary), Adafruit NeoPixel. Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p006.inoUnduh .ino

// Proyek 006 - Strip WS2812 8 LED: Warna dari HP
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <Adafruit_NeoPixel.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_NYALA  = "ichibot/budi1234/p006/nyala";
const char* TOPIK_TERANG = "ichibot/budi1234/p006/terang";
const char* TOPIK_R      = "ichibot/budi1234/p006/r";
const char* TOPIK_G      = "ichibot/budi1234/p006/g";
const char* TOPIK_B      = "ichibot/budi1234/p006/b";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PIN_DIN = 13, JUMLAH = 8;
Adafruit_NeoPixel strip(JUMLAH, PIN_DIN, NEO_GRB + NEO_KHZ800);
int r = 255, g = 120, b = 0, terang = 40;
bool nyala = true;

void tampil() {
  strip.setBrightness(nyala ? map(terang, 0, 100, 0, 255) : 0);
  strip.fill(strip.Color(r, g, b));
  strip.show();
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t, p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (topik == TOPIK_NYALA) nyala = (p == "ON");
  else if (topik == TOPIK_TERANG) terang = constrain(p.toInt(), 0, 100);
  else if (topik == TOPIK_R) r = constrain(p.toInt(), 0, 255);
  else if (topik == TOPIK_G) g = constrain(p.toInt(), 0, 255);
  else if (topik == TOPIK_B) b = constrain(p.toInt(), 0, 255);
  tampil();
}

void langganan() {
  mqtt.subscribe(TOPIK_NYALA);
  mqtt.subscribe(TOPIK_TERANG);
  mqtt.subscribe(TOPIK_R);
  mqtt.subscribe(TOPIK_G);
  mqtt.subscribe(TOPIK_B);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  strip.begin();
  tampil();
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
}

// Proyek 006 - Strip WS2812 8 LED: Warna dari HP
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <Adafruit_NeoPixel.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_NYALA  = "ichibot/budi1234/p006/nyala";
const char* TOPIK_TERANG = "ichibot/budi1234/p006/terang";
const char* TOPIK_R      = "ichibot/budi1234/p006/r";
const char* TOPIK_G      = "ichibot/budi1234/p006/g";
const char* TOPIK_B      = "ichibot/budi1234/p006/b";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PIN_DIN = 13, JUMLAH = 8;
Adafruit_NeoPixel strip(JUMLAH, PIN_DIN, NEO_GRB + NEO_KHZ800);
int r = 255, g = 120, b = 0, terang = 40;
bool nyala = true;

void tampil() {
  strip.setBrightness(nyala ? map(terang, 0, 100, 0, 255) : 0);
  strip.fill(strip.Color(r, g, b));
  strip.show();
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t, p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (topik == TOPIK_NYALA) nyala = (p == "ON");
  else if (topik == TOPIK_TERANG) terang = constrain(p.toInt(), 0, 100);
  else if (topik == TOPIK_R) r = constrain(p.toInt(), 0, 255);
  else if (topik == TOPIK_G) g = constrain(p.toInt(), 0, 255);
  else if (topik == TOPIK_B) b = constrain(p.toInt(), 0, 255);
  tampil();
}

void langganan() {
  mqtt.subscribe(TOPIK_NYALA);
  mqtt.subscribe(TOPIK_TERANG);
  mqtt.subscribe(TOPIK_R);
  mqtt.subscribe(TOPIK_G);
  mqtt.subscribe(TOPIK_B);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  strip.begin();
  tampil();
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
}

Langkah 4: Pahami kodenya

Membuat objek strip: 8 LED di GPIO13. NEO_GRB karena WS2812 menerima urutan warna hijau-merah-biru.
Kecerahan diatur terpisah dari warna. Saat switch mati, kecerahan 0, dan warna terakhir tetap tersimpan.
fill() memberi warna yang sama ke semua LED, lalu show() baru benar-benar mengirim datanya ke strip.
Lima topic didaftarkan satu per satu, sama seperti lima widget di dashboard.