AGS10 mengukur TVOC, yaitu uap kimia di udara dari cat, lem, parfum, pembersih lantai, dan asap. Berbeda dengan sensor MQ, AGS10 langsung mengirim angka dalam ppb lewat I2C dan sudah dikalibrasi pabrik.

TVOC (Total Volatile Organic Compounds) adalah jumlah senyawa organik yang mudah menguap. Sensor MEMS di AGS10 berisi pemanas mikro dan lapisan peka gas seperti sensor MQ, tetapi ukurannya jauh lebih kecil, butuh daya jauh lebih rendah, dan dilengkapi chip pengolah. Hasilnya bisa langsung dibaca dalam ppb (bagian per miliar).

Komunikasinya I2C di alamat 0x1A dengan satu kekhususan: kecepatan maksimal 15 kHz, jauh di bawah standar I2C 100 kHz. Setiap bacaan berisi 5 byte: status, tiga byte angka TVOC, dan satu byte CRC untuk memeriksa apakah data rusak di jalan. Setelah dinyalakan, sensor butuh sekitar 2 menit pemanasan. Selama itu bit status RDY bernilai 1.

Kategori Baik/Sedang/Buruk memakai ambang yang umum dipakai untuk TVOC dalam ruangan. Anggap saja sebagai panduan kasar.

Komponen

Komponen	Qty	Harga
ESP32 DOIT DevKit V1 30 pin	1	Rp75.000
AGS10 TVOC Air Quality Sensor I2C MEMS Pengganti	1	Rp80.000
Kabel jumper female-female 10 cm (isi 10)isi 10, terpakai 4	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp158.500

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
AGS10 TVOC (I2C) VCC	→	3V3	merah
AGS10 TVOC (I2C) GND	→	GND	hitam
AGS10 TVOC (I2C) SCL	→	D22 GPIO22	kuning
AGS10 TVOC (I2C) SDA	→	D21 GPIO21	biru

Langkah 2: Siapkan dashboard Klenik

TVOCichibot/budi1234/p076/tvoc

0 detik lalu

Grafik TVOCichibot/budi1234/p076/tvoc

190 ppb

0.0 ppb10 titik3000.0 ppb

0 detik lalu

Status Udaraichibot/budi1234/p076/log

Udara Baik (150 ppb)

Udara Buruk (1300 ppb)

Udara Sedang (610 ppb)

0 detik lalu

Cara cepat: unduh p076.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Gauge TVOC	`ichibot/KODE/p076/tvoc`	0–3000 ppb
Chart Grafik TVOC	`ichibot/KODE/p076/tvoc`	0–3000 ppb
Text Log Status Udara	`ichibot/KODE/p076/log`	menampilkan teks masuk

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: ESP32 Dev Module. Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p076.inoUnduh .ino

// Proyek 076 - Kualitas Udara Digital AGS10 (TVOC)
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <Wire.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_TVOC = "ichibot/budi1234/p076/tvoc";
const char* TOPIK_LOG  = "ichibot/budi1234/p076/log";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const uint8_t AGS10 = 0x1A;           // alamat I2C AGS10
unsigned long terakhir = 0;
String statusTadi = "";

uint8_t crc8(const uint8_t* d, int n) {   // pemeriksa data dari datasheet AGS10
  uint8_t c = 0xFF;
  for (int i = 0; i < n; i++) {
    c ^= d[i];
    for (int b = 0; b < 8; b++) c = (c & 0x80) ? (c << 1) ^ 0x31 : c << 1;
  }
  return c;
}

long bacaTVOC() {                     // ppb, -1 = gagal, -2 = masih pemanasan
  Wire.beginTransmission(AGS10);
  Wire.write(0x00);                   // register data TVOC
  if (Wire.endTransmission() != 0) return -1;
  delay(30);
  if (Wire.requestFrom(AGS10, (uint8_t)5) != 5) return -1;
  uint8_t d[5];
  for (int i = 0; i < 5; i++) d[i] = Wire.read();
  if (crc8(d, 4) != d[4]) return -1;
  if (d[0] & 0x01) return -2;         // bit RDY = 1: sensor belum siap
  return ((long)d[1] << 16) | ((long)d[2] << 8) | d[3];
}

String status(long ppb) {
  if (ppb < 220)  return "Baik";
  if (ppb < 660)  return "Sedang";
  if (ppb < 2200) return "Buruk";
  return "Sangat buruk";
}

void langganan() {}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  Wire.begin(21, 22);                 // SDA, SCL
  Wire.setClock(15000);               // AGS10 hanya sanggup I2C lambat (maks 15 kHz)
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (millis() - terakhir < 3000) return;
  terakhir = millis();

  long ppb = bacaTVOC();
  if (ppb == -1) { Serial.println("AGS10 tidak menjawab, cek kabel"); return; }
  if (ppb == -2) { Serial.println("AGS10 masih pemanasan"); return; }
  Serial.printf("TVOC %ld ppb\n", ppb);
  mqtt.publish(TOPIK_TVOC, String(ppb).c_str());

  String s = status(ppb);
  if (s != statusTadi) {
    statusTadi = s;
    mqtt.publish(TOPIK_LOG, ("Udara " + s + " (" + String(ppb) + " ppb)").c_str());
  }
}

// Proyek 076 - Kualitas Udara Digital AGS10 (TVOC)
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>
#include <Wire.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_TVOC = "ichibot/budi1234/p076/tvoc";
const char* TOPIK_LOG  = "ichibot/budi1234/p076/log";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const uint8_t AGS10 = 0x1A;           // alamat I2C AGS10
unsigned long terakhir = 0;
String statusTadi = "";

uint8_t crc8(const uint8_t* d, int n) {   // pemeriksa data dari datasheet AGS10
  uint8_t c = 0xFF;
  for (int i = 0; i < n; i++) {
    c ^= d[i];
    for (int b = 0; b < 8; b++) c = (c & 0x80) ? (c << 1) ^ 0x31 : c << 1;
  }
  return c;
}

long bacaTVOC() {                     // ppb, -1 = gagal, -2 = masih pemanasan
  Wire.beginTransmission(AGS10);
  Wire.write(0x00);                   // register data TVOC
  if (Wire.endTransmission() != 0) return -1;
  delay(30);
  if (Wire.requestFrom(AGS10, (uint8_t)5) != 5) return -1;
  uint8_t d[5];
  for (int i = 0; i < 5; i++) d[i] = Wire.read();
  if (crc8(d, 4) != d[4]) return -1;
  if (d[0] & 0x01) return -2;         // bit RDY = 1: sensor belum siap
  return ((long)d[1] << 16) | ((long)d[2] << 8) | d[3];
}

String status(long ppb) {
  if (ppb < 220)  return "Baik";
  if (ppb < 660)  return "Sedang";
  if (ppb < 2200) return "Buruk";
  return "Sangat buruk";
}

void langganan() {}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  Wire.begin(21, 22);                 // SDA, SCL
  Wire.setClock(15000);               // AGS10 hanya sanggup I2C lambat (maks 15 kHz)
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

if (millis() - terakhir < 3000) return;
  terakhir = millis();

long ppb = bacaTVOC();
  if (ppb == -1) { Serial.println("AGS10 tidak menjawab, cek kabel"); return; }
  if (ppb == -2) { Serial.println("AGS10 masih pemanasan"); return; }
  Serial.printf("TVOC %ld ppb\n", ppb);
  mqtt.publish(TOPIK_TVOC, String(ppb).c_str());

String s = status(ppb);
  if (s != statusTadi) {
    statusTadi = s;
    mqtt.publish(TOPIK_LOG, ("Udara " + s + " (" + String(ppb) + " ppb)").c_str());
  }
}

Langkah 4: Pahami kodenya

Wajib untuk AGS10. Pada kecepatan I2C biasa (100 kHz), sensor ini tidak menjawab atau mengirim data rusak.
CRC adalah angka pemeriksa. Sensor menghitungnya dari 4 byte data, ESP32 menghitung ulang, dan kalau hasilnya beda berarti data rusak lalu diabaikan.
Bit terendah byte status bernilai 1 selama pemanasan. Data baru dikirim setelah sensor siap.
Tiga byte digabung menjadi satu angka 24-bit: byte pertama digeser 16 bit, byte kedua 8 bit.