Saklar pelampung dipasang di dalam tandon, dan Klenik menunjukkan apakah tandon penuh atau airnya sudah turun. Riwayat jam penuh dan jam air turun ikut tercatat, jadi kamu tahu pola pemakaian air di rumah tanpa naik ke atap.

Saklar pelampung punya magnet di dalam pelampungnya dan saklar reed di batangnya. Saat air naik, pelampung terangkat dan saklar tertutup sehingga kedua kabelnya tersambung. Satu kabel ke D5, satu ke GND. Dengan INPUT_PULLUP, D5 terbaca LOW saat saklar tertutup.

Permukaan air bisa beriak saat tandon diisi, jadi pelampung naik-turun cepat. Perubahan baru dianggap sah kalau bertahan 3 detik. Status dikirim dengan flag retained, sehingga dashboard yang baru dibuka langsung menampilkan keadaan tandon.

Komponen

Komponen	Qty	Harga
NodeMCU ESP8266 V3 (Lolin)	1	Rp42.000
Plastic Float Switch Sensor 52mm Anti Korosi Aci	1	Rp18.500
Kabel jumper male-female 10 cm (isi 10)isi 10, terpakai 2, sambung kabel pelampung ke kabel panjang kalau tandon jauh	1	Rp3.500
Kabel micro USB data 30 cmopsional, kalau belum punya kabel micro USB data	1	Rp11.700
Total (tanpa opsional)		Rp64.000

Order semua komponen via WhatsAppDaftar komponen proyek ini otomatis masuk ke pesan. Hapus yang sudah kamu punya sebelum dikirim.

Langkah 1: Rangkai komponen

Sambungkan kabel sesuai gambar di atas. Kalau gambar dan tabel terlihat berbeda, ikuti tabel.

Dari		Ke	Kabel
Saklar pelampung (2 kabel) 1	→	G	hitam
Saklar pelampung (2 kabel) 2	→	D5 GPIO14	biru

Langkah 2: Siapkan dashboard Klenik

Tandonichibot/budi1234/p064/penuh

PENUH

0 detik lalu

Riwayat Tandonichibot/budi1234/p064/log

05:12 Tandon penuh

06:40 Air tandon turun

07:25 Tandon penuh

0 detik lalu

Cara cepat: unduh p064.json, ganti budi1234 dengan KODE-mu, lalu import di Klenik (menu titik tiga → Export / Import → Import → Ganti total). Langkah lengkapnya ada di Panduan Klenik.

Widget	Topic	Setting
Indikator Boolean Tandon	`ichibot/KODE/p064/penuh`	ON = `1` “PENUH”, OFF = `0`
Text Log Riwayat Tandon	`ichibot/KODE/p064/log`	menampilkan teks masuk

Langkah 3: Upload kode

Library: PubSubClient (Nick O'Leary). Board di Arduino IDE: NodeMCU 1.0 (ESP-12E Module). Isi dulu nama WiFi dan password di bagian ISI DULU, lalu ganti budi1234 di baris topic dengan KODE-mu, lalu upload dan buka Serial Monitor (115200).

p064.inoUnduh .ino

// Proyek 064 - Level Air Tandon dengan Pelampung
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_PENUH = "ichibot/budi1234/p064/penuh";
const char* TOPIK_LOG   = "ichibot/budi1234/p064/log";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PELAMPUNG = D5;             // kabel lain ke GND
int statusTadi = -1;                  // -1 = belum pernah dikirim
unsigned long berubahSejak = 0;

String jamSekarang() {
  time_t t = time(nullptr);
  char buf[6];
  strftime(buf, sizeof(buf), "%H:%M", localtime(&t));
  return String(buf);
}

void langganan() {}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(PELAMPUNG, INPUT_PULLUP);
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org");
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) { sambungMQTT(); statusTadi = -1; }   // kirim ulang setelah tersambung
  mqtt.loop();

  int penuh = (digitalRead(PELAMPUNG) == LOW) ? 1 : 0;   // saklar tertutup = pelampung terangkat
  if (penuh != statusTadi) {
    if (berubahSejak == 0) berubahSejak = millis();
    if (millis() - berubahSejak > 3000 || statusTadi == -1) {   // harus stabil 3 detik (riak air)
      bool pertama = (statusTadi == -1);
      statusTadi = penuh;
      berubahSejak = 0;
      mqtt.publish(TOPIK_PENUH, penuh ? "1" : "0", true);
      if (!pertama) {
        String pesan = jamSekarang() + (penuh ? " Tandon penuh" : " Air tandon turun");
        mqtt.publish(TOPIK_LOG, pesan.c_str());
      }
    }
  } else {
    berubahSejak = 0;
  }
}

// Proyek 064 - Level Air Tandon dengan Pelampung
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_PENUH = "ichibot/budi1234/p064/penuh";
const char* TOPIK_LOG   = "ichibot/budi1234/p064/log";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int PELAMPUNG = D5;             // kabel lain ke GND
int statusTadi = -1;                  // -1 = belum pernah dikirim
unsigned long berubahSejak = 0;

String jamSekarang() {
  time_t t = time(nullptr);
  char buf[6];
  strftime(buf, sizeof(buf), "%H:%M", localtime(&t));
  return String(buf);
}

void langganan() {}

void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(PELAMPUNG, INPUT_PULLUP);
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org");
  mqtt.setServer(BROKER, 1883);
}

void loop() {
  if (!mqtt.connected()) { sambungMQTT(); statusTadi = -1; }   // kirim ulang setelah tersambung
  mqtt.loop();

int penuh = (digitalRead(PELAMPUNG) == LOW) ? 1 : 0;   // saklar tertutup = pelampung terangkat
  if (penuh != statusTadi) {
    if (berubahSejak == 0) berubahSejak = millis();
    if (millis() - berubahSejak > 3000 || statusTadi == -1) {   // harus stabil 3 detik (riak air)
      bool pertama = (statusTadi == -1);
      statusTadi = penuh;
      berubahSejak = 0;
      mqtt.publish(TOPIK_PENUH, penuh ? "1" : "0", true);
      if (!pertama) {
        String pesan = jamSekarang() + (penuh ? " Tandon penuh" : " Air tandon turun");
        mqtt.publish(TOPIK_LOG, pesan.c_str());
      }
    }
  } else {
    berubahSejak = 0;
  }
}

Langkah 4: Pahami kodenya

Saklar pelampung tidak punya kutub, jadi kabel mana pun boleh ke D5. Kalau terbaca terbalik (PENUH saat kosong), balik pelampung di batangnya. Posisi pelampung menentukan kapan saklar tertutup.
Status baru dikirim setelah stabil 3 detik. Kiriman pertama setelah tersambung langsung dikirim tanpa menunggu.
Setelah koneksi putus lalu tersambung lagi, status dikirim ulang. Selama putus bisa saja tandon sudah berubah.