Jam meja yang tidak perlu disetel: waktunya diambil dari internet, jadi selalu tepat. Baris atas menampilkan jam:menit:detik, baris bawah hari dan tanggal dalam bahasa Indonesia. Lampu latar LCD bisa dimatikan dari HP saat malam.

NTP (Network Time Protocol) adalah cara komputer di seluruh dunia mencocokkan jam dengan server waktu yang sangat akurat. configTime() meminta ESP32 mengambil jam dari pool.ntp.org (cadangannya time.google.com) lalu menjaganya sendiri. ESP32 juga mencocokkan ulang secara berkala, jadi jamnya tidak melenceng.

Layar hanya digambar ulang saat detik berganti, bukan di setiap putaran loop(). Kalau terlalu sering ditulis ulang, LCD bisa berkedip. snprintf() menyusun teks dengan format tetap, misalnya %02d yang memberi nol di depan (07, bukan 7), sehingga posisi angka di layar tidak bergeser.

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
LCD 1602 Biru Terpasang I2C IIC 16×02 Display Mo	1	Rp37.500
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 4	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp116.000

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
LCD 16×2 + modul I2C GND	→	GND	hitam
LCD 16×2 + modul I2C VCC	→	VIN	merah
LCD 16×2 + modul I2C SDA	→	D21 GPIO21	biru
LCD 16×2 + modul I2C SCL	→	D22 GPIO22	kuning

Langkah 2: Siapkan dashboard Klenik

Lampu Latar LCDichibot/budi1234/p102/lampu

Lampu

0 detik lalu

Jam di Alatichibot/budi1234/p102/jam

07:58

07:59

08:00

0 detik lalu

Cara cepat: unduh p102.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Switch Lampu Latar LCD	`ichibot/KODE/p102/lampu`	payload ON / OFF
Text Log Jam di Alat	`ichibot/KODE/p102/jam`	menampilkan teks masuk

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary), LiquidCrystal I2C (Frank de Brabander). Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p102.inoUnduh .ino

// Proyek 102 - Jam Internet di LCD (NTP)
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LAMPU = "ichibot/budi1234/p102/lampu";
const char* TOPIK_JAM   = "ichibot/budi1234/p102/jam";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
LiquidCrystal_I2C lcd(0x27, 16, 2);
const char* HARI[] = {"Min", "Sen", "Sel", "Rab", "Kam", "Jum", "Sab"};
const char* BULAN[] = {"Jan", "Feb", "Mar", "Apr", "Mei", "Jun", "Jul", "Agu", "Sep", "Okt", "Nov", "Des"};
int detikTadi = -1;

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (p == "ON") lcd.backlight(); else lcd.noBacklight();
}

void langganan() {
  mqtt.subscribe(TOPIK_LAMPU);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  lcd.init();
  lcd.backlight();
  lcd.print("Ambil jam...");
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org", "time.google.com");
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  time_t t = time(nullptr);
  if (t < 1700000000) return;
  struct tm* w = localtime(&t);
  if (w->tm_sec == detikTadi) return;  // gambar ulang hanya saat detik berganti
  detikTadi = w->tm_sec;

  char baris1[17], baris2[17];
  snprintf(baris1, sizeof(baris1), "    %02d:%02d:%02d    ", w->tm_hour, w->tm_min, w->tm_sec);
  snprintf(baris2, sizeof(baris2), "%s, %2d %s %d", HARI[w->tm_wday], w->tm_mday, BULAN[w->tm_mon], w->tm_year + 1900);
  lcd.setCursor(0, 0); lcd.print(baris1);
  lcd.setCursor(0, 1); lcd.print(baris2);

  if (w->tm_sec == 0) {               // kirim jam ke dashboard tiap menit
    char jam[6];
    strftime(jam, sizeof(jam), "%H:%M", w);
    mqtt.publish(TOPIK_JAM, jam);
  }
}

// Proyek 102 - Jam Internet di LCD (NTP)
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LAMPU = "ichibot/budi1234/p102/lampu";
const char* TOPIK_JAM   = "ichibot/budi1234/p102/jam";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
LiquidCrystal_I2C lcd(0x27, 16, 2);
const char* HARI[] = {"Min", "Sen", "Sel", "Rab", "Kam", "Jum", "Sab"};
const char* BULAN[] = {"Jan", "Feb", "Mar", "Apr", "Mei", "Jun", "Jul", "Agu", "Sep", "Okt", "Nov", "Des"};
int detikTadi = -1;

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (p == "ON") lcd.backlight(); else lcd.noBacklight();
}

void langganan() {
  mqtt.subscribe(TOPIK_LAMPU);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  lcd.init();
  lcd.backlight();
  lcd.print("Ambil jam...");
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org", "time.google.com");
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

time_t t = time(nullptr);
  if (t < 1700000000) return;
  struct tm* w = localtime(&t);
  if (w->tm_sec == detikTadi) return;  // gambar ulang hanya saat detik berganti
  detikTadi = w->tm_sec;

char baris1[17], baris2[17];
  snprintf(baris1, sizeof(baris1), "    %02d:%02d:%02d    ", w->tm_hour, w->tm_min, w->tm_sec);
  snprintf(baris2, sizeof(baris2), "%s, %2d %s %d", HARI[w->tm_wday], w->tm_mday, BULAN[w->tm_mon], w->tm_year + 1900);
  lcd.setCursor(0, 0); lcd.print(baris1);
  lcd.setCursor(0, 1); lcd.print(baris2);

if (w->tm_sec == 0) {               // kirim jam ke dashboard tiap menit
    char jam[6];
    strftime(jam, sizeof(jam), "%H:%M", w);
    mqtt.publish(TOPIK_JAM, jam);
  }
}

Langkah 4: Pahami kodenya

Zona waktu dalam detik (WIB = +7 jam), koreksi musim panas (0 di Indonesia), lalu server waktu utama dan cadangan.
Layar hanya ditulis ulang sekali per detik.
Nama hari dan bulan diambil dari array buatan sendiri. tm_year dihitung dari 1900, jadi ditambah 1900. tm_mon dimulai dari 0 (Januari).