Tempel sensor getar di badan mesin cuci, dan Klenik memberi tahu saat cucian selesai, lengkap dengan lama mesin bekerja. Cocok untuk mesin cuci lama tanpa bunyi selesai, atau mesin di lantai jemur yang bunyinya tidak terdengar dari dalam rumah.

Mesin cuci yang bekerja terus bergetar. SW-420 mengirim HIGH setiap kali bergetar. Selama getaran masih datang, mesin dianggap jalan. Mesin cuci juga sering diam sebentar di antara tahap (merendam, mengisi air), jadi mesin baru dianggap selesai setelah 3 menit tanpa getaran sama sekali.

Laporan selesai hanya dikirim kalau mesin sudah bergetar lebih dari 5 menit, sehingga getaran sebentar dari orang yang menyenggol mesin tidak membuat laporan palsu. Jumlah getaran per menit dikirim ke grafik, dan dari pola grafiknya tahap mencuci, membilas, dan memeras bisa dikenali.

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
SW-420 Sensor Getar Vibration Module Getaran Ard	1	Rp8.500
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 3	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp87.000

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Sensor getar SW-420 VCC	→	3V3	merah
Sensor getar SW-420 GND	→	GND	hitam
Sensor getar SW-420 DO	→	D27 GPIO27	biru

Langkah 2: Siapkan dashboard Klenik

Mesin Cuciichibot/budi1234/p124/status

BEKERJA

0 detik lalu

Getaran per Menitichibot/budi1234/p124/getar

0.011 titik300.0

0 detik lalu

Pemberitahuanichibot/budi1234/p124/log

Cucian SELESAI! Mesin jalan 47 menit

0 detik lalu

Cara cepat: unduh p124.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Indikator Boolean Mesin Cuci	`ichibot/KODE/p124/status`	ON = `1` “BEKERJA”, OFF = `0`
Chart Getaran per Menit	`ichibot/KODE/p124/getar`	0–300
Text Log Pemberitahuan	`ichibot/KODE/p124/log`	menampilkan teks masuk

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p124.inoUnduh .ino

// Proyek 124 - Deteksi Mesin Cuci Selesai
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_STATUS = "ichibot/budi1234/p124/status";
const char* TOPIK_LOG    = "ichibot/budi1234/p124/log";
const char* TOPIK_GETAR  = "ichibot/budi1234/p124/getar";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int GETAR = 27;
const unsigned long DIAM_SELESAI = 3UL * 60 * 1000;   // diam 3 menit = selesai
const unsigned long MIN_JALAN = 5UL * 60 * 1000;      // harus sudah jalan 5 menit dulu
bool jalan = false;
unsigned long getarTerakhir = 0, mulaiJalan = 0, kirimTerakhir = 0;
int getarMenitIni = 0;

void langganan() {}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(GETAR, INPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (digitalRead(GETAR) == HIGH) {
    if (millis() - getarTerakhir > 100) getarMenitIni++;
    getarTerakhir = millis();
    if (!jalan) {
      jalan = true;
      mulaiJalan = millis();
      mqtt.publish(TOPIK_STATUS, "1", true);
    }
  }

  if (jalan && millis() - getarTerakhir > DIAM_SELESAI) {
    jalan = false;
    mqtt.publish(TOPIK_STATUS, "0", true);
    unsigned long lama = (getarTerakhir - mulaiJalan) / 60000;
    if (getarTerakhir - mulaiJalan > MIN_JALAN)   // getaran sebentar (orang lewat) tidak dilaporkan
      mqtt.publish(TOPIK_LOG, ("Cucian SELESAI! Mesin jalan " + String(lama) + " menit").c_str());
  }

  if (millis() - kirimTerakhir >= 60000) {
    kirimTerakhir = millis();
    mqtt.publish(TOPIK_GETAR, String(getarMenitIni).c_str());
    getarMenitIni = 0;
  }
}

// Proyek 124 - Deteksi Mesin Cuci Selesai
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_STATUS = "ichibot/budi1234/p124/status";
const char* TOPIK_LOG    = "ichibot/budi1234/p124/log";
const char* TOPIK_GETAR  = "ichibot/budi1234/p124/getar";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int GETAR = 27;
const unsigned long DIAM_SELESAI = 3UL * 60 * 1000;   // diam 3 menit = selesai
const unsigned long MIN_JALAN = 5UL * 60 * 1000;      // harus sudah jalan 5 menit dulu
bool jalan = false;
unsigned long getarTerakhir = 0, mulaiJalan = 0, kirimTerakhir = 0;
int getarMenitIni = 0;

void langganan() {}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(GETAR, INPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

if (digitalRead(GETAR) == HIGH) {
    if (millis() - getarTerakhir > 100) getarMenitIni++;
    getarTerakhir = millis();
    if (!jalan) {
      jalan = true;
      mulaiJalan = millis();
      mqtt.publish(TOPIK_STATUS, "1", true);
    }
  }

if (jalan && millis() - getarTerakhir > DIAM_SELESAI) {
    jalan = false;
    mqtt.publish(TOPIK_STATUS, "0", true);
    unsigned long lama = (getarTerakhir - mulaiJalan) / 60000;
    if (getarTerakhir - mulaiJalan > MIN_JALAN)   // getaran sebentar (orang lewat) tidak dilaporkan
      mqtt.publish(TOPIK_LOG, ("Cucian SELESAI! Mesin jalan " + String(lama) + " menit").c_str());
  }

if (millis() - kirimTerakhir >= 60000) {
    kirimTerakhir = millis();
    mqtt.publish(TOPIK_GETAR, String(getarMenitIni).c_str());
    getarMenitIni = 0;
  }
}

Langkah 4: Pahami kodenya

Lama diam yang dianggap selesai. Kalau mesinmu merendam lebih lama dari 3 menit, naikkan angka ini.
Penyaring laporan palsu: hanya kerja lebih dari 5 menit yang dilaporkan sebagai cucian.
Getaran yang datang beruntun dalam 100 ms dihitung satu, supaya grafik tidak berisi ribuan.