Rangkaiannya sama dengan proyek 006, kodenya yang berbeda. Strip WS2812 menampilkan animasi pelangi, titik berjalan, atau kedip. Mode dipilih dengan mengetik nama mode di HP, kecepatannya dari slider.

Animasi dibuat dengan menggambar satu "frame" setiap jeda milidetik. Variabel langkah bertambah tiap frame, dan setiap mode memakai langkah dengan caranya sendiri. Pelangi menggeser warna HSV, titik berjalan memindahkan satu LED, kedip menyala di langkah ganjil. Widget Text Input mengirim teks mentah, misalnya pelangi, ke topic .../p007/mode.

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
Modul WS2812 8 LED (stick)	1	Rp11.640
Pin header male 40 pindipotong 3 pin, disolder ke modul	1	Rp1.455
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 3	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp91.595

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
WS2812 8 LED (pin header disolder) 5V	→	VIN	merah
WS2812 8 LED (pin header disolder) GND	→	GND	hitam
WS2812 8 LED (pin header disolder) DIN	→	D13 GPIO13	hijau

Langkah 2: Siapkan dashboard Klenik

Pilih Modeichibot/budi1234/p007/mode

pelangi

Belum pernah dikirim

Jeda Animasiichibot/budi1234/p007/jeda

80ms80 of 500ms

0 detik lalu

Log Modeichibot/budi1234/p007/log

mode: jalan, jeda 80 ms

mode: pelangi, jeda 80 ms

0 detik lalu

Cara cepat: unduh p007.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
TEXT_INPUT Pilih Mode	`ichibot/KODE/p007/mode`	teks bebas
Slider Output Jeda Animasi	`ichibot/KODE/p007/jeda`	10–500 ms
Text Log Log Mode	`ichibot/KODE/p007/log`	menampilkan teks masuk

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary), Adafruit NeoPixel. Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p007.inoUnduh .ino

// Proyek 007 - Running LED WS2812 dengan Mode
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <Adafruit_NeoPixel.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LOG  = "ichibot/budi1234/p007/log";
const char* TOPIK_MODE = "ichibot/budi1234/p007/mode";
const char* TOPIK_JEDA = "ichibot/budi1234/p007/jeda";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PIN_DIN = 13, JUMLAH = 8;
Adafruit_NeoPixel strip(JUMLAH, PIN_DIN, NEO_GRB + NEO_KHZ800);
String mode = "pelangi";              // pelangi | jalan | kedip | mati
int jeda = 80;                        // ms per langkah animasi
int langkah = 0;
unsigned long terakhir = 0;

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t, p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (topik == TOPIK_MODE) { p.toLowerCase(); p.trim(); mode = p; }
  else if (topik == TOPIK_JEDA) jeda = constrain(p.toInt(), 10, 500);
  mqtt.publish(TOPIK_LOG, ("mode: " + mode + ", jeda " + String(jeda) + " ms").c_str());
}

void langganan() {
  mqtt.subscribe(TOPIK_MODE);
  mqtt.subscribe(TOPIK_JEDA);
}

void animasi() {
  strip.clear();
  if (mode == "pelangi") {
    for (int i = 0; i < JUMLAH; i++)
      strip.setPixelColor(i, strip.ColorHSV((langkah * 512 + i * 65536 / JUMLAH) % 65536));
  } else if (mode == "jalan") {
    strip.setPixelColor(langkah % JUMLAH, strip.Color(0, 120, 255));
  } else if (mode == "kedip") {
    if (langkah % 2) strip.fill(strip.Color(255, 60, 0));
  }
  strip.show();
  langkah++;
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  strip.begin();
  strip.setBrightness(60);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
  if (millis() - terakhir >= (unsigned long)jeda) {
    terakhir = millis();
    animasi();
  }
}

// Proyek 007 - Running LED WS2812 dengan Mode
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <Adafruit_NeoPixel.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LOG  = "ichibot/budi1234/p007/log";
const char* TOPIK_MODE = "ichibot/budi1234/p007/mode";
const char* TOPIK_JEDA = "ichibot/budi1234/p007/jeda";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PIN_DIN = 13, JUMLAH = 8;
Adafruit_NeoPixel strip(JUMLAH, PIN_DIN, NEO_GRB + NEO_KHZ800);
String mode = "pelangi";              // pelangi | jalan | kedip | mati
int jeda = 80;                        // ms per langkah animasi
int langkah = 0;
unsigned long terakhir = 0;

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t, p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (topik == TOPIK_MODE) { p.toLowerCase(); p.trim(); mode = p; }
  else if (topik == TOPIK_JEDA) jeda = constrain(p.toInt(), 10, 500);
  mqtt.publish(TOPIK_LOG, ("mode: " + mode + ", jeda " + String(jeda) + " ms").c_str());
}

void langganan() {
  mqtt.subscribe(TOPIK_MODE);
  mqtt.subscribe(TOPIK_JEDA);
}

void animasi() {
  strip.clear();
  if (mode == "pelangi") {
    for (int i = 0; i < JUMLAH; i++)
      strip.setPixelColor(i, strip.ColorHSV((langkah * 512 + i * 65536 / JUMLAH) % 65536));
  } else if (mode == "jalan") {
    strip.setPixelColor(langkah % JUMLAH, strip.Color(0, 120, 255));
  } else if (mode == "kedip") {
    if (langkah % 2) strip.fill(strip.Color(255, 60, 0));
  }
  strip.show();
  langkah++;
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  strip.begin();
  strip.setBrightness(60);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();
  if (millis() - terakhir >= (unsigned long)jeda) {
    terakhir = millis();
    animasi();
  }
}

Langkah 4: Pahami kodenya

Teks dari HP dibuat huruf kecil dan dibuang spasinya, jadi Pelangi tetap dikenali sebagai pelangi.
Warna HSV memakai sudut 0-65535 di roda warna. Tiap LED diberi sudut berbeda, dan seluruh sudut bergeser tiap langkah. Hasilnya pelangi yang berjalan.
% (sisa bagi) membuat angka kembali ke 0 setelah 7, jadi titik biru berjalan berputar terus.
Satu frame digambar setiap jeda ms. Teks mode yang tidak dikenal (atau mati) hanya menjalankan strip.clear(), jadi semua LED padam.