Rumah Aman: Gas, Api, Gerak

// Proyek 143 - Rumah Aman: Gas, Api, Gerak
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_SIAGA  = "ichibot/budi1234/p143/siaga";
const char* TOPIK_BAHAYA = "ichibot/budi1234/p143/bahaya";
const char* TOPIK_LOG    = "ichibot/budi1234/p143/log";
const char* TOPIK_GAS    = "ichibot/budi1234/p143/gas";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PIN_GAS = 34, API = 18, PIR = 27, SIRINE = 25;
const int BATAS_GAS = 40;
int dasar = 0;
bool siap = false, siagaMaling = false;
String bahayaTadi = "";
unsigned long terakhir = 0;

int bacaGas() {
  long jumlah = 0;
  for (int i = 0; i < 20; i++) jumlah += analogRead(PIN_GAS);
  return jumlah / 20;
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  siagaMaling = (p == "ON");          // sensor gerak hanya dipakai saat rumah ditinggal
}

void langganan() {
  mqtt.subscribe(TOPIK_SIAGA);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(API, INPUT);
  pinMode(PIR, INPUT);
  pinMode(SIRINE, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (millis() - terakhir < 500) return;
  terakhir = millis();
  int mentah = bacaGas();
  if (!siap && millis() > 60000) { dasar = max(mentah, 50); siap = true; }
  int gas = siap ? constrain((mentah - dasar) * 100 / dasar, 0, 500) : 0;

  String bahaya = "";                 // gas & api selalu dijaga, gerak hanya saat siaga
  if (digitalRead(API) == LOW) bahaya = "API";
  else if (gas > BATAS_GAS) bahaya = "GAS/ASAP";
  else if (siagaMaling && digitalRead(PIR) == HIGH) bahaya = "GERAKAN";

  digitalWrite(SIRINE, bahaya.length() && (millis() / 250) % 2);
  if (bahaya != bahayaTadi) {
    bahayaTadi = bahaya;
    mqtt.publish(TOPIK_BAHAYA, bahaya.length() ? "1" : "0", true);
    mqtt.publish(TOPIK_LOG, bahaya.length() ? ("BAHAYA: " + bahaya).c_str() : "Kembali aman");
  }
  static unsigned long kirim = 0;
  if (millis() - kirim > 5000) { kirim = millis(); mqtt.publish(TOPIK_GAS, String(gas).c_str()); }
}