Stasiun Cuaca Mini

// Proyek 145 - Stasiun Cuaca Mini
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <Wire.h>
#include <DHT.h>
#include <Adafruit_BMP280.h>
#include <BH1750.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_SUHU    = "ichibot/budi1234/p145/suhu";
const char* TOPIK_LEMBAP  = "ichibot/budi1234/p145/lembap";
const char* TOPIK_TEKANAN = "ichibot/budi1234/p145/tekanan";
const char* TOPIK_LUX     = "ichibot/budi1234/p145/lux";
const char* TOPIK_HUJAN   = "ichibot/budi1234/p145/hujan";
const char* TOPIK_RAMALAN = "ichibot/budi1234/p145/ramalan";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
DHT dht(4, DHT22);
Adafruit_BMP280 bmp;                  // I2C 0x76
BH1750 cahaya;                        // I2C 0x23, satu jalur SDA/SCL dengan BMP280
const int PIN_HUJAN = 34;
float tekananTadi = 0;
unsigned long terakhir = 0, trenTerakhir = 0;

String ramalan(float turunPerJam) {   // ramalan sederhana dari perubahan tekanan udara
  if (turunPerJam > 1.0) return "Cuaca memburuk, kemungkinan hujan";
  if (turunPerJam < -1.0) return "Cuaca membaik";
  return "Cuaca stabil";
}

void langganan() {}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  dht.begin();
  Wire.begin();
  if (!bmp.begin(0x76) && !bmp.begin(0x77)) Serial.println("BMP280 tidak ditemukan");
  if (!cahaya.begin()) Serial.println("BH1750 tidak ditemukan");
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (millis() - terakhir < 10000) return;
  terakhir = millis();
  float suhu = dht.readTemperature(), lembap = dht.readHumidity();
  float hpa = bmp.readPressure() / 100.0;
  float lux = cahaya.readLightLevel();
  int hujan = constrain(map(analogRead(PIN_HUJAN), 4095, 1200, 0, 100), 0, 100);

  if (!isnan(suhu)) {
    mqtt.publish(TOPIK_SUHU, String(suhu, 1).c_str());
    mqtt.publish(TOPIK_LEMBAP, String(lembap, 0).c_str());
  }
  mqtt.publish(TOPIK_TEKANAN, String(hpa, 1).c_str());
  mqtt.publish(TOPIK_LUX, String(lux, 0).c_str());
  mqtt.publish(TOPIK_HUJAN, String(hujan).c_str());

  if (millis() - trenTerakhir >= 3600000UL || tekananTadi == 0) {   // bandingkan tekanan tiap jam
    if (tekananTadi > 0) mqtt.publish(TOPIK_RAMALAN, ramalan(tekananTadi - hpa).c_str());
    tekananTadi = hpa;
    trenTerakhir = millis();
  }
}