Penghitung pengunjung untuk perpustakaan, toko, atau pameran: sensor inframerah di pintu menghitung orang masuk, LCD menampilkan jumlahnya dan tanda PENUH saat ramai, dan Klenik menggambar grafik pengunjung per jam untuk melihat jam tersibuk.

KY-032 dipasang setinggi pinggang di sisi pintu. Setiap orang lewat memantulkan inframerah, dan hitungan bertambah. Jeda 1,5 detik mencegah satu orang terhitung dua kali karena tangan dan badan lewat bergantian.

Dengan jam NTP, data dikelompokkan per jam. Setiap jam berganti, jumlah orang selama jam tadi dikirim ke grafik, sehingga terlihat jam-jam tersibuk. Saat jumlah orang dalam satu jam mencapai kapasitas, LCD di pintu menampilkan "PENUH". Setiap hari baru, total kemarin dilaporkan dan hitungan dimulai dari nol.

Satu sensor hanya bisa menghitung orang lewat, tidak bisa membedakan masuk dan keluar. Untuk menghitung orang di dalam ruangan, pakai dua sensor dan lihat urutan mana yang tertutup lebih dulu (lihat Coba kembangkan).

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
Sensor IR KY-032	1	Rp7.500
LCD 1602 Biru Terpasang I2C IIC 16×02 Display Mo	1	Rp37.500
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 7	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp123.500

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Sensor IR KY-032 GND	→	GND	hitam
Sensor IR KY-032 +	→	3V3	merah
Sensor IR KY-032 OUT	→	D27 GPIO27	hijau
LCD 16×2 + modul I2C GND	→	GND	hitam
LCD 16×2 + modul I2C VCC	→	VIN	merah
LCD 16×2 + modul I2C SDA	→	D21 GPIO21	biru
LCD 16×2 + modul I2C SCL	→	D22 GPIO22	kuning

Langkah 2: Siapkan dashboard Klenik

Pengunjung Hari Iniichibot/budi1234/p147/hari

0 detik lalu

Pengunjung per Jamichibot/budi1234/p147/perjam

0.010 titik60.0

0 detik lalu

Laporan Harianichibot/budi1234/p147/log

Total kemarin: 187 pengunjung

0 detik lalu

Cara cepat: unduh p147.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Gauge Pengunjung Hari Ini	`ichibot/KODE/p147/hari`	0–300
Chart Pengunjung per Jam	`ichibot/KODE/p147/perjam`	0–60
Text Log Laporan Harian	`ichibot/KODE/p147/log`	menampilkan teks masuk

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary), LiquidCrystal I2C (Frank de Brabander). Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p147.inoUnduh .ino

// Proyek 147 - Penghitung Pengunjung + Layar LCD
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_HARI   = "ichibot/budi1234/p147/hari";
const char* TOPIK_PERJAM = "ichibot/budi1234/p147/perjam";
const char* TOPIK_LOG    = "ichibot/budi1234/p147/log";
const int KAPASITAS = 30;             // maksimal orang di dalam ruangan

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
LiquidCrystal_I2C lcd(0x27, 16, 2);
const int SENSOR = 27;                // KY-032 di pintu masuk
int hariIni = 0, perJam = 0;
bool adaTadi = false;
unsigned long lewatTerakhir = 0;
int jamTadi = -1, hariTadi = -1;

void tampilkan() {
  lcd.setCursor(0, 0);
  lcd.print("Pengunjung: ");
  lcd.print(hariIni);
  lcd.print("   ");
  lcd.setCursor(0, 1);
  lcd.print(perJam >= KAPASITAS ? "PENUH, tunggu.. " : "Silakan masuk   ");
}

void langganan() {}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(SENSOR, INPUT);
  lcd.init();
  lcd.backlight();
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org");
  mqtt.setServer(BROKER, 1883);
  tampilkan();
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  bool ada = digitalRead(SENSOR) == LOW;
  if (ada && !adaTadi && millis() - lewatTerakhir > 1500) {   // satu orang ±1,5 detik
    lewatTerakhir = millis();
    hariIni++;
    perJam++;
    tampilkan();
    mqtt.publish(TOPIK_HARI, String(hariIni).c_str(), true);
  }
  adaTadi = ada;

  time_t t = time(nullptr);
  if (t < 1700000000) return;
  struct tm* w = localtime(&t);
  if (w->tm_hour != jamTadi) {        // jam baru: kirim jumlah jam lalu ke grafik
    if (jamTadi != -1) mqtt.publish(TOPIK_PERJAM, String(perJam).c_str());
    jamTadi = w->tm_hour;
    perJam = 0;
    tampilkan();
  }
  if (w->tm_mday != hariTadi) {
    if (hariTadi != -1) mqtt.publish(TOPIK_LOG, ("Total kemarin: " + String(hariIni) + " pengunjung").c_str());
    hariTadi = w->tm_mday;
    hariIni = 0;
    tampilkan();
  }
}

// Proyek 147 - Penghitung Pengunjung + Layar LCD
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_HARI   = "ichibot/budi1234/p147/hari";
const char* TOPIK_PERJAM = "ichibot/budi1234/p147/perjam";
const char* TOPIK_LOG    = "ichibot/budi1234/p147/log";
const int KAPASITAS = 30;             // maksimal orang di dalam ruangan

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
LiquidCrystal_I2C lcd(0x27, 16, 2);
const int SENSOR = 27;                // KY-032 di pintu masuk
int hariIni = 0, perJam = 0;
bool adaTadi = false;
unsigned long lewatTerakhir = 0;
int jamTadi = -1, hariTadi = -1;

void tampilkan() {
  lcd.setCursor(0, 0);
  lcd.print("Pengunjung: ");
  lcd.print(hariIni);
  lcd.print("   ");
  lcd.setCursor(0, 1);
  lcd.print(perJam >= KAPASITAS ? "PENUH, tunggu.. " : "Silakan masuk   ");
}

void langganan() {}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(SENSOR, INPUT);
  lcd.init();
  lcd.backlight();
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org");
  mqtt.setServer(BROKER, 1883);
  tampilkan();
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

bool ada = digitalRead(SENSOR) == LOW;
  if (ada && !adaTadi && millis() - lewatTerakhir > 1500) {   // satu orang ±1,5 detik
    lewatTerakhir = millis();
    hariIni++;
    perJam++;
    tampilkan();
    mqtt.publish(TOPIK_HARI, String(hariIni).c_str(), true);
  }
  adaTadi = ada;

time_t t = time(nullptr);
  if (t < 1700000000) return;
  struct tm* w = localtime(&t);
  if (w->tm_hour != jamTadi) {        // jam baru: kirim jumlah jam lalu ke grafik
    if (jamTadi != -1) mqtt.publish(TOPIK_PERJAM, String(perJam).c_str());
    jamTadi = w->tm_hour;
    perJam = 0;
    tampilkan();
  }
  if (w->tm_mday != hariTadi) {
    if (hariTadi != -1) mqtt.publish(TOPIK_LOG, ("Total kemarin: " + String(hariIni) + " pengunjung").c_str());
    hariTadi = w->tm_mday;
    hariIni = 0;
    tampilkan();
  }
}

Langkah 4: Pahami kodenya

Tepi naik plus jeda 1,5 detik. Antrean yang sangat rapat bisa terhitung kurang, jadi sesuaikan dengan pintumu.
Setiap jam berganti, satu titik ditambahkan ke grafik per jam.
Spasi di ujung teks menimpa sisa huruf lama di LCD, jadi tidak perlu lcd.clear() yang membuat layar berkedip.