Smart Garden Lengkap

// Proyek 142 - Smart Garden Lengkap
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_POMPA = "ichibot/budi1234/p142/pompa";
const char* TOPIK_LOG   = "ichibot/budi1234/p142/log";
const char* TOPIK_SIRAM = "ichibot/budi1234/p142/siram";
const char* TOPIK_BATAS = "ichibot/budi1234/p142/batas";
const char* TOPIK_TANAH = "ichibot/budi1234/p142/tanah";
const char* TOPIK_SUHU  = "ichibot/budi1234/p142/suhu";
const char* TOPIK_UDARA = "ichibot/budi1234/p142/udara";
const int NILAI_KERING = 3300, NILAI_BASAH = 1300;   // kalibrasi sensor tanah (proyek 061)

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
DHT dht(4, DHT11);
const int PIN_TANAH = 34, POMPA = 26;
const unsigned long MAKS_SIRAM = 20000;   // sekali siram maksimal 20 detik
int batasKering = 40;
bool pompa = false;
unsigned long pompaSejak = 0, terakhir = 0;
float siramHariIni = 0;               // detik pompa menyala hari ini
int hariTadi = -1;

void aturPompa(bool v, const char* sebab) {
  if (v == pompa) return;
  pompa = v;
  digitalWrite(POMPA, v ? HIGH : LOW);
  if (v) pompaSejak = millis();
  else siramHariIni += (millis() - pompaSejak) / 1000.0;
  mqtt.publish(TOPIK_POMPA, v ? "1" : "0", true);
  mqtt.publish(TOPIK_LOG, (String(v ? "Mulai siram" : "Selesai siram") + " (" + sebab + ")").c_str());
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t;
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (topik == TOPIK_BATAS) batasKering = p.toInt();
  else if (topik == TOPIK_SIRAM && p == "ON") { aturPompa(true, "manual"); mqtt.publish(TOPIK_SIRAM, "OFF"); }
}

void langganan() {
  mqtt.subscribe(TOPIK_BATAS);
  mqtt.subscribe(TOPIK_SIRAM);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(POMPA, OUTPUT);
  dht.begin();
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org");
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (pompa && millis() - pompaSejak > MAKS_SIRAM) aturPompa(false, "waktu habis");

  if (millis() - terakhir < 5000) return;
  terakhir = millis();
  int tanah = constrain(map(analogRead(PIN_TANAH), NILAI_KERING, NILAI_BASAH, 0, 100), 0, 100);
  float suhu = dht.readTemperature();
  float udara = dht.readHumidity();
  mqtt.publish(TOPIK_TANAH, String(tanah).c_str());
  if (!isnan(suhu)) {
    mqtt.publish(TOPIK_SUHU, String(suhu, 1).c_str());
    mqtt.publish(TOPIK_UDARA, String(udara, 0).c_str());
  }

  time_t t = time(nullptr);
  struct tm* w = localtime(&t);
  bool siang = t > 1700000000 && w->tm_hour >= 10 && w->tm_hour < 15;   // hindari siram terik matahari
  if (!pompa && tanah < batasKering && !siang) aturPompa(true, "tanah kering");
  if (pompa && tanah > batasKering + 15) aturPompa(false, "tanah cukup basah");

  if (t > 1700000000 && w->tm_mday != hariTadi) {
    if (hariTadi != -1) mqtt.publish(TOPIK_LOG, ("Kemarin pompa menyala " + String(siramHariIni, 0) + " detik").c_str());
    hariTadi = w->tm_mday;
    siramHariIni = 0;
  }
}