Alarm Kebocoran Gas Dapur

// Proyek 072 - Alarm Kebocoran Gas Dapur
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_LOG   = "ichibot/budi1234/p072/log";
const char* TOPIK_BISU  = "ichibot/budi1234/p072/bisu";
const char* TOPIK_GAS   = "ichibot/budi1234/p072/gas";
const char* TOPIK_BOCOR = "ichibot/budi1234/p072/bocor";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PIN_GAS = 34, BUZZER = 4;
const unsigned long PEMANASAN = 60000;
const int BATAS = 40;                 // kenaikan (%) yang memicu alarm
int dasar = 0;
bool siap = false, alarm_aktif = false, dibisukan = false;
unsigned long terakhir = 0;

int bacaGas() {
  long jumlah = 0;
  for (int i = 0; i < 20; i++) { jumlah += analogRead(PIN_GAS); delay(5); }
  return jumlah / 20;
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  if (p == "ON" && alarm_aktif) {
    dibisukan = true;                 // bunyi berhenti, indikator tetap BOCOR
    mqtt.publish(TOPIK_LOG, "Buzzer dibisukan dari dashboard");
  }
  if (p == "ON") mqtt.publish(TOPIK_BISU, "OFF");
}

void langganan() {
  mqtt.subscribe(TOPIK_BISU);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(BUZZER, OUTPUT);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  // bunyi tiit-tiit cepat selama alarm dan belum dibisukan
  digitalWrite(BUZZER, (alarm_aktif && !dibisukan && (millis() / 150) % 2) ? HIGH : LOW);

  if (millis() - terakhir < 2000) return;
  terakhir = millis();

  int mentah = bacaGas();
  if (!siap) {
    if (millis() < PEMANASAN) return;
    dasar = max(mentah, 50);
    siap = true;
    mqtt.publish(TOPIK_LOG, "Detektor siap");
  }
  int naik = constrain((mentah - dasar) * 100 / dasar, 0, 500);
  mqtt.publish(TOPIK_GAS, String(naik).c_str());

  if (!alarm_aktif && naik > BATAS) {
    alarm_aktif = true;
    dibisukan = false;
    mqtt.publish(TOPIK_BOCOR, "1", true);
    mqtt.publish(TOPIK_LOG, "GAS TERDETEKSI! Tutup regulator, buka jendela, jangan nyalakan saklar listrik");
  } else if (alarm_aktif && naik < BATAS / 2) {
    alarm_aktif = false;
    mqtt.publish(TOPIK_BOCOR, "0", true);
    mqtt.publish(TOPIK_LOG, "Kadar gas kembali normal");
  }
}