Satu LED berisi tiga warna: merah, hijau, biru. Tiga slider di HP mengatur campurannya, jadi kamu bisa membuat ungu, oranye, putih, atau warna apa pun.

LED RGB common cathode punya satu kaki minus bersama (kaki paling panjang) dan tiga kaki warna. Tiap kaki warna diberi PWM 0-255 dari pin ESP32 yang berbeda. Mata mencampur ketiganya: merah 255 + biru 255 terlihat ungu, ketiganya penuh terlihat putih kebiruan. Di ESP32 core 3.x, analogWrite() bisa langsung dipakai untuk PWM.

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
LED RGB 5 mm common cathode	1	Rp1.261
Resistor 330 Ω (isi 10)isi 10, terpakai 3	1	Rp1.800
Breadboard mini 170 titik	1	Rp4.875
Kabel jumper male-female 10 cm (isi 10)isi 10, terpakai 4	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp86.436

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
LED RGB common cathode + 3 resistor R	→	D25 GPIO25	merah
LED RGB common cathode + 3 resistor G	→	D26 GPIO26	hijau
LED RGB common cathode + 3 resistor B	→	D27 GPIO27	biru
LED RGB common cathode + 3 resistor −	→	GND	hitam

Langkah 2: Siapkan dashboard Klenik

Merahichibot/budi1234/p005/r

180180 of 255

0 detik lalu

Hijauichibot/budi1234/p005/g

4040 of 255

0 detik lalu

Biruichibot/budi1234/p005/b

220220 of 255

0 detik lalu

Cara cepat: unduh p005.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Slider Output Merah	`ichibot/KODE/p005/r`	0–255
Slider Output Hijau	`ichibot/KODE/p005/g`	0–255
Slider Output Biru	`ichibot/KODE/p005/b`	0–255

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p005.inoUnduh .ino

// Proyek 005 - LED RGB Pilih Warna
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_R    = "ichibot/budi1234/p005/r";
const char* TOPIK_G    = "ichibot/budi1234/p005/g";
const char* TOPIK_B    = "ichibot/budi1234/p005/b";
const char* TOPIK_MATI = "ichibot/budi1234/p005/mati";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PIN_R = 25, PIN_G = 26, PIN_B = 27;
int r = 0, g = 0, b = 0;

void tampil() {
  analogWrite(PIN_R, r);
  analogWrite(PIN_G, g);
  analogWrite(PIN_B, b);
  Serial.printf("R%d G%d B%d\n", r, g, b);
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t, p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  int v = constrain(p.toInt(), 0, 255);
  if (topik == TOPIK_R) r = v;
  else if (topik == TOPIK_G) g = v;
  else if (topik == TOPIK_B) b = v;
  else if (topik == TOPIK_MATI && p == "ON") r = g = b = 0;
  tampil();
}

void langganan() {
  mqtt.subscribe(TOPIK_R);
  mqtt.subscribe(TOPIK_G);
  mqtt.subscribe(TOPIK_B);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
  tampil();
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
}

// Proyek 005 - LED RGB Pilih Warna
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_R    = "ichibot/budi1234/p005/r";
const char* TOPIK_G    = "ichibot/budi1234/p005/g";
const char* TOPIK_B    = "ichibot/budi1234/p005/b";
const char* TOPIK_MATI = "ichibot/budi1234/p005/mati";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PIN_R = 25, PIN_G = 26, PIN_B = 27;
int r = 0, g = 0, b = 0;

void tampil() {
  analogWrite(PIN_R, r);
  analogWrite(PIN_G, g);
  analogWrite(PIN_B, b);
  Serial.printf("R%d G%d B%d\n", r, g, b);
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t, p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  int v = constrain(p.toInt(), 0, 255);
  if (topik == TOPIK_R) r = v;
  else if (topik == TOPIK_G) g = v;
  else if (topik == TOPIK_B) b = v;
  else if (topik == TOPIK_MATI && p == "ON") r = g = b = 0;
  tampil();
}

void langganan() {
  mqtt.subscribe(TOPIK_R);
  mqtt.subscribe(TOPIK_G);
  mqtt.subscribe(TOPIK_B);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
  tampil();
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
}

Langkah 4: Pahami kodenya

Tiga pin PWM yang berdampingan di baris bawah ESP32, jadi kabelnya rapi.
Tiap warna mendapat nilai 0-255 sendiri. Ketiganya ditulis ulang setiap ada perubahan, supaya warna selalu sesuai tiga slider.
Nilai dari slider dijaga tetap di 0-255 sebelum dipakai.