Detektor Hujan Angkat Jemuran

// Proyek 063 - Detektor Hujan Angkat Jemuran
// Board: NodeMCU ESP8266 V3 | Dashboard: klenik.ichibot.id
#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <time.h>

// ===== ISI DULU =====
const char* WIFI_NAMA = "nama-wifi-kamu";
const char* WIFI_PASS = "password-wifi-kamu";

// topic MQTT: ganti budi1234 dengan KODE-mu (sama dengan di dashboard Klenik)
const char* TOPIK_BATAS = "ichibot/budi1234/p063/batas";
const char* TOPIK_BASAH = "ichibot/budi1234/p063/basah";
const char* TOPIK_LOG   = "ichibot/budi1234/p063/log";
const char* TOPIK_HUJAN = "ichibot/budi1234/p063/hujan";

const char* BROKER = "mqtt.ichibot.id";
WiFiClient wifi;
PubSubClient mqtt(wifi);
const int BUZZER = D2;
const int NILAI_KERING = 1024;        // A0 saat papan kering
const int NILAI_BASAH  = 300;         // A0 saat papan disiram air
int batas = 20;                       // % basah yang dianggap hujan
bool hujan = false;
unsigned long kirimTerakhir = 0, bunyiSampai = 0;

String jamSekarang() {
  time_t t = time(nullptr);
  char buf[6];
  strftime(buf, sizeof(buf), "%H:%M", localtime(&t));
  return String(buf);
}

void pesanMasuk(char* t, byte* isi, unsigned int panjang) {
  String p;
  for (unsigned int i = 0; i < panjang; i++) p += (char)isi[i];
  batas = p.toInt();
}

void langganan() {
  mqtt.subscribe(TOPIK_BATAS);
}

sambungWiFi() dan sambungMQTT(): sama di semua proyek (klik untuk lihat)
void sambungWiFi() {
  WiFi.begin(WIFI_NAMA, WIFI_PASS);
  Serial.print("WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" OK, IP " + WiFi.localIP().toString());
}

void sambungMQTT() {
  while (!mqtt.connected()) {
    if (mqtt.connect(WiFi.macAddress().c_str())) {
      Serial.println("Terhubung ke Klenik");
      langganan();
    } else {
      Serial.println("Broker gagal, coba lagi 3 detik");
      delay(3000);
    }
  }
}
void setup() {
  Serial.begin(115200);
  pinMode(BUZZER, OUTPUT);
  sambungWiFi();
  configTime(7 * 3600, 0, "pool.ntp.org");
  mqtt.setServer(BROKER, 1883);
  mqtt.setCallback(pesanMasuk);
}

void loop() {
  if (!mqtt.connected()) sambungMQTT();
  mqtt.loop();

  if (millis() - kirimTerakhir >= 2000) {
    kirimTerakhir = millis();
    int mentah = analogRead(A0);
    int basah = constrain(map(mentah, NILAI_KERING, NILAI_BASAH, 0, 100), 0, 100);
    Serial.printf("A0 %d -> basah %d%%\n", mentah, basah);
    mqtt.publish(TOPIK_BASAH, String(basah).c_str());

    if (!hujan && basah > batas) {
      hujan = true;
      bunyiSampai = millis() + 6000;
      mqtt.publish(TOPIK_LOG, ("Hujan mulai " + jamSekarang() + ". Angkat jemuran!").c_str());
    } else if (hujan && basah < batas / 2) {
      hujan = false;
      mqtt.publish(TOPIK_LOG, ("Papan kering lagi " + jamSekarang()).c_str());
    }
    mqtt.publish(TOPIK_HUJAN, hujan ? "1" : "0", true);
  }

  if (bunyiSampai) {
    digitalWrite(BUZZER, (millis() / 300) % 2);   // tiit-tiit 6 detik
    if ((long)(millis() - bunyiSampai) >= 0) {
      bunyiSampai = 0;
      digitalWrite(BUZZER, LOW);
    }
  }
}