Detektor Asap & Gas LPG MQ-2

// Proyek 071 - Detektor Asap & Gas LPG MQ-2
// Board: ESP32 DOIT DevKit V1 | Dashboard: klenik.ichibot.id
#include <WiFi.h>
#include <PubSubClient.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_BATAS  = "ichibot/budi1234/p071/batas";
const char* TOPIK_LOG    = "ichibot/budi1234/p071/log";
const char* TOPIK_GAS    = "ichibot/budi1234/p071/gas";
const char* TOPIK_BAHAYA = "ichibot/budi1234/p071/bahaya";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PIN_GAS = 34;               // AO lewat pembagi 1K/2K
const unsigned long PEMANASAN = 60000;  // sensor MQ perlu dipanaskan dulu
int dasar = 0;                        // angka udara bersih, diukur setelah pemanasan
int batas = 30;                       // kenaikan (%) yang dianggap bahaya
bool siap = false, bahaya = false;
unsigned long terakhir = 0;

int bacaGas() {
  long jumlah = 0;
  for (int i = 0; i < 20; i++) { jumlah += analogRead(PIN_GAS); delay(5); }
  return jumlah / 20;
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  batas = p.toInt();
}

void langganan() {
  mqtt.subscribe(TOPIK_BATAS);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  sambungWiFi();
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (millis() - terakhir < 2000) return;
  terakhir = millis();

  int mentah = bacaGas();
  if (!siap) {
    if (millis() < PEMANASAN) {
      mqtt.publish(TOPIK_LOG, ("Memanaskan sensor... " + String((PEMANASAN - millis()) / 1000) + " detik").c_str());
      return;
    }
    dasar = max(mentah, 50);          // anggap udara saat ini bersih
    siap = true;
    mqtt.publish(TOPIK_LOG, ("Siap. Angka udara bersih: " + String(dasar)).c_str());
  }

  int naik = (mentah - dasar) * 100 / dasar;   // kenaikan dibanding udara bersih (%)
  naik = constrain(naik, 0, 500);
  Serial.printf("Mentah %d, dasar %d, naik %d%%\n", mentah, dasar, naik);
  mqtt.publish(TOPIK_GAS, String(naik).c_str());

  bool sekarang = naik > batas;
  if (sekarang != bahaya) {
    bahaya = sekarang;
    mqtt.publish(TOPIK_BAHAYA, bahaya ? "1" : "0", true);
    mqtt.publish(TOPIK_LOG, bahaya ? "ASAP/GAS TERDETEKSI!" : "Udara kembali normal");
  }
}