Pembuka bab Layar: ketik pesan di HP dan pesan itu langsung muncul di LCD 16×2. Pesan pendek tampil di dua baris, pesan panjang berjalan dari kanan ke kiri. Cocok untuk papan pengumuman kelas atau pesan di pintu kamar.

LCD 16×2 menampilkan 2 baris × 16 huruf. Modul I2C di belakangnya (chip PCF8574) mengubah 16 kabel LCD menjadi hanya 4: GND, VCC, SDA, dan SCL. ESP32 berbicara dengannya lewat I2C di alamat 0x27, sama seperti sensor I2C di bab sebelumnya.

Pesan sampai 32 huruf dipotong menjadi dua: huruf 1-16 di baris atas, 17-32 di baris bawah. Pesan yang lebih panjang ditampilkan berjalan. Teks digandakan, lalu setiap 0,35 detik diambil 16 huruf mulai dari posisi yang terus bergeser, sehingga terlihat mengalir tanpa putus.

LCD diberi 5V supaya terang. Kalau tulisan tidak terlihat, putar trimpot biru di belakang modul I2C untuk mengatur kontras.

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
LCD 1602 Biru Terpasang I2C IIC 16×02 Display Mo	1	Rp37.500
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 4	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp116.000

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
LCD 16×2 + modul I2C GND	→	GND	hitam
LCD 16×2 + modul I2C VCC	→	VIN	merah
LCD 16×2 + modul I2C SDA	→	D21 GPIO21	biru
LCD 16×2 + modul I2C SCL	→	D22 GPIO22	kuning

Langkah 2: Siapkan dashboard Klenik

Pesan untuk LCDichibot/budi1234/p101/pesan

Rapat jam 10 di ruang 2

Belum pernah dikirim

Cara cepat: unduh p101.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
TEXT_INPUT Pesan untuk LCD	`ichibot/KODE/p101/pesan`	teks bebas

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary), LiquidCrystal I2C (Frank de Brabander). Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p101.inoUnduh .ino

// Proyek 101 - Tampilkan Pesan dari HP di LCD 16x2
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_PESAN = "ichibot/budi1234/p101/pesan";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
LiquidCrystal_I2C lcd(0x27, 16, 2);   // alamat 0x27 (sebagian modul 0x3F)
String pesan = "Halo dari Ichibot!";
int geser = 0;
unsigned long geserTerakhir = 0;

void tampilkan() {
  lcd.clear();
  if (pesan.length() <= 32) {         // muat: baris 1 dan 2 apa adanya
    lcd.setCursor(0, 0); lcd.print(pesan.substring(0, 16));
    lcd.setCursor(0, 1); lcd.print(pesan.substring(16));
  }
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  pesan = "";
  for (unsigned int i = 0; i < panjang; i++) pesan += (char)isi[i];
  geser = 0;
  tampilkan();
}

void langganan() {
  mqtt.subscribe(TOPIK_PESAN);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  lcd.init();
  lcd.backlight();
  lcd.print("Menyambung WiFi");
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
  tampilkan();
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  // pesan panjang berjalan di baris 1
  if (pesan.length() > 32 && millis() - geserTerakhir >= 350) {
    geserTerakhir = millis();
    String jalan = pesan + "    ";
    String tampil = (jalan + jalan).substring(geser, geser + 16);
    lcd.setCursor(0, 0);
    lcd.print(tampil);
    geser = (geser + 1) % jalan.length();
  }
}

// Proyek 101 - Tampilkan Pesan dari HP di LCD 16x2
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_PESAN = "ichibot/budi1234/p101/pesan";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
LiquidCrystal_I2C lcd(0x27, 16, 2);   // alamat 0x27 (sebagian modul 0x3F)
String pesan = "Halo dari Ichibot!";
int geser = 0;
unsigned long geserTerakhir = 0;

void tampilkan() {
  lcd.clear();
  if (pesan.length() <= 32) {         // muat: baris 1 dan 2 apa adanya
    lcd.setCursor(0, 0); lcd.print(pesan.substring(0, 16));
    lcd.setCursor(0, 1); lcd.print(pesan.substring(16));
  }
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  pesan = "";
  for (unsigned int i = 0; i < panjang; i++) pesan += (char)isi[i];
  geser = 0;
  tampilkan();
}

void langganan() {
  mqtt.subscribe(TOPIK_PESAN);
}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  lcd.init();
  lcd.backlight();
  lcd.print("Menyambung WiFi");
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
  tampilkan();
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

// pesan panjang berjalan di baris 1
  if (pesan.length() > 32 && millis() - geserTerakhir >= 350) {
    geserTerakhir = millis();
    String jalan = pesan + "    ";
    String tampil = (jalan + jalan).substring(geser, geser + 16);
    lcd.setCursor(0, 0);
    lcd.print(tampil);
    geser = (geser + 1) % jalan.length();
  }
}

Langkah 4: Pahami kodenya

Alamat I2C, jumlah kolom, jumlah baris. Kalau layar menyala tapi kosong, coba ganti 0x27 menjadi 0x3F.
setCursor(kolom, baris) dimulai dari 0. Baris kedua adalah baris 1.
Trik teks berjalan: teks ditulis dua kali berurutan, jadi potongan 16 huruf di posisi mana pun selalu penuh dan ujungnya menyambung ke awal.