Kipas Buang Otomatis saat Asap

// Proyek 077 - Kipas Buang Otomatis saat Asap
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_KIPAS_STATUS = "ichibot/budi1234/p077/kipas/status";
const char* TOPIK_LOG          = "ichibot/budi1234/p077/log";
const char* TOPIK_BATAS        = "ichibot/budi1234/p077/batas";
const char* TOPIK_MANUAL       = "ichibot/budi1234/p077/manual";
const char* TOPIK_ASAP         = "ichibot/budi1234/p077/asap";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PIN_ASAP = 34, RELAY = 26;
const unsigned long PEMANASAN = 60000;
const unsigned long SISA_PUTAR = 120000;   // kipas tetap jalan 2 menit setelah udara bersih
int dasar = 0, batas = 30;
bool siap = false, kipas = false, manual = false;
unsigned long bersihSejak = 0, terakhir = 0;

int bacaAsap() {
  long jumlah = 0;
  for (int i = 0; i < 20; i++) { jumlah += analogRead(PIN_ASAP); delay(5); }
  return jumlah / 20;
}

void aturKipas(bool v, const char* sebab) {
  if (v == kipas) return;
  kipas = v;
  digitalWrite(RELAY, v ? HIGH : LOW);
  mqtt.publish(TOPIK_KIPAS_STATUS, v ? "1" : "0", true);
  mqtt.publish(TOPIK_LOG, (String(v ? "Kipas nyala" : "Kipas mati") + " (" + sebab + ")").c_str());
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String topik = t;
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (topik == TOPIK_BATAS) batas = p.toInt();
  if (topik == TOPIK_MANUAL) {
    manual = (p == "ON");
    aturKipas(manual, manual ? "manual" : "manual dimatikan");
  }
}

void langganan() {
  mqtt.subscribe(TOPIK_BATAS);
  mqtt.subscribe(TOPIK_MANUAL);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(RELAY, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (millis() - terakhir < 2000) return;
  terakhir = millis();

  int mentah = bacaAsap();
  if (!siap) {
    if (millis() < PEMANASAN) return;
    dasar = max(mentah, 50);
    siap = true;
  }
  int naik = constrain((mentah - dasar) * 100 / dasar, 0, 500);
  mqtt.publish(TOPIK_ASAP, String(naik).c_str());
  if (manual) return;                 // mode manual: sensor tidak mengatur kipas

  if (naik > batas) {
    bersihSejak = 0;
    aturKipas(true, "ada asap");
  } else if (kipas) {
    if (bersihSejak == 0) bersihSejak = millis();
    if (millis() - bersihSejak > SISA_PUTAR) aturKipas(false, "udara bersih");
  }
}