Arus Listrik AC Non-Invasif SCT-013

// Proyek 123 - Arus Listrik AC Non-Invasif SCT-013
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_ARUS = "ichibot/budi1234/p123/arus";
const char* TOPIK_DAYA = "ichibot/budi1234/p123/daya";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PIN_CT = 34;
const float AMPERE_PER_VOLT = 30.0;   // SCT-013-030: 30 A menghasilkan 1 V
const float TEGANGAN_PLN = 220.0;
unsigned long terakhir = 0;

float ukurIrms() {                    // 2000 sampel ±10 siklus 50 Hz
  const int N = 2000;
  long jumlah = 0;
  static int data[N];
  for (int i = 0; i < N; i++) { data[i] = analogReadMilliVolts(PIN_CT); jumlah += data[i]; delayMicroseconds(100); }
  float tengah = (float)jumlah / N;   // titik bias (±1650 mV)
  double kuadrat = 0;
  for (int i = 0; i < N; i++) kuadrat += sq(data[i] - tengah);
  float vrms = sqrt(kuadrat / N) / 1000.0;   // volt RMS dari sensor
  return vrms * AMPERE_PER_VOLT;
}

void langganan() {}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (millis() - terakhir >= 2000) {
    terakhir = millis();
    float ampere = ukurIrms();
    if (ampere < 0.1) ampere = 0;     // derau saat tidak ada beban
    mqtt.publish(TOPIK_ARUS, String(ampere, 2).c_str());
    mqtt.publish(TOPIK_DAYA, String(ampere * TEGANGAN_PLN, 0).c_str());
  }
}